spiral, equal distance between points

Programming Questions

clankill3r

spiral, equal distance between points

in Programming Questions • 1 year ago

In the code below the distance between the previous point and the next gets smaller and smaller when the radius get's smaller.

I'm interested in keeping a equal distance between those, so if the radius get's smaller less points will be drawn.

If there is more then one way then i'm interested in the other ways as well, it's the start of a quite complex project and the complex method might make things easier at the long run.

could someone help?

float r;
void setup() {
size(600, 600);
r= width/2.2;
smooth();
}
void draw() {
background(255);
translate(width/2, height/2);
fill(0);
while(r > 0) {
ellipse(r--, 0, 5, 5);
rotate(radians(10));
}
noLoop();
}

Replies(6)

patakk

Re: spiral, equal distance between points

1 year ago

float dist = 40, radius = dist/2, alpha = 0, speed = 500;
float px, py, x, y, k;
void setup() {
size(640, 640);
background(255); fill(0);
smooth();
px = radius;
py = 0;
}
void draw() {
k = speed/radius ;
alpha += k;
radius += dist/(360/k);
x = radius*cos(radians(alpha));
y = -radius*sin(radians(alpha));
translate(width/2, height/2);
ellipse(x, y, 5, 5);
}

quarks

Re: spiral, equal distance between points

1 year ago

The picture on the left shows a spiral made from lines 15px long. The trick is to modify the change in angle realtive to the current radius.

This code was originally posted in this thread.

The length of the line is determine by the variable RES

size(300, 300);
background(0);
stroke(255);
strokeWeight(1.0);
final float RES = 15; // the line length
float numofCircles = 3.6;
PVector spiralCenter = new PVector(150, 150);
float startRadius = 100;
float endRadius = 20;
float currRadius = startRadius;
float totalRadian = numofCircles * PI * 2;
float startRadian = -PI;
float endRadian = startRadian + totalRadian;
float currentRadian = startRadian;
// This depends on the current radius
float deltaAngle;
// Spiral starts from outside
float lastX = cos(startRadian) * startRadius;
float lastY = sin(startRadian) * startRadius;
float nextX, nextY;
while (currentRadian < endRadian)
{
deltaAngle = PI * RES / currRadius;
currentRadian += deltaAngle;
currRadius = map(currentRadian, startRadian, endRadian, startRadius, endRadius);
nextX = cos(currentRadian) * currRadius;
nextY = sin(currentRadian) * currRadius;
line(lastX + spiralCenter.x, lastY + spiralCenter.y,
nextX + spiralCenter.x, nextY + spiralCenter.y);
lastX = nextX;
lastY = nextY;
}

clankill3r

Re: spiral, equal distance between points

1 year ago

both thanks

For the first one,

the distance between the points comes from speed. It needs quite a high value. Like a value of 500 is around 10px or something. Is it possible to have it like that?

For the second one (quarks), i really like the control of it.

Only if i add this where you draw the line:

println(dist(lastX + spiralCenter.x, lastY + spiralCenter.y,

nextX + spiralCenter.x, nextY + spiralCenter.y));

then i get those values back:

46.80389
46.796535
46.788925
46.780884
46.772465
46.763603
46.754322
46.744553
46.734226
46.723347
46.711834
46.699646
46.6867
46.672993
46.658356
46.642735
46.626087
46.608192
46.589005
46.56832
46.545975
46.521797
46.495525
46.46684
46.435455
46.400917
46.36275
46.32039
46.273056
46.219795
46.15958
46.09075
46.011543
45.919285
45.81055
45.68044
45.52224
45.325676
45.07514
44.745277
44.29219
43.632755
42.59021
40.714764
36.47411
20.387144

So it becomes smaller and smaller, also the line length is more then 2 times to long.

Also in the other topic where you post the code with sleight different values the problem occurs, only you had a value of 1.05 so it's hard to spot then.

The reason i want such precise control is that i want to make a vinyl record with a laser cutter.

For this it's also nice to be able to tell how many pixels a mm is etc. (i can calculate that, it's not a question to you guys). If i know that then i can set the distance of the line on 0.5mm for example (instead of a strange pixel value).

quarks

Re: spiral, equal distance between points

1 year ago

So the real problem is to calculate the spiral coordinates for the laser cutter NOT the pixel coordinates for the display.

You can always take the laser cutter coordinates and scale for the display if you want to draw it, but it is not a good idea to do it the other way round.

The distance between grooves will be the pitch, where pitch = groovewidth + gap

So the solution will depend on

size of the groovewidth
size of the gap
the tolereance required for the pitch (the range of acceptable values for pitch)
the minimum radius
the maximum radius
the precsion of the laser cutter.

all these would need to be in real world measures e.g. mm

clankill3r

Re: spiral, equal distance between points

1 year ago

ok attempt 3 to write this post, first time i had to log in again, then i had a system crash...

the precsion of the laser cutter.

It's 1000dpi, which is low, normally the groovewidth is 60 micron (0,06mm = 0 ,00236 inch ).

1000 x 0,00236 = 2.36 pixels

So that will be 2 pixels to choose from...

My goal is not creating the best sound anyway...

I will take a much bigger groove to at least get some 8 bit music.

With minim i can get values between 1 and -1, i can map that to the groove width, this is not hard to do (i think).

For the rest, the sample rate so to call is not constant on a vinyl record, since it works with rpm, so 200 degrees is about 1 second on 33rpm. I will go for 45 rpm so i have more length (270 degrees). This also means that the futher away from the centrum the more samples i can laser cut.

Now creating a pdf with the vector lines is probably a no go since it will be a insane amount of vector data.

So i want to create a image, only bad thing about it is that the laser cutter doesn't follow the spiral but cuts then row for row. Another solution might be to go to someone i know who build his own lasercutter and see if i can give instructions with processing (and hoping hi's dpi specs is also 1000 or close).

About your values of the length decreasing over time, i think it won't have much effect since i won't use a long length anyway. (althought a fix is always welcome)

all these would need to be in real world measures e.g. mm

Just worked on that:

int dpi = 1000;
void setup() {
PImage img = createImage(mmToPixels(302), mmToPixels(302), RGB);
img.save("12inchRecord.png");
println("done");
}
int mmToPixels(float mm) {
return int(dpi * (mm * 0.0393700787));
}

clankill3r

Re: spiral, equal distance between points

1 year ago

I'm still working on it. Reading a lot of formulas and terms i don't understand. But i bother a math forum with questions related to that.

Anyway, atm i'm thinking using something like this:

void setup() {
size(600, 600, P3D);
float r = 250;
// distance between each
float step = 70;
// number of dots to be drawn
int n = 160;
// decrease for radius
float decrement = 50;
// uncorect since this is the formula for a circle
float armLength = PI*(r*2);
// max steps for 1 rotation
int max = int(armLength/step);
// abort on minimum radius
float minRadius = 60;
translate(width/2, height/2);
int i = 0;
// previous
float px = 0;
float py = 0;
noFill();
stroke(0);
strokeWeight(1);
beginShape();
while (n > 0) {
float a = map(i, 0, max, 0, TWO_PI);
float r2 = map(i, 0, max, r, r-decrement);
if (r2 <= minRadius) break;
pushMatrix();
rotate(a);
ellipse(r2, 0, 5, 5);
vertex(r2, 0);
println(dist(modelX(r2, 0, 0), modelY(r2, 0, 0), px, py));
px = modelX(r2, 0, 0);
py = modelY(r2, 0, 0);
popMatrix();
n--;
i++;
if (i >= max) {
println(i+"\t"+max);
r-= decrement;
armLength = PI*(r*2);
max = int(armLength/step);
i = 0;
}
}
endShape();
}

I would need to fix the armLength (the length of 1 rotation) but i'm still looking into that.

Can something like this work? And would it be possible to fix the ugly going over to the next circle?

Top Reply