Speed of Serial, it's too slow

belimawr

Speed of Serial, it's too slow

in Contributed Library Questions • 4 months ago

Hi,

I'm doing a simple sketch to receive some bytes from an Arduino, covert them into floats to print and generate a graph.

Everything is working, but very slow! I'd say that the printing rate is about 2Hz but the Arduino is sending data at about 200Hz!

I'm not loosing any packet (it looks to have a huge buffer), however I need to print it in real time.

Here is my code:

import org.gwoptics.graphics.graph2D.Graph2D;
import org.gwoptics.graphics.graph2D.traces.ILine2DEquation;
import org.gwoptics.graphics.graph2D.traces.RollingLine2DTrace;
import java.util.ArrayList;
import java.util.Stack;
import processing.serial.*;
class GraphStackWrapper implements ILine2DEquation
{
Stack<Float> points;
float last;
public GraphStackWrapper()
{
points = new Stack<Float>();
last = 0.0f;
}
public double computePoint(double x,int pos)
{
if(!points.empty())
{
last = points.pop();
}
return (double) last;
}
public void addValue(float f)
{
points.push(f);
}
}
Serial my_serial;
int count;
byte[] byteBuffer;
GraphStackWrapper tmp0, tmp1;
GraphStackWrapper accel0x, accel0y, accel0z;
GraphStackWrapper accel1x, accel1y, accel1z;
RollingLine2DTrace Ltemp0, Lacc0X;
Graph2D g;
void setup()
{
size(800,300);
/* Initialize all graph wrappers */
tmp0 = new GraphStackWrapper();
tmp1 = new GraphStackWrapper();
accel0x = new GraphStackWrapper();
accel0y = new GraphStackWrapper();
accel0z = new GraphStackWrapper();
accel1x = new GraphStackWrapper();
accel1y = new GraphStackWrapper();
accel1z = new GraphStackWrapper();
Ltemp0 = new RollingLine2DTrace(tmp0 , 200, 0.1f);
Ltemp0.setTraceColour(0, 0, 0);
Lacc0X = new RollingLine2DTrace(accel0x , 200, 0.1f);
Lacc0X.setTraceColour(255, 0, 0);
g = new Graph2D(this, 400, 200, false);
g.setYAxisMax(50);
g.addTrace(Ltemp0);
g.addTrace(Lacc0X);
g.position.y = 50;
g.position.x = 100;
g.setYAxisTickSpacing(20);
g.setXAxisMax(5f);
g.setYAxisMin(-100.0f);
g.setXAxisLabel("Time");
g.setYAxisLabel("Sensors");
String portName = Serial.list()[0];
println(portName);
byteBuffer = new byte[38];
my_serial = new Serial(this, portName, 9600);
count = 1;
/* wait for a beginning */
while(my_serial.read() != 0x26)
print('.');
println("Setup Done!");
print("[26]");
}
void draw()
{
background(200);
/* Grab data */
if(my_serial.available() > 0)
{
byte inByte = (byte) my_serial.read();
if(count > 0)
byteBuffer[count - 1] = inByte;
// print('[');
// print(hex(inByte, 2));
// print(']');
count ++;
/* If it's finished, process it */
if(count == 0x27)
{
print('\n');
print('[');
print(hex(byteBuffer[1], 2));
print(']');
print('[');
print(hex(byteBuffer[0], 2));
print(']');
print('\t');
for(int i = 0; i < 9; i++)
{
float f = get4bytesFloat(byteBuffer, 2+i*4);
print(nf(f, 2, 3));
print('\t');
if(i==0)
{
tmp0.addValue(f);
}
if(i==2)
{
accel0x.addValue(f*30.0f);
}
}
count = 0;
println('\n');
}
}
/* print a graph */
g.draw();
}
float get4bytesFloat(byte[] data, int offset)
{
String hexint=hex(data[offset+3])+hex(data[offset+2])+hex(data[offset+1])+hex(data[offset]);
return Float.intBitsToFloat(unhex(hexint));
}

Does anyone have any idea about how I can speed up this code?

Replies(5)

GoToLoop

Re: Speed of Serial, it's too slow

4 months ago

May I suggest to use an ArrayDeque in place of a Stack? It's said the former is faster!

I've made some more alterations to your code.

Dunno whether it still works though, since I don't have an Arduino to check it out!

// http://forum.processing.org/topic/speed-of-serial-it-s-too-slow

import processing.serial.*;

import org.gwoptics.graphics.graph2D.Graph2D;
import org.gwoptics.graphics.graph2D.traces.ILine2DEquation;
import org.gwoptics.graphics.graph2D.traces.RollingLine2DTrace;

import java.util.Deque;
import java.util.ArrayDeque;

final static class GraphStackWrapper implements ILine2DEquation {
  final Deque<Float> points = new ArrayDeque();
  float last;

  double computePoint(double x, int pos) {
    return last = points.isEmpty()? last : points.pop();
  }

  void addValue(float f) {
    points.push(f);
  }
}

final static float get4BytesFloat(byte[] data, int offset) {
  final String hexInt = hex(data[offset+3]) + hex(data[offset+2]) 
    + hex(data[offset+1]) + hex(data[offset]);

  return Float.intBitsToFloat( unhex(hexInt) );
}

Serial mySerial;
final static byte NUM = 0x26;
final byte[] byteBuffer = new byte[NUM];
int count = 1;

GraphStackWrapper  tmp0, tmp1;
GraphStackWrapper  accel0x, accel0y, accel0z;
GraphStackWrapper  accel1x, accel1y, accel1z;

RollingLine2DTrace Ltemp0, Lacc0X;
Graph2D g;

void setup() {
  size(800, 300);
  frameRate(0200);

  tmp0 = new GraphStackWrapper();
  tmp1 = new GraphStackWrapper();

  accel0x = new GraphStackWrapper();
  accel0y = new GraphStackWrapper();
  accel0z = new GraphStackWrapper();

  accel1x = new GraphStackWrapper();
  accel1y = new GraphStackWrapper();
  accel1z = new GraphStackWrapper();

  Ltemp0  = new RollingLine2DTrace(tmp0, 200, .1);
  Ltemp0.setTraceColour(0, 0, 0);

  Lacc0X = new RollingLine2DTrace(accel0x, 200, .1);
  Lacc0X.setTraceColour(255, 0, 0);

  g = new Graph2D(this, 400, 200, false);
  g.setYAxisMax(50);

  g.addTrace(Ltemp0);
  g.addTrace(Lacc0X);

  g.position.y = 50;
  g.position.x = 100;
  g.setYAxisTickSpacing(20);
  g.setXAxisMax(5);
  g.setYAxisMin(-100);
  g.setXAxisLabel("Time");
  g.setYAxisLabel("Sensors");

  final String portName = Serial.list()[0];
  mySerial = new Serial(this, portName, 9600);
  println(portName);

  while (mySerial.read() != NUM)  print('.');

  println("Setup Done!\n[26]");
}


void draw() {
  if (mySerial.available() == 0)  return;

  //Grab data:
  final byte inByte = (byte) mySerial.read();
  if (count > 0)  byteBuffer[count-1] = inByte;

  if (count++ != NUM) return;

  print("\n[");
  print( hex(byteBuffer[1], 2) );

  print("][");
  print( hex(byteBuffer[0], 2) );

  print("]\t");

  for (int i = 0; i != 9; i++) {
    final float f = get4BytesFloat(byteBuffer, 4*i + 2);
    print( nf(f, 2, 3) );
    print('\t');

    if (i == 0)       tmp0.addValue(f);
    else if (i == 2)  accel0x.addValue(f*30);
  }

  count = 0;
  println('\n');

  background(0300);
  g.draw();
}

belimawr

Re: Re: Speed of Serial, it's too slow

4 months ago

Thanks!! Those changes speeded up a bit, but it's not as fast as I need... :(

PhiLho

Re: Speed of Serial, it's too slow

4 months ago

The conversion of bytes to float can be optimized, too:

void setup () {
byte[] data1 = { 0x12, 0x34, 0x56, 0x78 };
byte[] data2 = { (byte) 0xFF, 0x34, 0x56, 0x78 };
byte[] data3 = { 0x34, 0x56, 0x78, (byte) 0xFF };
println(get4BytesFloatSt(data1, 0));
println(get4BytesFloatSh(data1, 0));
println(get4BytesFloatSt(data2, 0));
println(get4BytesFloatSh(data2, 0));
println(get4BytesFloatSt(data3, 0));
println(get4BytesFloatSh(data3, 0));
exit();
}
float get4BytesFloatSt(byte[] data, int offset) {
String hexInt = hex(data[offset+3]) + hex(data[offset+2]) +
hex(data[offset+1]) + hex(data[offset]);
return Float.intBitsToFloat(unhex(hexInt));
}
float get4BytesFloatSh(byte[] data, int offset) {
int bInt =
((data[offset+3]) << 24) |
(data[offset+2] << 16) |
(data[offset+1] << 8) |
(data[offset] & 0x7F);
return Float.intBitsToFloat(bInt);
}

Would need more thorough tests, though.

belimawr

Re: Re: Speed of Serial, it's too slow

4 months ago

It didn't work with my real data... I just get NaN form your function...

PhiLho

Re: Speed of Serial, it's too slow

4 months ago

Ah, I see I forgot to mask out the ints:

void setup ()
{
byte[] data = new byte[4];
int c = 0;
for (int i = 0; i < 1000; i++)
{
for (int j = 0; j < data.length; j++)
{
data[j] = (byte) random(256);
}
if (Float.compare(
get4BytesFloatSt(data, 0),
get4BytesFloatSh(data, 0)) != 0)
{
c++;
}
}
println(c);
exit();
}
float get4BytesFloatSt(byte[] data, int offset)
{
String hexInt = hex(data[offset+3]) + hex(data[offset+2]) +
hex(data[offset+1]) + hex(data[offset]);
return Float.intBitsToFloat(unhex(hexInt));
}
float get4BytesFloatSh(byte[] data, int offset)
{
int bInt =
((data[offset+3] & 0xFF) << 24) |
((data[offset+2] & 0xFF) << 16) |
((data[offset+1] & 0xFF) << 8) |
(data[offset] & 0xFF);
return Float.intBitsToFloat(bInt);
}

The random testset shows that at least, the results are the same than the original function for a large range of data.
The problem is that when the bytes are converted to int (by the binary operators), the sign is propagating.