Sort game score and user name records

Programming Questions

jimmij

Sort game score and user name records

in Programming Questions • 3 years ago

Hello world!

I am writing a game, based on a how much users gain score.

My problem is: get every user name, his score, and sort it that way so the biggest score is at the top of the list.

(Also I would like to save score to file on a disk, so I have best record even after i restart the sketch)

here is the idea:

ricardo: 245

julia: 67

andreas: 22

john: 3

etc...

here's the prototype sketch for sorting and listing these scores. here you have to type scores manually (in game it will appear dynamically )

It works, however i believe it's the worst possible solution :)

my solution is to save score number into 3-digit string, then append name of a user, then sort it with sort() and then extract score and name again to human readable format.

so I really appreciate any tips mo make this algorithm more simple:

Here you have to type 3-digit number and the name of the user as one string

example: 022andreas, 245ricardo, 003john etc.

ArrayList names;
String msg=""; // name of a person
void setup()
{
size(400, 200);
names=new ArrayList();
}
void draw()
{
background(100);
String[] sorted=new String[names.size()]; // make temp string array which will be sorted
for (int i=0;i<names.size();i++)
{
sorted[i]=(String)names.get(i);
}
sorted = sort(sorted); // sort temp array
for (int i=0;i<sorted.length;i++) // make biggest score appear at the top of the list
{
println(sorted.length);
String number="";
String name=sorted[i].substring(3,sorted[i].length()); // get the name of a person
if (sorted[i].substring(0,1).equals("0"))
{
if (sorted[i].substring(1,2).equals("0"))
number=sorted[i].substring(2,3); // example score 005
else
number=sorted[i].substring(1,3); // example score 027
}
else number=sorted[i].substring(0,3); // example score 165
text(name+": "+number,20,40+map(i,0,sorted.length,sorted.length,0)*10); // map makes listing of biggest score at the top
}
text("type name and score in \"###name\" manner: "+msg, 20,20);
}
void keyPressed()
{
if (key==ENTER)
{
names.add(msg);
msg="";
}
else msg+=key;
}

Thanks,

jimmi

Replies(3)

PhiLho

Re: Sort game score and user name records

3 years ago

That's not a bad idea, actually, for a small set of data...
Note that you can easily convert an array list to an array:
String[] sorted = names.toArray(new String[0]); // The empty array is just to give the type of the array to the compiler
Actually, even better, you can just sort the array list:
Collections.sort(names);
and that's all...
Now, you can do something more efficient, by putting the data in a class, and either making it Comparable, or providing a Comparator to the sort() call. The topic has come a number of times in the forum, a search on the above keyword should give some results (or I should write this wiki entry I plan to do for quite some time now).

bjordal

Re: Sort game score and user name records

3 years ago

Why not create a score object, something like this

class ScoreHolder implements Comparable{
int score;
String name;
ScoreHolder(String n){
name = n;
score = 0;
}
void setScore(int s){
score = s;
}
void addToScore(int s){
score += s;
}
String toString(){
return name +": "+score; //can't remember is this will work, maybe you need to push it into a string first
}
int compareTo(Object o){
ScoreHolder sh = (ScoreHolder)o;
return score-sh.score;
}
}

i haven't tested this because i don't have processing on this computer (so there may be typos). But this way you can just store all the scores in a list and then just do Collection.sort();

jimmij

Re: Sort game score and user name records

3 years ago

Thank you so much philho and bjordal! :)

This makes me totally happy:

ArrayList scores;
void setup()
{
size(200, 600);
scores=new ArrayList();
}
void draw()
{
background(0);
Collections.sort(scores);
for (int i=0;i<scores.size();i++)
{
ScoreHolder temp=(ScoreHolder)scores.get(i);
fill(255);
text(temp.toString(), width/2, map(i, 0,scores.size(),scores.size(),0)*15+20);
}
fill(255, 255,0);
text("Click", 10, height-20);
}
void mousePressed()
{
String[] name= {
"Jim", "Ricardo", "Andreas", "Viki", "Tom", "Maria", "Niki", "Juliette"
};
scores.add(new ScoreHolder(name[(int)random(name.length)]));
}

class ScoreHolder implements Comparable{
int score;
String name;
ScoreHolder(String n){
name = n;
score = (int)random(512); // temp
}
void setScore(int s){
score = s;
}
void addToScore(int s){
score += s;
}
String toString(){
return name +": "+score;
}
int compareTo(Object o){
ScoreHolder sh = (ScoreHolder)o;
return score-sh.score;
}
}

Top Reply