Some advice for a newbie please

Programming Questions

andymc72

Some advice for a newbie please

in Programming Questions • 10 months ago

Hi,

I am trying to assist my daughter with a program however I have no experience within this industry at all. We have managed to get the basics of the program done whish are:-

Set up a basic grid (9 x 9 squares)

Place a circle within the centre point of that grid

add compass points around the outside of the grid

and some code that allows the circle to move from square to square in the direction of the compass point

What we need to be able to do now is stop the circle moving outside of the square. so place a boundary / constrain at set points. but this is baffling us.

Is there anyone I could forward the program to that may be able to assist us?

Cheers

Andy

Replies(4)

benja

Re: Some advice for a newbie please

10 months ago

I suppose there are many people here that would assist you. But posting the code here would be better than sending it to only one person. The chance of getting help is higher and others with a similar question could benefit from it as well.

andymc72

Re: Some advice for a newbie please

10 months ago

great idea,

Here is the code

int Side = 60;
int N = 11;
int W = N * Side,
    H = W;
PFont Font;
color Black = color(0, 0, 0),
      White = color(255, 255, 255),
      Yellow = color(255, 255, 0),
      Green = color(0, 255, 0),
      Red = color(255, 0, 0),
      Blue = color(0, 0, 255);
String[] Directions = {"NW", "W", "SW", "N", "S", "NE", "E", "SE"};
int Cx= W/2,
    Cy = Cx;

void setup() {
size(W, H);
   background(Green);//Sets canvas colour
Font = loadFont("Arial-BoldMT-36.vlw");
textFont(Font);
textAlign(CENTER);
DrawBoard();
}

void draw() {
int x = 0;
fill(Blue);
rect(x, 0, 60, 60);
rect(x + 300, 0, 60, 60);
rect(x + 600, 0, 60, 60);
rect(x, 300, 60, 60);
rect(x , 600, 60, 60);
rect(x + 600, 600, 60, 60);
rect(x + 300 , 600, 60, 60);
rect(x + 600, 300, 60, 60);
fill(Red);
text("NW",30,30);
text("N",330,30);
text("NE",630,30);
text("W",30,330);
text("SW",30,630);
text("E", 630,330);
text("SE",630,630);
text("S",330,630);

println("Implement DrawColouredSquare()");
}

void DrawBoard() {
     fill(Yellow);
rect(60, 60, 540, 540);
int i; //indexing variable
   stroke(Black);//Sets line colour
for(i = 0; i < N; i++) {    //Repeat for i in range 0..R-1
    line(60, Side * i, W-Side, Side * i); //Draw a line across
    line(Side * i, 60, Side * i, H-Side); //Draw a line down

   fill(Red);
      println("Implement DrawBoard()");
ellipse(Cx, Cy, Side, Side);
}

}

void mousePressed() {
if(mouseX < 60 && mouseY < 60) { //top left
    println("Here I am!!!!");
    Cx -= Side;
    Cy -= Side;
    DrawBoard();
}if(mouseX > 600 && mouseY >600) { //bottom right
    println("Here I am!!!!");
    Cx += Side;
    Cy += Side;
   DrawBoard();
   }if(mouseX > 600 && mouseY < 60) { // Top Right
    println("Here I am!!!!");
    Cx += Side;
    Cy -= Side;
   DrawBoard();
   }if(mouseX <60 && mouseY >600) { // bottom left
    println("Here I am!!!!");
    Cx -= Side;
    Cy += Side;
   DrawBoard();
}if(mouseX < 60 && mouseY > 300 && mouseY < 360){
    println("Here I am!!!!");
    Cx -= Side;
   DrawBoard();
   }if(mouseX >300 && mouseX <360 && mouseY < 60){
    println("Here I am!!!!");
    Cy -= Side;
   DrawBoard();
}if(mouseX >600 && mouseY > 300 && mouseY < 360){
    println("Here I am!!!!");
    Cx += Side;
   DrawBoard();
}if(mouseX >300 && mouseX < 360 && mouseY > 600){
    println("Here I am!!!!");
    Cy += Side;
   DrawBoard();
}
}

Any help is greatful to stop the ball moving outside the yellow zone

GoToLoop

Re: Re: Some advice for a newbie please

10 months ago

Hi AndyMC72!

I've made this function checkLimits() to correct ball's position if it would overstep grid's boundaries!
Besides that, also removed all constants and used variables only for drawing coordinates.
This way, variable S (formerly Size ) can be changed, and whole grid scales up!!!

P.S.: Newer version using whole board as a static background image!

/*
 * Ball in a Grid (v2.6)
 * by AndyMC72 (2012/Dec)
 * remixed by GoToLoop
 *
 * http://forum.processing.org/topic/some-advice-for-a-newbie-please
 */

final static byte   S = 80, SS = S>>1;
final static byte   N = 11;
final static short  W = N*S, H = W;
final static short  WW = W>>1, WS = W - S;

static int Cx = WW, Cy = Cx;

final static color Black  = 0;
final static color White  = 255;
final static color Red    = #FF0000;
final static color Green  = #00FF00;
final static color Blue   = #0000FF;
final static color Yellow = #FFFF00;

static PImage boardBG;

void setup() {

    size(W, H);
    noLoop();        // Turns draw() off!
    stroke(Black);
    rectMode(CORNER);

    //textFont( loadFont("Arial-BoldMT-36.vlw") );
    textAlign(CENTER);

    createBG();  // Draws board and save it as background image

    fill(Red);   // Sets color to draw circle within draw()
}

void draw() {

    background(boardBG);    //  Clears canvas using boardBG image

    ellipse(Cx, Cy, S, S);  //  Draws circle
}

void createBG() {

    background(Green);  // Clears canvas w/ green color

    drawBoard();        // Draws grid of lines
    drawCompass();      // Draws compass buttons.

    boardBG = get();    // Captures current canvas as an image
}

void drawBoard() {

    fill(Yellow);
    rect(S, S, WS-S, WS-S);

    for (byte i = 0; i < N; i++) {
        line(S, S * i, WS, S * i);    // Draws a line across
        line(S * i, S, S * i, H-S);   // Draws a line down
    }
}

void drawCompass() {

    fill(Blue);
    rect( 0, 0, S, S );
    rect( WW-SS, 0, S, S );
    rect( WS, 0, S, S );
    rect( 0, WW-SS, S, S );
    rect( 0, WS, S, S );
    rect( WS, WS, S, S );
    rect( WW-SS, WS, S, S );
    rect( WS, WW-SS, S, S );

    fill(Red);
    text( "NW", SS, SS );
    text( "N", WW, SS );
    text( "NE", W-SS, SS );
    text( "W", SS, WW );
    text( "SW", SS, W-SS );
    text( "E", W-SS, WW );
    text( "SE", W-SS, W-SS );
    text( "S", WW, W-SS );
}

void mousePressed() {

    if (mouseX < S && mouseY < S) { // Top left
        Cx -= S;
        Cy -= S;
    }
    else if (mouseX > WS && mouseY > WS) { // Bottom right
        Cx += S;
        Cy += S;
    }
    else if (mouseX > WS && mouseY < S) { // Top Right
        Cx += S;
        Cy -= S;
    }
    else if (mouseX < S && mouseY > WS) { // Bottom left
        Cx -= S;
        Cy += S;
    }
    else if (mouseX < S && mouseY > WW-SS && mouseY < WW+SS)
        Cx -= S;
    else if (mouseX > WW-SS && mouseX < WW+SS && mouseY < S)
        Cy -= S;
    else if (mouseX > WS && mouseY > WW-SS && mouseY < WW+SS)
        Cx += S;
    else if (mouseX > WW-SS && mouseX < WW+SS && mouseY > WS)
        Cy += S;

    checkLimits();  // Restrains circle within grid
    redraw();       // Reactivates draw() once
}

void checkLimits() {

    if (Cx > WS-SS)        Cx = WS-SS;
    else if (Cx < S+SS)    Cx = S+SS;

    if (Cy > H-S-SS)       Cy = H-S-SS;
    else if (Cy < S+SS)    Cy = S+SS;
}

benja

Re: Some advice for a newbie please

10 months ago

You are right, you have to check the position of the circle aggainst the bounds of your board before moving it.
Something like this would work:

void mousePressed() {
if(mouseX < 60 && mouseY < 60 && Cx-Side >= 60 && Cy-Side >= 60) { //top left
    println("Here I am!!!!");
    Cx -= Side;
    Cy -= Side;
    DrawBoard();
}if(mouseX > 600 && mouseY >600 && Cx+Side <= 600 && Cy+Side <= 600) { //bottom right
    println("Here I am!!!!");
    Cx += Side;
    Cy += Side;

[...]

Top Reply