Smoke simulation

Programming Questions

cheezcoder

in Programming Questions • 1 year ago

I'm pretty new to processing (okay, really new).
I was browsing through the learning section and found this.
I thought, "well, this is awesome! maybe I could use this..."

I was thinking that it could be used in a game I was making to make little fluffy explosions whenever an enemy died. After experimenting with it (basically just changing the size, renderer [to P2D, which improved speed by a longshot] and the contents of the res variable), I got really, really confused. I have no idea what vbuffer is, and the code is not commented at all... I couldn't figure out which part generated the particles from the bottom of the screen.

So could anyone give me some pointers to:

removing rising of smoke
creating new smoke with specified position, direction, and velocity... if it works that way

I have already commented out random gusts and mouse control but I can get some portion of them back if I need.

Thanks in advance,
cheezcoder

Replies(2)

Chrisir

Re: Smoke simulation

1 year ago

hello,

wow, that's complicated!

First: Where is the smoke set up?

the smoke is done in setup()

  for(int i = 0; i < pnum; i++) {
    p[i] = new particle(random(width/2-20,width/2+20),random(height-20,height));
  }

if you want to have it at position x and y go for

for(int i = 0; i < pnum; i++) {
p[i] = new particle(random(x-4,x+4),random(y-4,y+4));
}


or so.

Probably you want to have it occur when you smash / shoot / hit an enemy. 
Then in your shoot routine you have to make a call to a smoke routine 
where this

for(int i = 0; i < pnum; i++) {
p[i] = new particle(random(x-4,x+4),random(y-4,y+4));
}


happens.
Make pnum much much smaller. 


Second: Where can smoke particles be stopped? 

In

class particle

in method

void updatepos() {

it is checked whether the smoke particle is still on the screen:

if(vi > 0 && vi < lwidth && vu > 0 && vu < lheight) {

When it is, it moves.

Otherwise it is re-initialized:

else {
reposition();
}


there is also a random re-initializisation right after that:

if(random(0,400) < 1) {
reposition();
}


remove the last one. 

Give the class a property "dead".

boolean dead = false;


Instead of 

re-initializisation / reposition

set "dead" to true 

and when drawing etc. ignore all particles that are dead.
Later you can use an (or multiple) arraylist and just remove particles 
that are dead (faster).

for arraylist see reference
for multiple arraylist make an array of arraylists (or more complicated: 
an arraylist of arraylists).


Third: Other stuff 

Maybe remove randomGust as well.

Post your code here then. 

Greetings, Chrisir

cheezcoder

Re: Smoke simulation

1 year ago

Thank you so much! I'll post my code here when I'm done.

EDIT: Well, here is the smoke part. It's pretty slow, and I'm messing with the resolution and optimization throughout the game part of the sketch.

The way I've done it, any amount of enemies can have explosions running simultaneously, and the explosions can interact.

~~By the way, is there a way to create each particle traveling at a certain velocity? It would look more explosion-like, not a fuzzy, pixelated black block that slowly separates and floats into the sky.~~
Never mind, I did it by changing the xpos and ypos fields of the particles after they were created.

int res = 8;
int penSize = 30;
int lwidth;
int lheight;
int pnum = 1;
vsquare[][] v;
vbuffer[][] vbuf;
//particle[] p;
int pcount = 0;
int mouseXvel = 0;
int mouseYvel = 0;
ArrayList p;

void setupSmoke() {
lwidth = width/res;
lheight = height/res;
v = new vsquare[lwidth+1][lheight+1];
vbuf = new vbuffer[lwidth+1][lheight+1];
//p = new particle[pnum];
p = new ArrayList();
noStroke();
for(int i = 0; i < pnum; i++) {
    p.add(new particle(random(width/2-20,width/2+20), random(height-20,height)));
}
for(int i = 0; i <= lwidth; i++) {
    for(int u = 0; u <= lheight; u++) {
      v[i][u] = new vsquare(i*res,u*res);
      vbuf[i][u] = new vbuffer(i*res,u*res);
    }
}
}

void drawSmoke()
{
int axvel = mouseX-pmouseX;
int ayvel = mouseY-pmouseY;

mouseXvel = (axvel != mouseXvel) ? axvel : 0;
mouseYvel = (ayvel != mouseYvel) ? ayvel : 0;

for(int i = 0; i < lwidth; i++) {
    for(int u = 0; u < lheight; u++) {
      vbuf[i][u].updatebuf(i,u);
      v[i][u].col = 0;
    }
}
for(int i = 0; i < p.size(); i++) {
    particle checking = (particle) p.get(i);
    if (!checking.dead)
      checking.updatepos();
    else
      p.remove(i);
}
for(int i = 0; i < lwidth; i++) {
    for(int u = 0; u < lheight; u++) {
      v[i][u].addbuffer(i, u);
      v[i][u].updatevels(mouseXvel, mouseYvel);
      v[i][u].display(i, u);
    }
}
}

class particle
{
float x;
float y;
float xvel;
float yvel;
float temp;
int pos;
boolean dead;

particle(float xIn, float yIn) {
    x = xIn;
    y = yIn;
    dead = false;
}

void reposition() {
    x = width/2+random(-20,20);
    y = random(height-10,height);

    xvel = random(-1,1);
    yvel = random(-1,1);
}

void updatepos() {
    int vi = (int)(x/res);
    int vu = (int)(y/res);

    if(vi > 0 && vi < lwidth && vu > 0 && vu < lheight) {
      v[vi][vu].addcolour(2);

      float ax = (x%res)/res;
      float ay = (y%res)/res;

      xvel += (1-ax)*v[vi][vu].xvel*0.05;
      yvel += (1-ay)*v[vi][vu].yvel*0.05;

      xvel += ax*v[vi+1][vu].xvel*0.05;
      yvel += ax*v[vi+1][vu].yvel*0.05;

      xvel += ay*v[vi][vu+1].xvel*0.05;
      yvel += ay*v[vi][vu+1].yvel*0.05;

      v[vi][vu].yvel -= (1-ay)*0.003;
      v[vi+1][vu].yvel -= ax*0.003;

      if(v[vi][vu].yvel < 0) v[vi][vu].yvel *= 1.00025;

      x += xvel;
      y += yvel;
    }
    else {
      dead = true;
    }
    if(random(0,400) < 1) {
      dead = true;
    }
    xvel *= 0.6;
    yvel *= 0.6;
}
}

class vbuffer
{
int x;
int y;
float xvel;
float yvel;
float pressurex = 0;
float pressurey = 0;
float pressure = 0;

vbuffer(int xIn,int yIn) {
    x = xIn;
    y = yIn;
    pressurex = 0;
    pressurey = 0;
}

void updatebuf(int i, int u) {
    if(i>0 && i<lwidth && u>0 && u<lheight) {
      pressurex = (v[i-1][u-1].xvel*0.5 + v[i-1][u].xvel + v[i-1][u+1].xvel*0.5 - v[i+1][u-1].xvel*0.5 - v[i+1][u].xvel - v[i+1][u+1].xvel*0.5);
      pressurey = (v[i-1][u-1].yvel*0.5 + v[i][u-1].yvel + v[i+1][u-1].yvel*0.5 - v[i-1][u+1].yvel*0.5 - v[i][u+1].yvel - v[i+1][u+1].yvel*0.5);
      pressure = (pressurex + pressurey)*0.25;
    }
}
}

class vsquare {
int x;
int y;
float xvel;
float yvel;
float col;

vsquare(int xIn,int yIn) {
    x = xIn;
    y = yIn;
}

void addbuffer(int i, int u) {
    if(i>0 && i<lwidth && u>0 && u<lheight) {
      xvel += (vbuf[i-1][u-1].pressure*0.5
      +vbuf[i-1][u].pressure
      +vbuf[i-1][u+1].pressure*0.5
      -vbuf[i+1][u-1].pressure*0.5
      -vbuf[i+1][u].pressure
      -vbuf[i+1][u+1].pressure*0.5
      )*0.49;
      yvel += (vbuf[i-1][u-1].pressure*0.5
      +vbuf[i][u-1].pressure
      +vbuf[i+1][u-1].pressure*0.5
      -vbuf[i-1][u+1].pressure*0.5
      -vbuf[i][u+1].pressure
      -vbuf[i+1][u+1].pressure*0.5
      )*0.49;
    }
}

void updatevels(int mvelX, int mvelY) {
    float adj;
    float opp;
    float dist;
    float mod;

//    if(mousePressed) {
//      adj = x - mouseX;
//      opp = y - mouseY;
//      dist = sqrt(opp*opp + adj*adj);
//      if(dist < penSize) {
//        if(dist < 4) dist = penSize;
//        mod = penSize/dist;
//        xvel += mvelX*mod;
//        yvel += mvelY*mod;
//      }
//    }
    xvel *= 0.99;
    yvel *= 0.98;
}

void addcolour(int amt) {
    col += amt;
    if(col > 196) col = 196;
}

void display(int i, int u) {
    float tcol = 0;
    if(i>0 && i<lwidth-1 && u>0 && u<lheight-1) {

      tcol = (+ v[i][u+1].col
      + v[i+1][u].col
      + v[i+1][u+1].col*0.5
      )*0.3;
      tcol = (int)(tcol+col*0.5);
    }

    noStroke();
    fill(255-tcol, 255-tcol, 255-tcol);
    rect(x,y,res,res);
    col = 0;
}
}