small problem l-system koch curve etc

Programming Questions

alexx600

small problem l-system koch curve etc

in Programming Questions • 8 months ago

Hello. I have small problem. I wrote small program to generate this things. If THETA is 90 degree everythings looks ok.When theta for example is 60 It works bad.

This is my code. Maybe somone can help me.

PVector pos;//<start position

void setup()

{

float p=1.5;//extra variable to simple change size

size(int(800*p),int( 800*p));

noLoop();

background(#ffffff);

pos=new PVector(800*p/2,400*p/2);//<start position

}

//-----------------------------

//

String L_string = "+F+F+F+F";

//String change="F-F+F+FF-F-F+F";

String change="FF-F-F-F-F-F+F";

int n=3;//iteration number

//-----------------------------

int F=int(10); //how long single line is

float THETA=PI/2;

//-------------------------------

//-------------------------------

void draw()

{

println(L_string+" <-String in beginning ");

for(int i=0;i<n;i=i+1)//n-number of iterations,it generate string

{

L_string=Make_String(L_string,change);

println(L_string+" <-String in end");

}

background(#ffffff);

draw_String(L_string,THETA,F);

}

//-------------------------------

//-------------------------------

String Make_String(String L_string,String change)

{

//I am creating array

String[] L_STRING = new String[L_string.length()];

//----------------------------------------

//fill in array

for (int i = 0; i < L_string.length(); i = i+1)

{

L_STRING[i]=""+L_string.charAt(i);

if(L_string.charAt(i)=='F')

{L_STRING[i]=change;}

}

//----------------------------------------

int W=L_string.length();

//I add new variable because i will change string

//it create string from array

L_string="";

for (int i = 0; i < W; i = i+1)

{

L_string=L_string+L_STRING[i];

}

return(L_string);

}

//-------------------------------

//-------------------------------

void draw_String(String L_string,float TETA,int F)

{

float R=0;

for (int i = 0; i < L_string.length(); i = i+1)

{

//if rotation is multiple of 360 i can remove it

if(R>=2*PI)

{R=R-2*PI;}

if(R<-2*PI)

{R=R+2*PI;}

if(L_string.charAt(i)=='F'){

//extra variables

int x=int(F*cos(R+PI/2));

int y= int(F*sin(R+PI/2));

line(pos.x,pos.y,pos.x- x,pos.y-y);

pos.x-= x;

pos.y-= y;}

if(L_string.charAt(i)=='+')

{//turn right

R+=THETA;}

if(L_string.charAt(i)=='-')

{//turn left

R-=THETA;}

}

print(R);

}

Replies(4)

Chrisir

Re: small problem l-system koch curve etc

8 months ago

honestly? I have no idea.

But since nobody answers:

I am sure you know about degrees and radians. You do all in radians. Fine.

Then another thing:

I do not have any knowledge on L-Systems but couldn't it be when the angle Theta is not compatible with the pattern you defined with the string, it doesn't look great? What I mean is you have only a nice symmetrical form without overlapping when the angle executed n times by the String-pattern results in a form that is closing on itself like a circle. I don't think every pattern matches every Theta, n or length if you know what I mean. Maybe onle 90° and 180° work for your pattern, who knows.

Anyway, I made some adjustements and a figure with Theta=60° looks ok for me now. I mainly changed some vars to float (F) and forced some vars to come out as float (R) by using (float) - it's called casting. Because afaik accidently processing / JAVA can come to treat a float like an int and lose its decimals (e.g. I guess when you multiply a float with an int or with 3 (looking like an int) processing goes, "hey, 3 looks like an int let's make the result int too"). Those roundings or cutting off decimals can destroy values in the long run. Bad.
But that might just be an urban legend... or I misunderstood. It's a guess. Are you more content with the result now?

BTW: Did you post the sketch with Theta = 90°? So you posted the working sketch not the one you had problems with, right?

Good luck to you and congrats to an impressive program!

Greetings, Chrisir

PVector pos;//<start position
void setup()
{
float p=2.5;//extra variable to simple change size
size(int(800*p), int( 800*p));
noLoop();
background(#ffffff);
pos=new PVector(800*p/2, 400*p/2);//<start position
}
//-----------------------------
//
String L_string = "+F+F+F+F";
//String change="F-F+F+FF-F-F+F";
String change="FF-F-F-F-F-F+F";
int n=3;//iteration number
//-----------------------------
float F=(39.0); //how long single line is
// float THETA = PI/2 ;
float THETA = radians(60); // ((PI/2.0) / 3.0) * 2.0 ; // // // PI/2 ; // There are 360 degrees in a circle and 2*PI radians in a circle. 90° = PI/2 = 1.5707964.
//-------------------------------
//-------------------------------
void draw()
{
// scale(.3311);
println(L_string+" <-String in beginning ");
for (int i=0;i<n;i=i+1)//n-number of iterations,it generate string
{
L_string=Make_String(L_string, change);
println(L_string+" <-String in end");
}
background(#ffffff);
draw_String(L_string, THETA, F);
}
//-------------------------------
//-------------------------------
String Make_String(String L_string, String change)
{
//I am creating array
String[] L_STRING = new String[L_string.length()];
//----------------------------------------
//fill in array
for (int i = 0; i < L_string.length(); i = i+1)
{
L_STRING[i]=""+L_string.charAt(i);
if (L_string.charAt(i)=='F')
{
L_STRING[i]=change;
}
}
//----------------------------------------
int W=L_string.length();
//I add new variable because i will change string
//it create string from array
L_string="";
for (int i = 0; i < W; i = i+1)
{
L_string=L_string+L_STRING[i];
}
return(L_string);
}
//-------------------------------
//-------------------------------
void draw_String(String L_string, float TETA, float F)
{
float R=0.0;
for (int i = 0; i < L_string.length(); i = i+1)
{
//if rotation is multiple of 360 i can remove it
if (R>=2*PI)
{
R=(float)R-2.0*PI;
}
if (R<-2*PI)
{
R=(float)R+2.0*PI;
}
if (L_string.charAt(i)=='F') {
//extra variables
float x=(float)(F*cos(R+PI/2.0));
float y=(float)(F*sin(R+PI/2.0));
line(pos.x, pos.y, pos.x- x, pos.y-y);
pos.x-= x;
pos.y-= y;
}
if (L_string.charAt(i)=='+')
{//turn right
R=(float)(R+THETA);
}
if (L_string.charAt(i)=='-')
{//turn left
// R-=THETA;
R=(float)(R-THETA);
}
}
print(R);
}

asimes

Re: small problem l-system koch curve etc

8 months ago

This is almost it. There must be something funny about the rules for changing the string but I haven't worked with an L-System for too long to see it. Sorry I changed your spacing so much, but this is how I am used to reading:

PVector pos;
void setup() {
size(800, 800); // This was too big for my screen
noLoop();
background(#ffffff);
pos = new PVector(width>>1, height>>1);
}
String L_string = "F--F--F";
String change = "F+F--F+F";
int n = 3;
int F = 10;
float THETA = PI/3;
void draw() {
println(L_string+" <-String in beginning");
for (int i = 0; i < n; i++) {
L_string = Make_String();
//println(L_string+" <-String in end");
}
draw_String();
}
String Make_String() { // Don't need to pass Global variables
String[] L_STRING = new String[L_string.length()];
for (int i = 0; i < L_string.length(); i++) {
if (L_string.charAt(i) == 'F') L_STRING[i] = change;
else L_STRING[i] = ""+L_string.charAt(i);
}
int W = L_string.length();
L_string = "";
for (int i = 0; i < W; i++) L_string = L_string+L_STRING[i];
return(L_string);
}
void draw_String() { // Don't need to pass Global variables
float R = 0;
for (int i = 0; i < L_string.length(); i++) {
if (R >= TWO_PI || R <= -TWO_PI) R %= TWO_PI;
if (L_string.charAt(i) == 'F') {
int x = int(F*cos(R));
int y = int(F*sin(R));
line(pos.x, pos.y, pos.x-x, pos.y-y);
pos.x -= x;
pos.y -= y;
}
else if (L_string.charAt(i) == '+') R += THETA;
else if (L_string.charAt(i) == '-') R -= THETA;
}
//print(R);
}

asimes

Re: small problem l-system koch curve etc

8 months ago

This version works completely, the problem with the one before it was that x and y inside of draw_String() had rounding errors from being integers:

PVector pos;
void setup() {
size(800, 800); // This was too big for my screen
noLoop();
background(#ffffff);
pos = new PVector(width>>1, height>>1);
}
String L_string = "F--F--F";
String change = "F+F--F+F";
int n = 3;
int F = 10;
float THETA = PI/3;
void draw() {
println(L_string+" <-String in beginning");
for (int i = 0; i < n; i++) Make_String();
draw_String();
}
void Make_String() {
String temp = "";
for (int i = 0; i < L_string.length(); i++) {
if (L_string.charAt(i) == 'F') temp += change;
else temp += ""+L_string.charAt(i);
}
L_string = temp;
}
void draw_String() {
float R = 0;
for (int i = 0; i < L_string.length(); i++) {
if (R >= TWO_PI || R <= -TWO_PI) R %= TWO_PI;
if (L_string.charAt(i) == 'F') {
float x = pos.x+F*cos(R);
float y = pos.y+F*sin(R);
line(pos.x, pos.y, x, y);
pos.x = x;
pos.y = y;
}
if (L_string.charAt(i) == '+') R += THETA;
if (L_string.charAt(i) == '-') R -= THETA;
}
}

alexx600

Re: small problem l-system koch curve etc

8 months ago

processing community is great! Thanks for really quick and proffesional answers.

@ Chrisir I now the difference between degree and radians. Yes i used Theta 90. I would't say my program is impressive but thanks:)

@ asimes

Thanks it works perfect now:)

Your code is so clear and much more simple.

I will never pass global variable in functon, trick which %2*PI is also great! Finally I don't need to add extra array in Make_string function, I learned a lot:)