Slider objects, only 1 working

Programming Questions

mimzi87

Slider objects, only 1 working

in Programming Questions • 2 years ago

Hello,

I'm new to using objects and classes, and having some kind of logic problem with sliders. I hav 2 sliders, A and B. B works perfectly, but A doesn't reset when I let go. Can anyone see why and help me, please? Thanks!

Slider sliderA;

Slider sliderB;

int topRowY = 4;

int topRowY2 = 306;

int midRowY = 348;

int midRowY2 = 568;

int bottomRowY = 610;

int bottomRowY2 = 674;

int bracketHeight = 10;

int sliderPositionA;

int sliderPositionB;

void setup(){

rectMode(CORNER);

smooth();

size(1408, bottomRowY2+4);

background(255);

sliderA = new Slider(topRowY2 +bracketHeight + 2, 5, 1);

sliderB = new Slider(midRowY2 +bracketHeight + 2, 64, 5);

sliderPositionA = 4;

sliderPositionB = 4;

sliderA.displaySlider(sliderPositionA);

sliderB.displaySlider(sliderPositionB);

}

void draw(){

//sliderA.displaySlider(sliderPositionA);

//sliderB.displaySlider(sliderPositionB);

if (mouseY > topRowY2 && mouseX < midRowY){

sliderA.mouseOverCheck(sliderPositionA);

}

if (mouseY > midRowY2 && mouseY < bottomRowY){

sliderB.mouseOverCheck(sliderPositionB);

}

void mousePressed(){

sliderA.sliderPressed();

sliderB.sliderPressed();

}

void mouseDragged(){

sliderPositionA = sliderA.sliderDraggedPosition(sliderPositionA);

sliderPositionB = sliderB.sliderDraggedPosition(sliderPositionB);

sliderA.displaySlider(sliderPositionA);

sliderB.displaySlider(sliderPositionB);

}

void mouseReleased(){

sliderA.sliderReleasedLogic();

sliderB.sliderReleasedLogic();

}

class Slider {

//these are global variables for the class

int sliderY;

int daysInRow;

int daysInBracket;

int sliderX;

int arrowHeight = 16;

int arrowWidth = 10;

int sliderX2 = sliderX + arrowWidth;

int sliderY2 = sliderY + bracketHeight*2 + arrowHeight;

int sliderPosition;

int bracketWidth;

boolean sliderOver;

boolean sliderLocked;

//this is the constructor

Slider(int tempSliderY, int tempDaysInRow, int tempDaysInBracket) {

sliderY = tempSliderY;

daysInRow = tempDaysInRow;

daysInBracket = tempDaysInBracket;

}

//these are functions that live within slider

//draws the slider at the x position it is given in the parameter. x is middle of arrow/ bracket

void displaySlider(int tempSliderPosition) {

//makes bracket width of the

bracketWidth = (width/ daysInRow) * daysInBracket;

//draw rectangles to clear slider

fill(255);

noStroke();

rectMode(CORNER);

rect(0, sliderY - bracketHeight, 1408, sliderY + arrowHeight + bracketHeight);

//draw triangles

fill(0);

stroke(0);

beginShape();

vertex(tempSliderPosition - arrowWidth/2 + bracketWidth/2, sliderY);

vertex(tempSliderPosition + arrowWidth/2 + bracketWidth/2, sliderY);

vertex(tempSliderPosition - arrowWidth/2 + bracketWidth/2, sliderY + arrowHeight);

vertex(tempSliderPosition + arrowWidth/2 + bracketWidth/2, sliderY + arrowHeight);

endShape();

//draw top bracket

noFill();

beginShape();

vertex(4, sliderY - bracketHeight);

vertex(4, sliderY);

vertex(1404, sliderY);

vertex(1404, sliderY - bracketHeight);

endShape();

//drawMovingBracket

beginShape();

vertex(tempSliderPosition, sliderY + arrowHeight + bracketHeight);

vertex(tempSliderPosition, sliderY + arrowHeight);

vertex(tempSliderPosition + bracketWidth, sliderY + arrowHeight);

vertex(tempSliderPosition + bracketWidth, sliderY + arrowHeight + bracketHeight);

endShape();

}

//this checks if mouse is over bracket and says "yea, hey, I'm totally over bracket"

void mouseOverCheck(int tempSliderPosition){

sliderOver = false;

if (mouseX > (tempSliderPosition - arrowWidth/2 + bracketWidth/2 - 4)

&& mouseX < (tempSliderPosition + arrowWidth/2 + bracketWidth/2 +4)

&& mouseY > (sliderY -4) && mouseY < (sliderY + arrowHeight +4)) {

sliderOver = true;

println(sliderOver);

}

else {

sliderOver = false;

println(sliderOver);

}

if (sliderOver = true){

cursor(HAND);

}

else if (sliderOver = false){

cursor(CROSS);

}

void sliderPressed(){

if (sliderOver) {

sliderLocked = true;

}

else {

sliderLocked = false;

}

int sliderDraggedPosition(int tempSliderPosition){

if (sliderLocked){

mouseX = constrain(mouseX, 4, width - bracketWidth/2 - 4);

int position = mouseX;

//println(position);

return position;

}

else {

return tempSliderPosition;

}

void sliderReleasedLogic(){

sliderLocked = false;

}

Replies(1)

PhiLho

Re: Slider objects, only 1 working

2 years ago

I think I fixed the issues. I will try and remember most of the changes I made:
- Moved global variables like sliderPositionA to the class. If you need to know the value, make a getter, ie. a method returning this position.
- Renamed the fields and methods inside the class: no need to repeat the name of the class there, we know they belong to the class!
- Changed the position to be the center of the handle. More logical, and the arrows follow the mouse more closely...
- Changed the cursor logic. It must be managed at the global level, otherwise there is a conflict.
- Used booleans as variables: no need to do if (a) b = true else b= false, you can do assignments! Also beware of not using if (a = true), you are making an assignment inside the condition! That's why I prefer if (a), and it is less redundant too.
- I added a background() call in draw(), because it is likely it will happen there if you do something else. I kept the slider erasing code, because you might need a different refresh logic inside the global logic of the application.

Hope this helps.

Slider sliderA;
Slider sliderB;
int topRowY = 4;
int topRowY2 = 306;
int midRowY = 348;
int midRowY2 = 568;
int bottomRowY = 610;
int bottomRowY2 = 674;
void setup() {
size(1008, bottomRowY2+4);
rectMode(CORNER);
smooth();
background(255);
sliderA = new Slider(topRowY2 + 2, 5, 1);
sliderB = new Slider(midRowY2 + 2, 64, 5);
}
void draw() {
background(255);
sliderA.display();
sliderB.display();
boolean isOverA = sliderA.mouseOverCheck();
boolean isOverB = sliderB.mouseOverCheck();
if (isOverA || isOverB) cursor(HAND);
else cursor(CROSS);
}
void mousePressed() {
sliderA.pressed();
sliderB.pressed();
}
void mouseDragged() {
sliderA.dragged();
sliderB.dragged();
}
void mouseReleased() {
sliderA.released();
sliderB.released();
}
class Slider {
//these are global variables for the class
int daysInRow;
int daysInBracket;
int arrowHeight = 16;
int arrowWidth = 10;
int bracketWidth;
int bracketHeight = 10;
int xPos = 4;
int yPos;
int sWidth; // Here I don't use width to avoid masking the global 'width' variable
int handlePosition;
boolean isOver;
boolean isLocked;
//this is the constructor
Slider(int tempyPos, int tempDaysInRow, int tempDaysInBracket) {
daysInRow = tempDaysInRow;
daysInBracket = tempDaysInBracket;
yPos = tempyPos + bracketHeight;
sWidth = width - 2 * xPos;
//makes bracket width of the
bracketWidth = (width / daysInRow) * daysInBracket;
constrainHandle();
}
//these are functions that live within slider
//draws the slider at the x position it is given in the parameter. x is middle of arrow/ bracket
void display() {
//draw rectangles to clear slider
fill(255);
noStroke();
rectMode(CORNER);
rect(xPos, yPos - bracketHeight, sWidth, yPos + arrowHeight + bracketHeight);
//draw triangles
fill(0);
stroke(0);
beginShape();
vertex(handlePosition - arrowWidth/2, yPos);
vertex(handlePosition + arrowWidth/2, yPos);
vertex(handlePosition - arrowWidth/2, yPos + arrowHeight);
vertex(handlePosition + arrowWidth/2, yPos + arrowHeight);
endShape();
//draw top bracket
noFill();
beginShape();
vertex(xPos, yPos - bracketHeight);
vertex(xPos, yPos);
vertex(xPos + sWidth, yPos);
vertex(xPos + sWidth, yPos - bracketHeight);
endShape();
//drawMovingBracket
beginShape();
vertex(handlePosition - bracketWidth/2, yPos + arrowHeight + bracketHeight);
vertex(handlePosition - bracketWidth/2, yPos + arrowHeight);
vertex(handlePosition + bracketWidth/2, yPos + arrowHeight);
vertex(handlePosition + bracketWidth/2, yPos + arrowHeight + bracketHeight);
endShape();
}
void constrainHandle() {
handlePosition = constrain(mouseX, xPos + bracketWidth/2 + 4, sWidth - bracketWidth/2 - 4);
}
//this checks if mouse is over bracket and says "yea, hey, I'm totally over bracket"
boolean mouseOverCheck() {
isOver = mouseX > (handlePosition - arrowWidth/2 - 4) &&
mouseX < (handlePosition + arrowWidth/2 + 4) &&
mouseY > (yPos - 4) && mouseY < (yPos + arrowHeight + 4);
// println(isOver);
// The two sliders are competiting for this one, must be resolved at global level
// if (isOver) cursor(HAND);
// else cursor(CROSS);
return isOver;
}
void pressed() {
isLocked = isOver;
}
void dragged() {
if (isLocked) {
constrainHandle();
//println(handlePosition);
}
}
void released() {
isLocked = false;
}
}

Top Reply