Size of the drawing Logic fail

Programming Questions

curoiusbr..

Size of the drawing Logic fail

in Programming Questions • 1 month ago

Hi,

Here I have written a code which should detect the size of the shape drawn on the screen and draw rectangle around it but the problem is it only saves the min value of the (x,y) coordinates of the shape and doesn't save the max value of coordinates instead it saves the last coordinates of the mouse.

Any help ?

int flag=0;
ArrayList poop;
PVector PVprep, SaveMax, SaveMin;
void setup()
{
size(400, 400);
smooth();
poop = new ArrayList();
PVprep = new PVector(0, 0);
SaveMax = new PVector(0, 0);
SaveMin = new PVector(0, 0);
}
void draw()
{
background(255);
for (int i=0;i<poop.size();i++)
{
PVector PV = (PVector) poop.get(i);
stroke(0);
line(PV.x, PV.y, PVprep.x, PVprep.y);
if (PV.x > SaveMax.x)
{
SaveMax.x = PV.x;
}
if (PV.x < SaveMax.x)
{
SaveMin.x = PV.x;
}
if (PV.y > SaveMax.y)
{
SaveMax.y = PV.y;
}
else if (PV.y < SaveMax.y)
{
SaveMin.y = PV.y;
}
PVprep = PV;
}
if (flag==1)
{
noFill();
stroke(255, 0, 0);
rect(SaveMin.x, SaveMin.y, abs(SaveMin.x - SaveMax.x), abs(SaveMin.y-SaveMax.y));
}
println( "SaveMin.x " + SaveMin.x + " SaveMin.y " + SaveMin.y + " SaveMax.x " + SaveMax.x + " SaveMax.y " + SaveMax.y );
}
void mouseDragged()
{
PVector P = new PVector(mouseX, mouseY);
poop.add(P);
flag=0;
}
void mouseReleased()
{
flag=1;
}

Replies(4)

GoToLoop

Re: Size of the drawing Logic fail

1 month ago

Got no idea. But since I was re-factoring your code to try to understand its logic, I'll post it anyways:

final ArrayList<PVector> coords = new ArrayList();
final PVector pvPrev = new PVector();
final PVector saveMax = new PVector(), saveMin = new PVector();

boolean flag;

void setup() {
  size(400, 400);
  smooth();
  noLoop();
  noFill();
}

void draw() {
  background(-1);
  stroke(0);

  for (int i = 0, ii = coords.size(); i != ii;) {
    final PVector pv = coords.get(i++);

    line(pv.x, pv.y, pvPrev.x, pvPrev.y);

    saveMax.x = max(pv.x, saveMax.x);
    if (pv.x < saveMax.x) saveMin.x = pv.x;

    saveMax.y = max(pv.y, saveMax.y);
    if (pv.y < saveMax.y) saveMin.y = pv.y;

    pvPrev.set(pv);
  }

  if (flag) {
    stroke(#FF0000);

    rect(saveMin.x, saveMin.y, 
    saveMax.x - saveMin.x, saveMax.y - saveMin.y);
  }

  println( "saveMin.x " + saveMin.x + " saveMin.y " +  saveMin.y
    + " saveMax.x " +  saveMax.x + " saveMax.y " +  saveMax.y );
}

void mouseDragged() {
  coords.add( new PVector(mouseX, mouseY) );
  flag = false;
  redraw();
}

void mouseReleased() {
  flag = true;
  redraw();
}

asimes

Re: Size of the drawing Logic fail

1 month ago

The problem was in initializing SaveMin as (0, 0), it already is the minimum. The code works (no error), but normally people use capital letters for classes. Here's code:

boolean flag = false;
ArrayList<PVector> poop;
PVector pvPrep, saveMax, saveMin;
void setup() {
size(400, 400);
smooth();
poop = new ArrayList<PVector>();
pvPrep = new PVector();
saveMax = new PVector(0, 0);
saveMin = new PVector(width, height);
}
void draw() {
background(255);
for (int i = 0; i < poop.size(); i++) {
PVector pv = poop.get(i);
stroke(0);
line(pv.x, pv.y, pvPrep.x, pvPrep.y);
pvPrep = pv;
}
if (flag) {
noFill();
stroke(255, 0, 0);
rect(saveMin.x, saveMin.y, saveMax.x-saveMin.x, saveMax.y-saveMin.y);
}
println("saveMin.x "+saveMin.x+" saveMin.y "+saveMin.y+" saveMax.x "+saveMax.x+" saveMax.y "+saveMax.y);
}
void mouseDragged() {
PVector p = new PVector(mouseX, mouseY);
poop.add(p);
flag = false;
}
void mouseReleased() {
flag = true;
for (int i = 0; i < poop.size(); i++) {
PVector pv = poop.get(i);
if (saveMin.x > pv.x) saveMin.x = pv.x;
if (saveMin.y > pv.y) saveMin.y = pv.y;
if (saveMax.x < pv.x) saveMax.x = pv.x;
if (saveMax.y < pv.y) saveMax.y = pv.y;
}
}

curoiusbr..

Re: Size of the drawing Logic fail

1 month ago

Thanks a lot asimes :)

but can you tell me where is the problem

asimes

Re: Size of the drawing Logic fail

1 month ago

From the original code:

SaveMin = new PVector(0, 0);
}
void draw()
{
background(255);
for (int i=0;i<poop.size();i++)
{
PVector PV = (PVector) poop.get(i);
stroke(0);
line(PV.x, PV.y, PVprep.x, PVprep.y);
if (PV.x > SaveMax.x)
{
SaveMax.x = PV.x;
}
if (PV.x < SaveMax.x)
{
SaveMin.x = PV.x;
}
if (PV.y > SaveMax.y)
{
SaveMax.y = PV.y;
}
else if (PV.y < SaveMax.y)
{
SaveMin.y = PV.y;
}

SaveMin needs to be initialized as (width, height) and you need to compare SaveMin.x and SaveMin.y instead of SaveMax.x and SaveMax.y when assigning SaveMin.

Top Reply