Loading...
Logo
Processing Forum
General Discussion Other
alejost848
alejost848

Simple shooting with keyPressed

in General Discussion  •  Other  •  6 months ago  
Hello everybody. As an assignment for my Programming class I have to make a Space Invaders alike game. I'm trying to shoot everytime I press the space bar, but so far it only shoots once.

I did a "for" to display 5 images (the bullets), but they appear all at the same time and I just need one to appear at a time. Could anyone help me with this please?

How do I get it to display one image everytime I press the space bar and the max amount of them being 5?

Replies(6)

Chrisir
Chrisir

Re: Simple shooting with keyPressed

6 months ago
alejost848
alejost848

Re: Simple shooting with keyPressed

6 months ago
Thanks, but that is very complex, I need something simpler (I´m new to programming). Well, about my code... (I don't show you the whole because there are 11 tabs).

Copy code
  1. bulletVisible=false;
  2. bullet = new Bullet[9];
  3. for (int i=0; i<9; i++) {     
  4.       bullet[i]= new Bullet(character.getPosX(), 500+i*50); //Display the bullets at the position where the character was when shooting
  5.     }
  6.  

Copy code
  1. for (int i=0; i<9; i++) {
  2.         if (bulletVisible==true) {
  3.           bullet[i].display();
  4.           bullet[i].move();
  5.          }
  6. }


Copy code
  1. void spaceKey(){
  2.     for (int i=0; i<9; i++) {
  3.       if (keyCode==' ') {
  4.         bulletVisible=true;
  5.         bullet[i].setPosX(character.getPosX());
  6.       }
  7.     }
  8. }
Chrisir
Chrisir

Re: Simple shooting with keyPressed

6 months ago


ok....

make bulletVisible part of the class Bullet
because you need to know for each bullet if it's visible


is this
Copy code
  1. for (int i=0; i<9; i++) {     
  2.       bullet[i]= new Bullet(character.getPosX(), 500+i*50); //Display the bullets at the position where the character was when shooting
  3.     }
in setup() ?

You should do this in the function spaceKey() . Because when the player moves it is not at the same position as it was in setup().

Also in the function spaceKey() don't use a for-loop.
Just make one more bullet visible. You can use a for-loop to
  • find a bullet with bulletVisible == false and
  • then set bulletVisible for this bullet to true.
  • And then immediately leave the for-loop because you don't want to set two bullet's bulletVisible to true.
An arraylist would be better than an array btw.

Also if they leave the screen or hit something, set bulletVisible for this bullet to false (in move or so)

Anyway, also keyReleased could be better than keyPressed, I don't know.

Greetings, Chrisir    


alejost848
alejost848

Re: Simple shooting with keyPressed

6 months ago
Thanks for your help! I have seen lots of examples using ArrayList, but we haven't studied that yet, so I'll be doing it with arrays.
Chrisir
Chrisir

Re: Simple shooting with keyPressed

6 months ago

here....

note that I use inbuild function keyReleased
instead of spaceKey().


Copy code
  1. //
  2. Bullet[] bullet;
  3. //
  4. void setup () {
  5.   size(900, 900);
  6.   background(0);
  7.   //
  8.   bullet = new Bullet[9];
  9.   for (int i=0; i<9; i++) {    
  10.     bullet[i]= new Bullet(333, 500, 1, -4, 3); //Display the bullets at the position where the character was when shooting
  11.   }
  12. }
  13. void draw() {
  14.   background(0);
  15.   // blue rect
  16.   fill(0, 0, 255);
  17.   rect (327, 500, 10, 10);
  18.   //
  19.   for (int i=0; i<9; i++) {
  20.     if (bullet[i].bulletVisible==true) {
  21.       bullet[i].display();
  22.       bullet[i].move();
  23.     }
  24.   }
  25. }
  26. //
  27. void keyReleased() {
  28.   if (key==' ') {
  29.     // search empty slot
  30.     for (int i=0; i<9; i++) {
  31.       if (!bullet[i].bulletVisible) {
  32.         // start new bullet 
  33.         bullet[i].bulletVisible=true;
  34.         bullet[i].life = 255;
  35.         bullet[i].x=333;
  36.         bullet[i].y=500 ;
  37.         break;
  38.         // return;
  39.       } // if
  40.     } // for
  41.   } // if
  42. } // func
  43. //
  44. // ================================================================
  45. // Bullet - Simple class for bullets
  46. // http://www.processing.org/learning/topics/arraylistclass.html
  47. class Bullet {
  48.   float x;
  49.   float y;
  50.   float speedX ;
  51.   float speedY;
  52.   float w;
  53.   float life = 255;
  54.   boolean bulletVisible = false ;
  55.   //
  56.   Bullet(float tempX, float tempY, // new2
  57.   float tempSpeedX, float tempSpeedY,
  58.   float tempW) {
  59.     x = tempX;
  60.     y = tempY;
  61.     w = tempW;
  62.     speedX = tempSpeedX;
  63.     speedY = tempSpeedY;
  64.   }
  65.   void move() {
  66.     // Add speed to location
  67.     x = x + speedX;
  68.     y = y + speedY;
  69.     //
  70.     // kill bullet when outside screen
  71.     if (x<4)
  72.       life=-1;
  73.     if (y<4)
  74.       life=-1;
  75.     if (x>width-4)
  76.       life=-1;
  77.     if (y>width-4)
  78.       life=-1;
  79.     //
  80.     if (life==-1) {
  81.       bulletVisible = false ;
  82.     }
  83.   } // method
  84.   //
  85.   void display() {
  86.     // Display the circle
  87.     fill(244, 2, 2);
  88.     noStroke();
  89.     ellipse(x, y, w, w);
  90.   }
  91. } // class
  92. //

GoToLoop
GoToLoop

Re: Simple shooting with keyPressed

6 months ago
Here's another program example which also uses regular Arrays and  when mousePressed() , 
search for an available  isInactive Firework  object to launch() it again!
Top Reply

Statistics

  • 6 Replies
  • 389  Views
  • 1 Followers

Tags

No tags available for this topic.

Actions

Related Posts