Simple puss/pop matrix problem

Programming Questions

thrasher89

Simple puss/pop matrix problem

in Programming Questions • 2 years ago

hey im doing a simple program that zoom in and out with the click of 2 buttons which I will eventually add to a larger program. Problem is when the buttons are pressed it zooms in/out but only on the click. I no the pushMatrix() and popMatrix() should be used but im not sure where exactly to put it. This is the method.

void update(int x, int y)
{
if(locked == false)
{
    zoomIN.update();
    zoomOUT.update();
}
else
{
    locked = false;
}
    if(mousePressed)
    {
      float a = 0.0;
      float b = 0.0;

      if(zoomIN.pressed())
      {
        a = a + 0.04;
        b = cos(a)*2;
        scale(b);
      }
      else if(zoomOUT.pressed())
      {
        a = a - 0.04;
        b = cos(a)/2;
        scale(b);
      }
    }

}

I will be greatful for any help thanks in advance.

Replies(6)

torfuspol..

Re: Simple puss/pop matrix problem

2 years ago

It's hard to tell what the precise problem is if you show us only parts of the code

Could you post a fully working example of your problem?

thrasher89

Re: Re: Simple puss/pop matrix problem

2 years ago

Sorry your right here it is

color currentcolor;
RectButton zoomIN, zoomOUT;
boolean locked = false;
void setup()
{
size(700, 400);
smooth();
color baseColor = color(102);
currentcolor = baseColor;
color buttoncolor = color(204);
color highlight = color(153);

buttoncolor = color(0);
highlight = color(200);
zoomIN = new RectButton(90, 20, 50, buttoncolor, highlight);

buttoncolor = color(200);
highlight = color(51);
zoomOUT = new RectButton(150, 20, 50, buttoncolor, highlight);
}
void draw()
{
background(currentcolor);
stroke(255);
update(mouseX, mouseY);
zoomIN.display();
zoomOUT.display();
}
void update(int x, int y)
{
if(locked == false)
{
    zoomIN.update();
    zoomOUT.update();
}
else
{
    locked = false;
}
    if(mousePressed)
    {
      float a = 0.0;
      float b = 0.0;

      if(zoomIN.pressed())
      {
        a = a + 0.04;
        b = cos(a)*2;
        scale(b);

        currentcolor = zoomIN.basecolor;
      }

      else if(zoomOUT.pressed())
      {
        a = a - 0.04;
        b = cos(a)/2;
        scale(b);

        currentcolor = zoomOUT.basecolor;
      }
    }

}
class Button
{
int x, y;
int size;
color basecolor, highlightcolor;
color currentcolor;
boolean over = false;
boolean pressed = false;
void update()
{
    if(over())
    {
      currentcolor = highlightcolor;
    }
    else
    {
      currentcolor = basecolor;
    }
}
boolean pressed()
{
    if(over)
    {
      locked = true;
      return true;
    }
    else
    {
      locked = false;
      return false;
    }
}
boolean over()
{
return true;
}
boolean overZoom(int x, int y, int width, int height)
{
    if (mouseX >= x && mouseX <= x + width && mouseY >= y && mouseY <= y + height)
    {
      return true;
    }
    else
    {
      return false;
    }
}
}
class RectButton extends Button
{
RectButton(int ix, int iy, int isize, color icolor, color ihighlight)
{
    x = ix;
    y = iy;
    size = isize;
    basecolor = icolor;
    highlightcolor = ihighlight;
    currentcolor = basecolor;
}
boolean over()
{
    if( overZoom(x, y, size, size) )
    {
      over = true;
      return true;
    }
    else
    {
      over = false;
      return false;
    }
}
void display()
{
    stroke(255);
    fill(currentcolor);
    rect(x, y, size, size);
}
}

PhiLho

Re: Simple puss/pop matrix problem

2 years ago

When draw() ends, the scale is reset (along with other transformations). Put your scale value in a global variable, call scale() with this variable at the beginning of draw(), update the variable on button press.

fizzyp

Re: Re: Simple puss/pop matrix problem

2 years ago

I've also run into this: the matrix appears to be reset (just like resetMatrix() was called) between every call of draw()

PhiLho

Re: Re: Simple puss/pop matrix problem

2 years ago

Yes, that's what I meant by "other transformations".

thrasher89

Re: Re: Simple puss/pop matrix problem

2 years ago

Thanks phi.lho i understood what my problem was and corrected it. I altered the program slightly and it seems to be working correctly.

My program uses two rect's(created using 2 classes with inheritance) to zoom in/out. While the rect's themselves stay the same 2 ellipse grow larger/smaller.

Here is the code if anyone is also having this problem

color currentcolor;
RectButton zoomIN, zoomOUT;
float zoom = 1;
boolean locked = false;
void setup()
{
size(700, 400);
smooth();
color baseColor;
color buttoncolor;
color highlight;

buttoncolor = color(125, 125, 125);
highlight = color(0, 125, 0);
zoomIN = new RectButton(90, 20, 50, buttoncolor, highlight);

buttoncolor = color(255, 0, 0);
highlight = color(0, 255, 0);
zoomOUT = new RectButton(150, 20, 50, buttoncolor, highlight);
}
void draw()
{
background(255, 255, 255);
stroke(255);
zoomIN.display();
zoomOUT.display();
scale(zoom);

fill(0,0,0);
ellipse(200, 100, 100, 40);
fill(0,255,0);
ellipse(100, 100, 50, 50);
update(mouseX, mouseY);
}
void update(int x, int y)
{
if(locked == false)
{
    zoomIN.update();
    zoomOUT.update();
}
else
{
    locked = false;
}
    if(mousePressed)
    {
      if(zoomIN.pressed())
      {
        //trans = trans - 0.4;
        zoom = zoom + 0.1;
      }
      else if(zoomOUT.pressed())
      {
        //trans = trans + 0.4;
        zoom = zoom - 0.1;
      }
    }

}
class Button
{
int x, y;
int size;
color basecolor, highlightcolor;
color currentcolor;
boolean over = false;
boolean pressed = false;
void update()
{
    if(over())
    {
      currentcolor = highlightcolor;
    }
    else
    {
      currentcolor = basecolor;
    }
}
boolean pressed()
{
    if(over)
    {
      locked = true;
      return true;
    }
    else
    {
      locked = false;
      return false;
    }
}
boolean over()
{
return true;
}
boolean overZoom(int x, int y, int width, int height)
{
    if (mouseX >= x && mouseX <= x + width && mouseY >= y && mouseY <= y + height)
    {
      return true;
    }
    else
    {
      return false;
    }
}
}
class RectButton extends Button
{
RectButton(int ix, int iy, int isize, color icolor, color ihighlight)
{
    x = ix;
    y = iy;
    size = isize;
    basecolor = icolor;
    highlightcolor = ihighlight;
}
boolean over()
{
    if( overZoom(x, y, size, size) )
    {
      over = true;
      return true;
    }
    else
    {
      over = false;
      return false;
    }
}
void display()
{
    stroke(255);
    fill(currentcolor);
    rect(x, y, size, size);
}
}

Top Reply