Basically you need to use inheritance. I don't feel like going in to the details of things (sorry) but you should just read up on OOP (and inheritance) and everything should be fine. However i did throw together this quick example to show how it could be done.
So you need one parent class that holds x,y,w,h and make sure all your objects "extends" that class, then you can just use that parent class as the datatype and you will be able to access the variables. However as you can see in my example, if you're using a parent class you could just as well have the hitTest method inside that class and this way you can do many different implementations of the hitTest depending on the different objects shape (this is not something i do in my example).

1. class Entity {
     float posx, posy, width, height;
     boolean hitTest(Entity e) {
       return(e.posx<posx+width && e.posx+e.width>posx && e.posy<posy+height && e.posy+e.height>posy);
     }
   }
   class SomeObject extends Entity {
     int aFunInt;
     SomeObject(float x,float y,float w,float h) {
       this.posx = x;
       this.posy = y;
       this.width = w;
       this.height = h;
       aFunInt = -1;
     }
     void draw() {
       rect(posx,posy,width,height);
     }
   }
   class SomeOtherObject extends Entity {
     float aFunFloat;
     boolean thisObjectIsDifferentFromTheOtherOne;
     SomeOtherObject(float x,float y,float w,float h) {
       this.posx = x;
       this.posy = y;
       this.width = w;
       this.height = h;
       aFunFloat = 0.1;
       thisObjectIsDifferentFromTheOtherOne = true;
     }
     void draw() {
       ellipseMode(CORNER);
       ellipse(posx,posy,width,height);
     }
   }
   
   SomeObject a;
   SomeOtherObject b;
   SomeOtherObject c;
   void setup() {
     size(600,600);
     a=new SomeObject(random(width),random(height),20,20);
     b=new SomeOtherObject(mouseX,mouseY,20,20);
     c=new SomeOtherObject(random(width),random(height),20,20);
   }
   
   void draw() {
     background(0);
     b.posx = mouseX;
     b.posy = mouseY;
     a.draw();
     b.draw();
     c.draw();
     if(a.hitTest(b)) {
       println("object true");
     }
     if(hitTest(c,b)) {
       println("method true");
     }
   }
   
   boolean hitTest(Entity e1,Entity e2) {
     return(e1.posx<e2.posx+e2.width && e1.posx+e1.width>e2.posx && e1.posy<e2.posy+e2.height && e1.posy+e1.height>e2.posy);
   }
   
   

Thanks, that's extremely helpful!