Shoot multiple bullets.

General Discussion Other

benny.wat..

in General Discussion • Other • 9 months ago

Hello and Happy new year to all of those who read my post,

I'm here once again whit a problem in my Code,

I'v been working on this game in whitch for now i have a red dot you can move whit awsd keys and a green dot witch trys to catch up whit the red dot, and also a life bar for the red dot witch lowers down when the greed dot touches the red dot.

I would like it if when the player clicks whit the mouse on a location of the screen, a ellipse witch represents a bullet will come from the red dot and go to the pointed location, if it touches the borders of the screen i want it to do nothing and when it touches the green dot i can give it some effects.

The problem is i have no idea how to make an ellipse that stays after the mouse press and how to make it possible to get multiple bullets over the screen at one time...

coul you have a tought about how i could make this work, i would be vey gratefull.

i won't put my code on here right now but if needed i will.

The only thing is that the code has to be pretty basic because i'm doing this as a school project and i don't want to just copy and paste, the main goal is to discover new ways of coding but also to be able to understand them and be able to reuse them.

Replies(9)

amnon.owed

Re: Shoot multiple bullets.

9 months ago

You could use a Bullet class with a location and direction. And an arrayList to hold the bullets.

Code Example

ArrayList <Bullet> bullets = new ArrayList <Bullet> ();
PVector player, playerSpeed;
float maxSpeed = 3;
void setup() {
size(600, 600);
player = new PVector(width/2, height/2);
playerSpeed = new PVector();
noCursor();
noStroke();
smooth();
}
void draw() {
background(255);
player.add(playerSpeed);
fill(255, 0, 0);
ellipse(player.x, player.y, 20, 20);
fill(255);
ellipse(player.x, player.y, 10, 10);
PVector mouse = new PVector(mouseX, mouseY);
fill(0);
ellipse(mouse.x, mouse.y, 5, 5);
if (frameCount%5==0 && mousePressed) {
PVector dir = PVector.sub(mouse, player);
dir.normalize();
dir.mult(maxSpeed*3);
Bullet b = new Bullet(player, dir);
bullets.add(b);
}
for (Bullet b : bullets) {
b.update();
b.display();
}
}
class Bullet extends PVector {
PVector vel;
Bullet(PVector loc, PVector vel) {
super(loc.x, loc.y);
this.vel = vel.get();
}
void update() {
add(vel);
}
void display() {
fill(0, 0, 255);
ellipse(x, y, 3, 3);
}
}
void keyPressed() {
if (keyCode == UP) { playerSpeed.y = -maxSpeed; }
if (keyCode == DOWN) { playerSpeed.y = maxSpeed; }
if (keyCode == LEFT) { playerSpeed.x = -maxSpeed; }
if (keyCode == RIGHT) { playerSpeed.x = maxSpeed; }
}
void keyReleased() {
if (keyCode == UP || keyCode == DOWN) { playerSpeed.y = 0; }
if (keyCode == LEFT || keyCode == RIGHT) { playerSpeed.x = 0; }
}

benny.wat..

Re: Shoot multiple bullets.

9 months ago

Ths does exactly what i wanted , now there are some tinghs on this code i never used , i'm going to study it a bit and i'll ask my question on the way , thank you a lot amnon:

benny.wat..

Re: Shoot multiple bullets.

9 months ago

i got a hard time whit this...

if (frameCount%5==0 && mousePressed) {
PVector dir = PVector.sub(mouse, player);
dir.normalize();
dir.mult(maxSpeed*3);
Bullet b = new Bullet(player, dir);
bullets.add(b);
}
for (Bullet b : bullets) {
b.update();
b.display();
}
}
class Bullet extends PVector {
PVector vel;
Bullet(PVector loc, PVector vel) {
super(loc.x, loc.y);
this.vel = vel.get();
}

amnon.owed

Re: Shoot multiple bullets.

9 months ago

Commented...

// every 5th frame AND when the mouse is pressed
if (frameCount%5==0 && mousePressed) {
// get the direction from the player to the mouse
PVector dir = PVector.sub(mouse, player);
// normalize it to length 1 (make it as unit vector)
dir.normalize();
// multiply it by maxSpeed times three (giving the direction a fixed velocity)
dir.mult(maxSpeed*3);
// create a new bullet at the position of the player in the direction of the mouse
Bullet b = new Bullet(player, dir);
// add the new bullet to the list
bullets.add(b);
}
// for each bullet b in the the list of bullets
for (Bullet b : bullets) {
// run the bullet's update() method
b.update();
// run the bullet's display() method
b.display();
}
}
// class Bullet which extends PVector (note PVector differences between 1.5.1 and 2.0xx)
class Bullet extends PVector {
// have a velocity variable for the bullet's velocity
PVector vel;
// constructor for Bullet with location and direction/velocity
Bullet(PVector loc, PVector vel) {
// send the location to the PVector constructor (where it is stored in x, y variables)
super(loc.x, loc.y);
// send the velocity to the instance variable PVector vel
this.vel = vel.get(); // make a copy just to avoid any reference problems
}

GoToLoop

Re: Shoot multiple bullets.

9 months ago

For me, PVector itself is a little hard to picture the whole thing in my head!

It is however an interesting concept: 3 field float variables plus methods for vector math.

So I've decided to fool around Ammon's example code to see whether I could finally grasp it in my mind.

Moreover, added in some checks for canvas border limits both for player & bullets.
PVector playerPos is transported to the opposite border if it is so.
And a Bullet class instance from the ArrayList is removed to save memory.

So, check it out:

/**
 * Multiple Bullets (v2.1)
 * by Ammon.Owed (2013/Jan)
 *
 * http://forum.processing.org/topic/shoot-multiple-bullets
 */

final static List<Bullet> bullets = new ArrayList(50);

final static PVector playerPos = new PVector(); 
final static PVector playerSpd = new PVector();
final static PVector bulletSpd = new PVector();

final static byte  playerVel  = 3, bulletVel = 5, fps = 60;
final static byte  playerSize = 20, holeSize = playerSize>>1;
final static byte  aimSize = 5, bulletSize = 4, bulletGap = 3;

final static color aimColor = 0, bg = 255;
final static color playerColor = #FF0000, bulletColor = #0000FF;

void setup() {
    size(600, 600);
    smooth();
    noStroke();
    noCursor();
    ellipseMode(CENTER);
    frameRate(fps);

    playerPos.set(width>>1, height>>1, 0);
}

void draw() {
    background(bg);

    updatePlayer();
    displayPlayer();
    displayAim();

    if (mousePressed && frameCount % bulletGap == 0)
        addBullet();

    //for (Bullet b: bullets)  b.run(); //unremovable bullets!

    for ( int b = bullets.size(); b != 0; )
        if ( bullets.get(--b).run() )   bullets.remove(b);

    print(bullets.size() + "\t");
}

void updatePlayer() {
    playerPos.add(playerSpd);

    if (playerPos.x > width)    playerPos.x = 0;
    else if (playerPos.x < 0)   playerPos.x = width;

    if (playerPos.y > height)   playerPos.y = 0;
    else if (playerPos.y < 0)   playerPos.y = height;
}

void displayPlayer() {
    fill(playerColor);
    ellipse(playerPos.x, playerPos.y, playerSize, playerSize);

    fill(bg);
    ellipse(playerPos.x, playerPos.y, holeSize, holeSize);
}

void displayAim() {
    fill(aimColor);
    ellipse(mouseX, mouseY, aimSize, aimSize);
}

void addBullet() {
    bulletSpd.set(mouseX, mouseY, 0);

    bulletSpd.sub(playerPos);
    bulletSpd.normalize();
    bulletSpd.mult(bulletVel);

    bullets.add( new Bullet(playerPos, bulletSpd) );
}

void keyPressed() {
    final int k = keyCode;

    if (k == LEFT || k == 'A')
        playerSpd.x = -playerVel;
    else if (k == RIGHT || k == 'D')
        playerSpd.x = playerVel;
    else if (k == UP || k == 'W') 
        playerSpd.y = -playerVel;
    else if (k == DOWN || k == 'S')
        playerSpd.y = playerVel;
}

void keyReleased() {
    final int k = keyCode;

    if ( (k == LEFT || k == 'A') && playerSpd.x < 0 
        || (k == RIGHT || k == 'D') && playerSpd.x > 0 )
        playerSpd.x = 0;

    else if ( (k == UP || k == 'W') && playerSpd.y < 0 
        || (k == DOWN  || k == 'S') && playerSpd.y > 0 )
        playerSpd.y = 0;
}

class Bullet extends PVector {
    PVector vel;

    Bullet(PVector loc, PVector vel) {
        super(loc.x, loc.y);
        this.vel = vel.get();
    }

    void display() {
        fill(bulletColor);
        ellipse(x, y, bulletSize, bulletSize);
    }

    boolean update() {
        add(vel);
        return x > width || x < 0 || y > height || y < 0;
    }

    boolean run() {
        display();
        return update();
    }
}

benny.wat..

Re: Shoot multiple bullets.

9 months ago

Hello Amnon.owed, it took me some time to understand your code but i have to say after quite some learning and studying on it it finaly got it and was able to reproduce it.

But i got stuck on this next thing, when i want to set the borders of my screen as a limmit for the ellipse and not make it go around , it works when i move wile pressing and releasing asdz but when i use a continued press it ignores the limmits i imposed.

GoToLoop

Re: Shoot multiple bullets.

9 months ago

Tweaked my derived version so the player not be able to cross the borders now.

It's located at function updatePlayer().
Old code is commented out for comparison.

Also, take a look at this post:
http://forum.processing.org/topic/array-usage-objects-in-general

/**
 * Multiple Bullets (v2.5)
 * by Ammon.Owed (2013/Jan)
 *
 * http://forum.processing.org/topic/shoot-multiple-bullets
 */

final static List<Bullet> bullets = new ArrayList(50);

final static PVector playerPos = new PVector(); 
final static PVector playerSpd = new PVector();
final static PVector bulletSpd = new PVector();

final static byte  playerVel  = 3, bulletVel = 5, fps = 60;
final static byte  playerSize = 20, holeSize = playerSize>>1;
final static byte  aimSize = 5, bulletSize = 4, bulletGap = 3;

final static color aimColor = 0, bg = 255;
final static color playerColor = #FF0000, bulletColor = #0000FF;

void setup() {
  size(600, 600);
  smooth();
  noStroke();
  noCursor();
  ellipseMode(CENTER);
  frameRate(fps);

  playerPos.set(width>>1, height>>1, 0);
}

void draw() {
  background(bg);

  updatePlayer();
  displayPlayer();
  displayAim();

  if (mousePressed && frameCount % bulletGap == 0)
    addBullet();

  //for (Bullet b: bullets)  b.run(); //unremovable bullets!

  for ( int b = bullets.size(); b != 0; )
    if ( bullets.get(--b).run() )   bullets.remove(b);

  print(bullets.size() + "\t");
}

void updatePlayer() {
  playerPos.add(playerSpd);

  if (playerPos.x > width - holeSize)  playerPos.x = width-holeSize;
  else if (playerPos.x < holeSize)     playerPos.x = holeSize;

  if (playerPos.y > height-holeSize)   playerPos.y = height-holeSize;
  else if (playerPos.y < holeSize)     playerPos.y = holeSize;

  /*
   if (playerPos.x > width)    playerPos.x = 0;
   else if (playerPos.x < 0)   playerPos.x = width;
   
   if (playerPos.y > height)   playerPos.y = 0;
   else if (playerPos.y < 0)   playerPos.y = height;
   */
}

void displayPlayer() {
  fill(playerColor);
  ellipse(playerPos.x, playerPos.y, playerSize, playerSize);

  fill(bg);
  ellipse(playerPos.x, playerPos.y, holeSize, holeSize);
}

void displayAim() {
  fill(aimColor);
  ellipse(mouseX, mouseY, aimSize, aimSize);
}

void addBullet() {
  bulletSpd.set(mouseX, mouseY, 0);

  bulletSpd.sub(playerPos);
  bulletSpd.normalize();
  bulletSpd.mult(bulletVel);

  bullets.add( new Bullet(playerPos, bulletSpd) );
}

void keyPressed() {
  final int k = keyCode;

  if (k == LEFT || k == 'A')
    playerSpd.x = -playerVel;
  else if (k == RIGHT || k == 'D')
    playerSpd.x = playerVel;
  else if (k == UP || k == 'W') 
    playerSpd.y = -playerVel;
  else if (k == DOWN || k == 'S')
    playerSpd.y = playerVel;
}

void keyReleased() {
  final int k = keyCode;

  if ( (k == LEFT  || k == 'A') && playerSpd.x < 0 
    || (k == RIGHT || k == 'D') && playerSpd.x > 0 )
    playerSpd.x = 0;

  else if ( (k == UP || k == 'W') && playerSpd.y < 0 
    || (k == DOWN    || k == 'S') && playerSpd.y > 0 )
    playerSpd.y = 0;
}

class Bullet extends PVector {
  PVector vel;

  Bullet(PVector loc, PVector vel) {
    super(loc.x, loc.y);
    this.vel = vel.get();
  }

  void display() {
    fill(bulletColor);
    ellipse(x, y, bulletSize, bulletSize);
  }

  boolean update() {
    add(vel);
    return x > width || x < 0 || y > height || y < 0;
  }

  boolean run() {
    display();
    return update();
  }
}

benny.wat..

Re: Shoot multiple bullets.

9 months ago

I got what you did, i tried a similar thing ,i will try this one tought, maybe it is because i did not put it in the player update but in the player display that it mignt not have worked?

Chrisir

Re: Shoot multiple bullets.

9 months ago

I made the player into a class..

/**
* Multiple Bullets (v2.5)
* by Ammon.Owed (2013/Jan)
*
* http://forum.processing.org/topic/shoot-multiple-bullets
*/
final static ArrayList<Bullet> bullets = new ArrayList(); // class Bullet
Player player = new Player(); // class Player
final static color bg = 255;
final static byte fps = 60;
void setup() {
size(600, 600);
smooth();
noStroke();
noCursor();
cursor (CROSS);
ellipseMode(CENTER);
frameRate(fps);
player.playerPos.set(width>>1, height>>1, 0);
}
void draw() {
background(bg);
player.updatePlayer();
player.displayPlayer();
player.shoot();
// displayAim();
handleBullets();
}
void keyPressed() {
final int k = keyCode;
if (k == LEFT || k == 'A')
player.playerSpd.x = -player.playerVel;
else if (k == RIGHT || k == 'D')
player.playerSpd.x = player.playerVel;
else if (k == UP || k == 'W')
player.playerSpd.y = -player.playerVel;
else if (k == DOWN || k == 'S')
player.playerSpd.y = player.playerVel;
}
void keyReleased() {
final int k = keyCode;
if ( (k == LEFT || k == 'A') && player.playerSpd.x < 0
|| (k == RIGHT || k == 'D') && player.playerSpd.x > 0 )
player.playerSpd.x = 0;
else if ( (k == UP || k == 'W') && player.playerSpd.y < 0
|| (k == DOWN || k == 'S') && player.playerSpd.y > 0 )
player.playerSpd.y = 0;
}
// other functions -----------------------------------------
void handleBullets() {
//for (Bullet b: bullets) b.run(); //unremovable bullets!
for ( int b = bullets.size(); b != 0; )
if ( bullets.get(--b).run() )
bullets.remove(b);
print(bullets.size() + "\t");
}
// void displayAim() {
// final static byte aimSize = 5;
// final static color aimColor = 0;
// fill(aimColor);
// ellipse(mouseX, mouseY, aimSize, aimSize);
// }
// classes =====================================================
class Player {
final PVector playerPos = new PVector();
final PVector playerSpd = new PVector();
final static byte playerVel = 3;
final static byte bulletVel = 5;
final static byte playerSize = 20;
final static byte holeSize = playerSize>>1;
final static color playerColor = #FF0000 ;
void updatePlayer() {
playerPos.add(playerSpd);
if (playerPos.x > width - holeSize)
playerPos.x = width-holeSize;
else if (playerPos.x < holeSize)
playerPos.x = holeSize;
if (playerPos.y > height-holeSize)
playerPos.y = height-holeSize;
else if (playerPos.y < holeSize)
playerPos.y = holeSize;
/*
if (playerPos.x > width) playerPos.x = 0;
else if (playerPos.x < 0) playerPos.x = width;
if (playerPos.y > height) playerPos.y = 0;
else if (playerPos.y < 0) playerPos.y = height;
*/
}
void displayPlayer() {
fill(playerColor);
ellipse(playerPos.x, playerPos.y, playerSize, playerSize);
fill(bg);
ellipse(playerPos.x, playerPos.y, holeSize, holeSize);
}
void shoot() {
final byte bulletGap = 3;
if (mousePressed && frameCount % bulletGap == 0)
player.addBullet();
}
void addBullet() {
final PVector bulletSpd = new PVector();
bulletSpd.set(mouseX, mouseY, 0);
bulletSpd.sub(playerPos);
bulletSpd.normalize();
bulletSpd.mult(bulletVel);
bullets.add( new Bullet(playerPos, bulletSpd) );
}
} // class Player
// ==========================================================
class Bullet extends PVector {
PVector vel;
final static color bulletColor = #0000FF;
Bullet(PVector loc, PVector vel) {
super(loc.x, loc.y);
this.vel = vel.get();
}
void display() {
final byte bulletSize = 4;
fill(bulletColor);
ellipse(x, y, bulletSize, bulletSize);
}
boolean update() {
add(vel);
return x > width || x < 0 || y > height || y < 0;
}
boolean run() {
display();
return update();
}
} // class Bullet
//

Top Reply