[Shared Code] Class to enable boolean shape operations in ToxicLibs (via Geomerative)

bjzaba

[Shared Code] Class to enable boolean shape operations in ToxicLibs (via Geomerative)

in Library and Tool Development • 2 years ago

Boolean shape operations don't seem to have been implemented in ToxicLibs, so I spent some time extending Geomerative's RPolygon class to allow me to do it. And so I present to you:

RPolygon2D

I'm not a great programmer, and it's not finished, but I thought seeing as I spent the time on it I should share it. There may be be problems with what I've done, and it's a little rough-and-ready, so be warned.

I did it in eclipse so sorry to those using the processing IDE. It shouldn't be too hard to translate it though.

A little test program is included in the main class:

One thing I have noticed is that the mouse clicks in the example program don't register. If anyone could shed light on that mystery I'd be most grateful.

~B☼

Replies(1)

toxmeister

Re: [Shared Code] Class to enable boolean shape operations in ToxicLibs (via Geomerative)

1 years ago

You can also just easily do this with the vanilla Java2D toolkit and I recently mocked this up for some architecture students to compute the areas of agent clusters in a simulation:

import java.awt.geom.*;
import toxi.geom.*;
import toxi.processing.*;
int BEZIER_RES=8;
ToxiclibsSupport gfx;
void setup() {
size(400, 400);
gfx = new ToxiclibsSupport(this);
}
void draw() {
background(51);
noFill();
stroke(255, 0, 0);
float phi = frameCount * 0.01f;
// use Java2D types for realizing boolean shape operations
// use mouse to move one of them
Ellipse2D e1=new Ellipse2D.Float(mouseX-100, mouseY-100, 200, 200);
Ellipse2D e2=new Ellipse2D.Float(150, 130+sin(phi)*50, 120, 120);
Ellipse2D e3=new Ellipse2D.Float(200+sin(phi*13/8)*50, 180, 200, 200);
Ellipse2D e4=new Ellipse2D.Float(50+sin(phi*15/13)*50, 50, 120, 120);
// the Area class handles
// building a union shape from all subshapes
Area a = new Area(e1);
a.add(new Area(e2));
a.add(new Area(e3));
a.add(new Area(e4));
// now sample the resulting paths and produce toxiclibs Polygon2Ds
List<Polygon2D> shapes=produceAreaSubShapes(a, BEZIER_RES);
for (Polygon2D p : shapes) {
gfx.polygon2D(p);
}
}
// computes point on bezier segment with t={0.0 .. 1.0}
Vec2D bezierPoint(Vec2D a, Vec2D b, Vec2D c, Vec2D d, float t) {
float it = 1.0f - t;
float it2 = it * it;
float t2 = t * t;
return a.scale(it2 * it)
.addSelf(b.scale(3 * t * it2))
.addSelf(c.scale(3 * t2 * it))
.addSelf(d.scale(t2 * t));
}
// translates the segments returned by the Area's PathIterator
// into a list of Polygon2D instances. Also see:
// http://download.oracle.com/javase/7/docs/api/java/awt/geom/Area.html
// http://download.oracle.com/javase/7/docs/api/java/awt/geom/PathIterator.html
//
// Note: Currently only line & bezier segments are supported.
// The method will throw an UnsupportedOperationException if any unsupported
// segment types are encountered.
List<Polygon2D> produceAreaSubShapes(Area a, int bezierRes) {
PathIterator i = a.getPathIterator(null);
float[] buf = new float[6];
Vec2D prev = new Vec2D();
List<Polygon2D> shapes = new ArrayList<Polygon2D>();
Polygon2D s = null;
while (!i.isDone ()) {
int id = i.currentSegment(buf);
switch (id) {
case PathIterator.SEG_MOVETO:
s = new Polygon2D();
shapes.add(s);
prev.set(buf[0], buf[1]);
s.add(prev.copy());
break;
case PathIterator.SEG_LINETO:
prev.set(buf[0], buf[1]);
s.add(prev.copy());
break;
case PathIterator.SEG_CUBICTO:
Vec2D pa = new Vec2D(buf[0], buf[1]);
Vec2D pb = new Vec2D(buf[2], buf[3]);
Vec2D pc = new Vec2D(buf[4], buf[5]);
for (int t = 0; t <= bezierRes; t++) {
s.add(bezierPoint(prev, pa, pb, pc, (float) t / bezierRes));
}
prev.set(pc);
break;
case PathIterator.SEG_CLOSE:
break;
default:
throw new UnsupportedOperationException(
"Unsupported path segment type: " + id);
}
i.next();
}
return shapes;
}

I also created a more flexible version of this approach with support for anything which implements the toxi.geom.Shape2D interface and this will be part of the next release. You can already check out the source for it here:

http://hg.postspectacular.com/toxiclibs/src/tip/src.core/toxi/geom/BooleanShapeBuilder.java

http://postspectacular.com | http://toxiclibs.org

Top Reply