First remark: don't load fonts in draw()! (I should put this sentence in a template...)
You don't change font in the play, so set it once in setup() and be done with it.

Don't change Processing variables like mouseX. They are set by Processing and of course, reset on the next frame.

I don't see the issue with 2).

Here is a quick fix. I see some strange things with the ball being something almost stuck... You need probably to improve the collision tests.

int ballx = 50;
int bally = 50;
int motionx = 6;
int motiony = 5;
float paddlePos;
int screendisplay = 1;
PFont font;
float ballx2 = random(50, 900);
int ballx1 = int(ballx2);
float bally2 = random (300, 400);
int bally1 = int(bally2);

void setup() {
  size(1000, 600);
  font = createFont("Tahoma", 42);
  textFont(font, 42); 
}

void draw() {
  if (screendisplay == 1) {
    background (#AFE5EA);
    fill(255);
    rect(350, 300, 300, 100);

    fill(0);
    text("Start", 450, 365);

    if (mouseX > 350 && mouseX < 650 && mouseY > 300 && mouseY < 400 && mousePressed && screendisplay == 1) {
      screendisplay = 2;
    }
  }

  if (screendisplay == 2) {
    background (#AFE5EA);
    fill(255);

    // The ball
    strokeWeight(6);
    ellipse(ballx, bally, 50, 50);
    ballx += motionx;
    bally += motiony;

    // Ball collisions
    if (ballx > 970 || ballx < 30) {
      motionx *= -1;
    }
    if (bally < 30) {
      motiony *= -1;
    }

    // The paddle
    paddlePos = mouseX;
    if (paddlePos + 150 > 1000) {
      paddlePos = 850;
    }
    if (paddlePos < 2) {
      paddlePos = 3;
    }

    rect(paddlePos, 500, 150, 30);
    // Rebounding on the paddle
    if (500-bally < 40 && ballx > paddlePos && ballx < paddlePos+150) {
      motiony *= -1;
    }


    if (bally > 570) {
      screendisplay = 3;
      bally = 500 - bally1;
    }
  }

  if (screendisplay == 3) {
    background(0);
    fill(255);
    text("Menu", 450, 365);
    if (mouseX > 400 && mouseX < 600 && mouseY > 340 && mouseY < 470 && mousePressed) {
      screendisplay = 2;
    }
  }
}

Note: define some constants, like ball radius, paddle dimensions, etc. Use width and height Processing constants and those you define, with simple arithmetic. Thus, if you need to change something, it is easier. And you don't have mystery numbers like 500-bally < 40: constants also document the piece of code where they are used.