Set pixels[] once and use it as a background

Programming Questions

asimes

Set pixels[] once and use it as a background

in Programming Questions • 1 year ago

I have a program that draws a fractal using pixels[]. I want to be able to zoom in by clicking and dragging a rect over a section to make that the new boundaries (then redraw the fractal with the new boundaries). It takes a almost a second to calculate the fractal and draw it so I don't want to draw it every frame. Is there a way to set pixels once so I could call it like a background and be able to drag a rect on top of it?

This would be the equivalent of what I want but with background:

int mx, my;
void setup() {
size(600, 600);
noFill();
stroke(255);
}
void draw() {
background(128); // I want this to be a call to show what is in pixels[]
if (mousePressed) rect(mx, my, mouseX-mx, mouseY-my);
}
void mousePressed() {
mx = mouseX;
my = mouseY;
}

Replies(4)

PhiLho

Re: Set pixels[] once and use it as a background

1 year ago

Once drawn, use get() to have a PImage of the drawing, you can use it after that.

asimes

Re: Set pixels[] once and use it as a background

1 year ago

I must be doing something wrong, but I don't know what (no errors). Could you point out how to make the image correctly please?

EDIT: I made the part I assume I am doing wrong in red

boolean drawFractal = true;
float xmin = -2.5;
float ymin = -2.0;
float wh = 4;
int maxIterations = 1000;
int mx, my;
void setup() {
size(800, 800, P2D);
stroke(255);
noFill();
}
void draw() {
if (mousePressed) {
PImage fracImg = get();
image(fracImg, 0, 0);
rect(mx, my, mouseX-mx, mouseY-my);
}
if (drawFractal) fractal();
}
void fractal() {
loadPixels();
float xmax = xmin+wh;
float ymax = ymin+wh;
float dx = (xmax-xmin)/width;
float dy = (ymax-ymin)/height;
float x = xmin;
for (int i = 0; i < width; i++) {
float y = ymin;
for (int j = 0; j < height; j++) {
float zr = x;
float zi = y;
int n = 0;
while (n < maxIterations) {
float zrr = zr*zr;
float zii = zi*zi;
float twori = 2*zr*zi;
zr = zrr-zii+x;
zi = twori+y;
if (zrr+zii > 16) break;
n++;
}
if (n == maxIterations) pixels[i+j*width] = 0;
else {
float fn = n+1-log(log(sqrt(zr*zr+zi*zi)))/log(2);
float logColor = log(fn)/log(maxIterations);
pixels[i+j*width] = color(logColor*255);
}
y += dy;
}
x += dx;
}
updatePixels();
println("Time: "+millis());
drawFractal = false;
}
void mousePressed() {
mx = mouseX;
my = mouseY;
}

PhiLho

Re: Set pixels[] once and use it as a background

1 year ago

You capture an image and immediately display it back, that's not very useful. Even less as in the next frame, the image will have the previously drawn rectangles.
You must capture the image on mousePressed(), or, probably better, when the image has finished drawing.
Changes:

PImage fracImg; // Global
// [...]
void draw() {
if (fracImg != null) {
image(fracImg, 0, 0);
}
if (mousePressed) {
rect(mx, my, mouseX-mx, mouseY-my);
}
if (drawFractal) fractal();
}
// [...]
void mousePressed() {
mx = mouseX;
my = mouseY;
fracImg = get();
}

asimes

Re: Set pixels[] once and use it as a background

1 year ago

Ah, I assumed it was calling pixels[], I didn't realize it was like taking a screenshot. Thanks

Top Reply