set equal distances in 3d

Programming Questions

clankill3r

in Programming Questions • 2 years ago

If you want equal rotations on a 2d space then you can devide 360 by the ammount of lines for example you want.
(I call those line's normals from now on, a common name in 3d applications (it's a direction for a vector)).

Here's a example of 7 normals.

In 3d however this is much more difficult, here's my attempt (with 5):

I only have no clue how to make it correct, i hope someone can helps me.

void setup() {
size(600, 600, P3D);
smooth();

}

int normals = 5;

void draw() {
background(255);
translate(width/2, height/2, 0);
rotateY(map(mouseX, 0, width, 0, TWO_PI));
rotateZ(map(mouseY, 0, height, 0, TWO_PI));

for(int i = 0; i < normals; i++) {
    pushMatrix();

    float rotX = map(i, 0, normals, 0, TWO_PI);
    float rotY = map(i, 0, normals, 0, TWO_PI);
    float rotZ = map(i, 0, normals, 0, TWO_PI);

    rotateX(rotX);
    rotateY(rotY);
    rotateZ(rotZ);

    line(0, 0, 0, 40, 0, 0);

    popMatrix();
}

}

Replies(15)

allonestr..

Re: set equal distances in 3d

2 years ago

I call them radii, they are not normals, but shall we compromise on "spokes"? And I can see seven of them.

So, are you trying to draw a wheel (minus the tyre) in 3D space - this would have all the spokes plus the centre in one plane, or something like your second drawing, where, presumably the tyre end of the spokes are all in one plane, but the centre is not on that plane? Like something Boudicca might have had on her chariot wheels?

clankill3r

Re: set equal distances in 3d

2 years ago

spokes then :)

No not a wheel, i made this info graphic:

There are 12 persons, everyone has it's own direction, the conversation is shown. I want to give it a try in 3d.

clankill3r

Re: set equal distances in 3d

2 years ago

I asked the same question on a math forum, and someone there new what i meant.

I want to distribute points on a sphere (to start with).

here is a site
http://paulbourke.net/geometry/spherepoints/

There is code in C++, C and even JAVA!
However, it's from 2006, i don't know if much has changed since then but i don't understand it (talking about java).
About C++ and C, i looked into them, and i have no knwoledge of those languaes but sometimes i can understand certain things, but not with this.
If someone could help me with it then that would be awsome.

amnon.owed

Re: Re: set equal distances in 3d

2 years ago

The java example seems to be missing a SphericalCoordinates class unfortunately.

allonestr..

Re: set equal distances in 3d

2 years ago

Two things come to mind:

- there're a lot of websites discussing methods for doing this, not just the one you mentioned - have you had a good look to see if any of them have an approachable method?

- when I read about the "electrostatic repulsion" method, the rules for flocking came to mind

and a couple of questions:

- what other shapes/surface will you want to distribute the points on?

- how many points are you thinking of?

clankill3r

Re: set equal distances in 3d

2 years ago

I don't find websites that are more clear to me then that.
In fact, a lot of websites refer to that page.

About the shapes, i don't even need the sphere but it's a good starting point (i don't know where to start else). I need the direction seem from <0,0,0> .
I'm talking about 12 points.

allonestr..

Re: set equal distances in 3d

2 years ago

12 points are a dream as one of the platonic solids has 12 vertices - the icosahedron - so your distrubution is already done.

This reminds me of the allonestring method of "it's good enough distribution" (though I expect that other people have derived this too); here illustrated with a cube as I can draw them.

This was done with this method.

clankill3r

Re: set equal distances in 3d

2 years ago

Thanks, the word icosahedron is gold.
About the method with the images you have show, that gives 14 points.

If you know a good library wich can give me the coordinates of a icosahedron then please tell me.
I will look myself later.

allonestr..

Re: set equal distances in 3d

2 years ago

I want to distribute points on a sphere

Yes, I know that my cube example gives 14 points; it is an illustration of the allonestring method for distributing points on a sphere.

wiki gives the co-ordinates of the vertices of an icosahedron.

mbraendle

Re: set equal distances in 3d

2 years ago

You may also try out WolframAlpha, the computational knowledge engine.

E.g. regular icosahedron vertex coordinates

regular dodecahedron vertex coordinates

Or, if you take the Archimedean solids (which are not regular), e.g.

great rhombicosidodecahedron vertex coordinates

clankill3r

Re: set equal distances in 3d

2 years ago

WolframAlpha answer are one page of hardcore formulas.
Wiki has this:

The following Cartesian coordinates define the vertices of an icosahedron with edge-length 2, centered at the origin:

(0, ±1, ±φ)

(±1, ±φ, 0)

(±φ, 0, ±1)

where φ = (1+√5)/2 is the golden ratio (also written τ). Note that these vertices form five sets of three concentric, mutually orthogonal golden rectangles, whose edges form Borromean rings.

If the original icosahedron has edge length 1, its dual dodecahedron has edge length $\frac{\sqrt{5}-1}{2}$ , one divided by the golden ratio.

The 12 edges of a regular octahedron can be subdivided in the golden ratio so that the resulting vertices define a regular icosahedron. This is done by first placing vectors along the octahedron's edges such that each face is bounded by a cycle, then similarly subdividing each edge into the golden mean along the direction of its vector. The five octahedra defining any given icosahedron form a regular polyhedral compound, as do the two icosahedra that can be defined in this way from any given octahedron.

which is to poor of information if you ask me.

I will try some basic stuff like this with rotating, i think that will do:

quarks

Re: set equal distances in 3d

2 years ago

Problem: to evenly distribute n points over the surface of a sphere

There does not appear to be an exact solution but less than 10mins googling gave me this source which details 4 numerical methods to solve the problem. The best was number 3 the trig method, the code below is the trig method in action

import peasy.org.apache.commons.math.*;
import peasy.*;
import peasy.org.apache.commons.math.geometry.*;
int nbr = 20;
PVector[] pts;
PVector vec;
PeasyCam pcam;
void setup(){
size(300,300,P3D);
pts = new PVector[nbr];
makePoints();
pcam = new PeasyCam(this, 100);
}
void draw(){
background(0);
stroke(255);
strokeWeight(1.1);
for(int i = 0; i < nbr; i++){
vec = pts[i];
line(0,0,0,vec.x, vec.y, vec.z);
}
}
void makePoints(){
float r, t, z;
for(int i = 0; i < nbr; i++){
z = random(-1.0, 1.0);
r = sqrt(1 - z*z);
t = random(0.0, TWO_PI);
pts[i] = new PVector(r * cos(t), r * sin(t), z);
// Points all lie on a sphere of radius 1 so
// scale the vector so it is visible
pts[i].mult(80);
}
}

mbraendle

Re: set equal distances in 3d

2 years ago

The trig algorithm only gives good results for large n; for small n (say less than 20) the points may be distributed all on one side of the sphere. You may see that immediately when you execute the code in the previous post with a low value of nbr.

So the trig algorithm just gives an initial guess, which gets the better the larger the number of points on the sphere.

I have updated the algorithm with code that sets up a force field (repulsive forces between the points on the sphere, and springs between the center point and the points on the sphere) which is used by the traer.physics particle system to optimize the positions. Unfortunately, traer.physics does not return the total energy of the particle system, which could be used to stop the optimization. Otherwise, one could use the energy to stop the particle system optimization. Instead of the energy, I tried to take the sum of the distances between the points; if the difference falls b. However, this did not work out, since during optimization the sum of all distances may also decrease and then the optimization stops.

In the present solution, the optimization just runs over 50000 iterations, which should be enough. Here the code:

import traer.physics.*;
import peasy.org.apache.commons.math.*;
import peasy.*;
import peasy.org.apache.commons.math.geometry.*;
float sphereradius = 40.0;
float attraction_force = -0.1;
float spring_force = 0.5;
float damping = 0.2;
ArrayList edges;
int n = 20;
PVector[] pts;
PeasyCam pcam;
ParticleSystem ps;
Particle[] particles;
void setup(){
size(300,300,P3D);
pts = new PVector[n];
ps = new ParticleSystem();
particles = new Particle[n+1];
edges = new ArrayList();
makePoints();
setupForceField();
optimize();
find_edges();
pcam = new PeasyCam(this, 100);
}
void draw() {
background(0);
stroke(255);
strokeWeight(1);
for(int i = 0; i < n; i++) {
PVector vec = pts[i];
line(0,0,0,vec.x, vec.y, vec.z);
}
stroke(255,255,0);
for (int i = 0; i < edges.size(); i++) {
Edge temp_edge = (Edge) edges.get(i);
PVector v1 = pts[temp_edge.start];
PVector v2 = pts[temp_edge.end];
line(v1.x,v1.y,v1.z,v2.x,v2.y,v2.z);
}
}
void makePoints() {
float r, t, z;
for(int i = 0; i < n; i++){
z = random(-1.0, 1.0);
r = sqrt(1 - z*z);
t = random(0.0, TWO_PI);
pts[i] = new PVector(r * cos(t), r * sin(t), z);
// Points all lie on a sphere of radius 1 so
// scale the vector so it is visible
pts[i].mult(sphereradius);
PVector vec = pts[i];
particles[i] = ps.makeParticle(1.0, vec.x,vec.y,vec.z);
}
// create center particle and add a high mass so that it doesn't move
particles[n] = ps.makeParticle(1.0,0.0,0.0,0.0);
particles[n].makeFixed();
}
void setupForceField() {
// for each point, add a repulsive force to between it and all the other points
for (int i = 0; i < n; i++) {
for (int j = i+1; j < n; j++) {
PVector v1 = pts[i];
PVector v2 = pts[j];
ps.makeAttraction(particles[i],particles[j],attraction_force,0);
}
// add a spring between center and sphere point
ps.makeSpring(particles[i],particles[n],spring_force,damping,sphereradius);
}
}
void optimize() {
for (int i = 0; i < 50000; i++) {
ps.tick();
}
update_pts();
}
void update_pts() {
for (int i = 0; i < n; i++) {
pts[i].set(particles[i].position().x(), particles[i].position().y(), particles[i].position().z());
}
}
/*
float calc_dist_total() {
float r = 0.0;
for (int i = 0; i < n; i++) {
PVector v1 = pts[i];
for (int j = i+1; j < n; j++) {
PVector v2 = pts[j];
r = r + v1.dist(v2);
}
}
return r;
}
*/
void find_edges() {
float sphere_area = 4 * PI * sphereradius * sphereradius;
float sphere_area_normalized = sphere_area / n;
float min_distance = 1.4 * sqrt(sphere_area_normalized);
for (int i = 0; i < n; i++) {
PVector v1 = pts[i];
for (int j = i+1; j < n; j++) {
PVector v2 = pts[j];
float r = v1.dist(v2);
if (r < min_distance) {
edges.add(new Edge(i,j));
}
}
}
}
class Edge {
int start,end;
Edge(int start_init, int end_init) {
start = start_init;
end = end_init;
}
}

clankill3r

Re: set equal distances in 3d

2 years ago

both thanks,

The code quark posted is indeed not to well for a small amount of points (but thanks for input anyway!).
Mbraendle's your thing is very nice, i probably want to expand my idea in the future where i also use less then 12n so i'm planning to continue with the code you posted. I feel a bit sick atm, so i look at it in detail later.

I wasn't able to look before cause i have no internet at home (yeah that sucks), so i did a attempt myself in that time.
Here it is:

import processing.opengl.*;

Icosahedron ico;

PVector[] rotations;

void setup() {
size(1024, 768, OPENGL);
smooth();

ico = new Icosahedron(300);

// we need to store the amount of rotation in xyz for every radii
// for this we use a PVector
rotations = new PVector[12];
}

void draw() {
background(255);
lights();

pushMatrix();

// move to center
translate(width/2, height/2);
// alow mouse rotation
rotateX(map(mouseY, 0, width, 0, TWO_PI));
rotateZ(map(mouseX, 0, width, 0, TWO_PI));

drawGrid();

stroke(0);
strokeWeight(1);
// fill(120, 20, 20);
noFill();
noStroke();
ico.draw();

stroke(0, 0, 255);
strokeWeight(6);

popMatrix();

translate(width/2, height/2);

for (int i = 0; i < ico.vertexes.length; i++) {

    if (frameCount == 1) { // print positions
      PVector p = ico.vertexes[i];
      println("x: "+p.x+"\ty: "+p.y+"\tz: "+p.z);
    }

    PVector p = ico.vertexes[i];
    //point(p.x, p.y, p.z);
    line(0, 0, 0, p.x, p.y, p.z);

}
}

// . . . . . . . . . . .

PVector getModelPVector(float x, float y, float z) {
float mx = modelX(x, y, z);
float my = modelY(x, y, z);
float mz = modelZ(x, y, z);

// minus preverious translation
// so if something was set at 0,0,0
// then it will be 0,0,0

mx -= modelX(0, 0, 0);
my -= modelY(0, 0, 0);
mz -= modelZ(0, 0, 0);

return new PVector(mx, my, mz);
}

// . . . . . . . . . . .

PVector getRotation(PVector v) {
float x = v.x;
float y = v.y;
float z = v.z;

// x rotation

// y rotation

// z rotation
return null;
}

// . . . . . . . . . . .

void mouseDragged() {
if (mouseButton == LEFT && mouseButton == RIGHT) {
    println("zoom");
}
else if (mouseButton == LEFT) {
    println("rotate");
}
else if (mouseButton == RIGHT) {
    println("pan");
}
}

// . . . . . . . . . . .

void drawGrid() {

float gridLength = 600;
int steps = 11;

float stepDist = gridLength/(steps-1);

pushStyle();
pushMatrix();

translate(-gridLength/2, -gridLength/2, 0);

noFill();
strokeWeight(1);
stroke(0);
// XY plane
for (int x = 0; x < steps; x++) {
    for (int y = 0; y < steps; y++) {

      if (x == (steps-1)/2) { // midle
        strokeWeight(1.5);
        line(x*stepDist, 0, x*stepDist, gridLength/2);
        stroke(0, 255, 0);
        line(x*stepDist, gridLength/2, x*stepDist, gridLength);

        // restore
        stroke(0);
        strokeWeight(1);
      }
      else if (y == (steps-1)/2) { // midle

        strokeWeight(1.5);
        line(0, y*stepDist, gridLength/2, y*stepDist);
        stroke(255, 0, 0);
        line(gridLength/2, y*stepDist, gridLength, y*stepDist);

        // restore
        stroke(0);
        strokeWeight(1);
      }
      else {

        line(x*stepDist, 0, x*stepDist, gridLength);
        line(0, y*stepDist, gridLength, y*stepDist);
      }
    }
}

popMatrix();
popStyle();
}

Icosahedron class

class Icosahedron {

float size;

PVector[] vertexes;

Icosahedron(float size) {
    this.size = size;

    vertexes = new PVector[12];
}

void draw() {

    PVector p;
    float x, y, z;

    int count = 0;

    rectMode(CORNERS);
    rect(-size/2, -size/4, size/2, size/4);

    vertexes[count++] = getModelPVector(size/2, size/4, 0);
    vertexes[count++] = getModelPVector(size/2, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4, 0);

    rectMode(CENTER);

    pushMatrix();

    rotateX(HALF_PI);
    rotateY(HALF_PI);

    // fill(0, 255, 0, 50);
    rect(0, 0, size, size/2);

    vertexes[count++] = getModelPVector(size/2, size/4, 0);
    vertexes[count++] = getModelPVector(size/2, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4, 0);

    popMatrix();

    pushMatrix();
    rotateX(HALF_PI);
    rotateZ(HALF_PI);

    // fill(0, 0, 255, 50);
    rect(0, 0, size, size/2);

    vertexes[count++] = getModelPVector(size/2, size/4, 0);
    vertexes[count++] = getModelPVector(size/2, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4 - size/2, 0);
    vertexes[count++] = getModelPVector(size/2 - size, size/4, 0);
    popMatrix();
}

}

clankill3r

Re: set equal distances in 3d

2 years ago

I forgot to ask, i did a google but i get a lot of stuff about quaronations and other complicated stuff.

if you have coordinates like (x, y, z) :
-33.49237 -19.30569 10.275825

and i know my center point:
0 0 0

Then how can the rotation in x, y and z be calculated (so i want 3 different values).
I know there is atan2 but that's for 2d space.

Top Reply