Unfortunately not. You have to do it manually and redraw the scene each time from a different viewpoint. So it's key to really seperate update code from display code. Once you start displaying (multiple times), nothing can change except the viewpoint. Here is a basic example of this idea. With the GLGraphics library you can have offscreen buffers in OPENGL and you can redraw a GLModel with a single line.

If you are feeling adventurous you could look into opengl multiple viewports or glsl shaders, but I am not sure if these would really yield results. And if so, probably not very easily.

Code Example

1. PGraphics topleft, topright, bottomleft, bottomright;
2. color c;
3.  
4. void setup() {
5.   size(800, 800);
6.   topleft = createGraphics(400, 400, P3D);
7.   topright = createGraphics(400, 400, P3D);
8.   bottomleft = createGraphics(400, 400, P3D);
9.   bottomright = createGraphics(400, 400, P3D);
10. }
11.  
12. void draw() {
13.   updateVariables();
14.   drawCube(topleft, cos(frameCount*0.01)*200, sin(3.5 + frameCount*0.01)*200);
15.   drawCube(topright, sin(frameCount*0.01)*200, cos(10+frameCount*0.01)*200);
16.   drawCube(bottomleft, sin(frameCount*0.01)*200, cos(13.5 + frameCount*0.01)*200);
17.   drawCube(bottomright, sin(9.8+frameCount*0.01)*200, cos(5.6+frameCount*0.01)*200);
18.   image(topleft, 0, 0);
19.   image(topright, 400, 0);
20.   image(bottomleft, 0, 400);
21.   image(bottomright, 400, 400);
22.   line(400, 0, 400, height);
23.   line(0, 400, width, 400);
24. }
25.  
26. void updateVariables() {
27.   if (frameCount % 60 == 0) {
28.     c = color(random(255), random(255), random(255));
29.   }
30. }
31.  
32. void drawCube(PGraphics pg, float eyeX, float eyeY) {
33.   pg.beginDraw();
34.   pg.background(255);
35.   pg.smooth();
36.   pg.lights();
37.   pg.camera(
38.     eyeX, eyeY, (pg.height/2.0) / tan(PI*60.0 / 360.0),
39.     pg.width/2.0, pg.height/2.0, 0,
40.     0, 1, 0
41.   );
42.   pg.translate(pg.width/2, pg.height/2);
43.   pg.fill(c);
44.   pg.noStroke();
45.   pg.box(200);
46.   pg.endDraw();
47. }

This is so great! Thanks a lot for your answers!

Awesome Makio135 I've been playing around with the glViewport technique.

Adapted Code

1. import processing.opengl.*;
2. import javax.media.opengl.*;
3.  
4. int numViews = 100;
5. GL gl;
6. float rot;
7. PVector[] cam = new PVector[numViews];
8.  
9. void setup() {
10.   size(900, 900, OPENGL);
11.   gl = ((PGraphicsOpenGL)g).beginGL();
12.   colorMode(RGB, 1);
13.   stroke(255, 255, 255);
14.   strokeWeight(2.5);
15.   setCams();
16. }
17.  
18. void draw() {
19.   background(0);
20.   rot += 0.005;
21.   int s = int(sqrt(numViews));
22.   int w = width/s;
23.   int h = height/s;
24.   for (int i=0; i<numViews; i++) {
25.     gl.glViewport (i%s*w, i/s*h, w, h); 
26.     perspective(PI/6, (float) width/height, 1, 1000);
27.     camera(cam[i].x, cam[i].y, cam[i].z, 0, 0, 0, 0, 1, 0);
28.     renderGeometry();
29.   }
30.   if (frameCount % 60 == 0) { frame.setTitle(int(frameRate) + " fps"); }
31. }
32.  
33. void keyPressed() {
34.   setCams();
35. }
36.  
37. void setCams() {
38.   for (int i=0; i<cam.length; i++) {
39.     PVector r = new PVector();
40.     while (r.mag() < 0.75) {
41.       r = new PVector(random(-1, 1), random(-1, 1),  random(-1, 1));
42.     }
43.     cam[i] = PVector.mult(r, 600);
44.   }
45. }
46.  
47. void renderGeometry() {
48.   pushMatrix();
49.   scale(60);
50.   rotateX(rot);
51.   rotateY(rot);
52.   beginShape(QUADS);
53.  
54.   fill(0, 1, 1); vertex(-1, 1, 1);
55.   fill(1, 1, 1); vertex( 1, 1, 1);
56.   fill(1, 0, 1); vertex( 1, -1, 1);
57.   fill(0, 0, 1); vertex(-1, -1, 1);
58.  
59.   fill(1, 1, 1); vertex( 1, 1, 1);
60.   fill(1, 1, 0); vertex( 1, 1, -1);
61.   fill(1, 0, 0); vertex( 1, -1, -1);
62.   fill(1, 0, 1); vertex( 1, -1, 1);
63.  
64.   fill(1, 1, 0); vertex( 1, 1, -1);
65.   fill(0, 1, 0); vertex(-1, 1, -1);
66.   fill(0, 0, 0); vertex(-1, -1, -1);
67.   fill(1, 0, 0); vertex( 1, -1, -1);
68.  
69.   fill(0, 1, 0); vertex(-1, 1, -1);
70.   fill(0, 1, 1); vertex(-1, 1, 1);
71.   fill(0, 0, 1); vertex(-1, -1, 1);
72.   fill(0, 0, 0); vertex(-1, -1, -1);
73.  
74.   fill(0, 1, 0); vertex(-1, 1, -1);
75.   fill(1, 1, 0); vertex( 1, 1, -1);
76.   fill(1, 1, 1); vertex( 1, 1, 1);
77.   fill(0, 1, 1); vertex(-1, 1, 1);
78.  
79.   fill(0, 0, 0); vertex(-1, -1, -1);
80.   fill(1, 0, 0); vertex( 1, -1, -1);
81.   fill(1, 0, 1); vertex( 1, -1, 1);
82.   fill(0, 0, 1); vertex(-1, -1, 1);
83.  
84.   endShape();
85.   popMatrix();
86. }

Hey guys,

However, I did had some trouble setting the perspective. I'm not sure exactly why, but using a strange proportion (like the one from my screen, /3 non-square) I had to change the perspective's "aspect" parameter accordingly - and as I don't know the math behind it, I just tried out proportions until I got it!

The correct aspect is width/height, hard coding that value is not safe, besides who has a square monitor ;-) Also you don't want the znear clipping plane so high. It will clip away much of your scene. So to get something more like the Processing perspective use (similar to my adaped code line 26):

1.    perspective(PI/3.0, (float) width/height, 1, 10000);

Great! Thanks, amnon!

Currently working on: http://namainstrument.tumblr.com/