selecting one object from an array

Programming Questions

yokoama

selecting one object from an array

in Programming Questions • 10 months ago

Hi,

So I have an array in which I create 'ants'. What I want to do is to be able to select one ant on the screen with a mouseclick and have a small rectangle around it so that you know you've selected it. This is the code I thought would do the job:

void collision() {
for(int i=0;i<AntGroup.size();i++) {
    Ant eachAnt = (Ant)AntGroup.get(i);
    if (((dist(mouseX, mouseY, eachAnt.antX, eachAnt.antY) < 20.0) && mouseButton == LEFT) == true) {
    stroke(204, 102, 0);
    noFill();
    rect(eachAnt.antX, eachAnt.antY, 15, 15);
    clicked = true;
    } if (clicked == true) {
    stroke(204, 102, 0);
    noFill();
    rect(eachAnt.antX, eachAnt.antY, 15, 15);
    } if ((dist(mouseX, mouseY, eachAnt.antX, eachAnt.antY) < 20.0) && mouseButton == RIGHT) {
     clicked = false;
    }
}

}

The problem is that now all the ants get selected instead of one. Does anybody know how to solve this. I'm kind of running against a deadline... aahh!

Samuel

Replies(5)

v.k.

Re: selecting one object from an array

10 months ago

Maybe make a isOver() boolean function in Ant class, simple check against mouseX and mouseY and each instace mind only it self. Then in your loop (inside mouseCliked? or released) call:

for( Ant eachAnt:AntGroup)

{

if(eachAnt.isOver()){ doStuff}

}

yokoama

Re: selecting one object from an array

10 months ago

Hey,

But isn't it already doing that more or less. But instead of IsOver() it is checking if it is within 20 pixels. Or am I misunderstanding.

Samuel

v.k.

Re: selecting one object from an array

10 months ago

Well I can't say cause I saw just a part of the code. I assumed this void was outside Ant class as it has an Array of ants, but any way here is what i meant, in a quick and dirty example. I'm not a very good programmer, but this is how i would try :) Hope it can help.

Ant[] ants = new Ant[20];
void setup()
{
size(400, 400);
strokeWeight(3);
for(int i=0; i < ants.length; i++)
{
ants[i] = new Ant();
}
}
void draw()
{
background(75, 16, 160);
for(int i=0; i < ants.length; i++)
{
ants[i].displayUpdate();
}
}
void mouseReleased()
{
for(int i=0; i < ants.length; i++)
{
ants[i].select();
}
}
class Ant {
float xpos;
float ypos;
float sz = 40;
boolean selected = false;
Ant()
{
xpos = random(0, width);
ypos = random(0, height);
}
void displayUpdate()
{
if (isOver() || selected)
{
if(selected)
stroke(0);
else
stroke(100);
}
else
{
noStroke();
}
fill(57, 192, 178);
rect(xpos, ypos, sz, sz);
}
boolean isOver()
{
return (mouseX > xpos && mouseX < xpos + sz && mouseY > ypos && mouseY < ypos + sz);
}
void select()
{
if (isOver())
selected = !selected;
}
}

PhiLho

Re: selecting one object from an array

10 months ago

Instead of drawing the rect only when the user clicks, memorize instead the index of the ant being clicked.
Then, when drawing the ants, if the current index is the memorized one, you can add a rectangle around it.

yokoama

Re: selecting one object from an array

10 months ago

I did this in the end and that seemed to work:

void collision() {

for (int i=0;i<AntGroup.size();i++) {
    Ant eachAnt = ((Ant)AntGroup.get(i));
    if ((dist(mouseX, mouseY, eachAnt.antX, eachAnt.antY) < 20.0) && mousePressed && mouseButton == LEFT)
      SelectedAnt = eachAnt;
    if ((dist(mouseX, mouseY, eachAnt.antX, eachAnt.antY) < 20.0) && mousePressed && mouseButton == RIGHT)
      SelectedAnt = null;
}
if (SelectedAnt != null) {
    stroke(204, 102, 0);
    noFill();
    rect(SelectedAnt.antX - SelectedAnt.rW/2, SelectedAnt.antY - SelectedAnt.rH/2, 15, 15);
}
}

Thanks for all the help!

Top Reply