... rectangle teleports to place I need.

I don't understand it! If it's what you needed, what is wrong then?

Anyways, just show us the code you got. 

2. int x, y;
3. 
   
4. void setup() {
5.   smooth();
6.   noStroke();
7.   background(255);
8.   fill(0);
9.   size(600, 600);
10.   x = 50;
11.   y = 50;
12.   display();
13. }
14. 
    
15. void display() {
16.   background(255);
17.   rect(x, y, 30, 30);
18. }
19. 
    
20. void go() {
21.   for (int i = 0; i <= 10; ++i) {
22.     ++x;
23.     ++y;
24.     display();
25.   }
26. }
27. 
    
28. void draw() {
29.   if (mousePressed)
30.     go();
31. }

Rectangle is just teleporting, but I want it to move, slowly move.

Some changes to your code:

1. int x, y;
2.  
3. void setup() {
4.   size(600, 600); // Must be first in setup()!
5.   smooth();
6.   noStroke();
7.   fill(0);
8.   x = 50;
9.   y = 50;
10.   display();
11. }
12.  
13. void display() {
14.   rect(x, y, 30, 30);
15. }
16.  
17. void go() {
18.     ++x;
19.     ++y;
20.     display();
21. }
22.  
23. void draw() {
24.   background(255);
25.   if (mousePressed)
26.     go();
27. }

The for loop isn't really necessary, unless you want to make a trail effect, perhaps. But you erased the whole sketch on each step, so it wasn't effective...

Oh, I was too l8! Anyways, here's my take: 

/* forum.processing.org/topic/screen-updating */

final static short SPD = 5, FPS = 50;
final static short DIM = 30, HALF_DIM = DIM >> 1;
final static color BG = #FFFF00, FG = #0000FF;

int x, y;

void setup() {
  size(600, 600);
  frameRate(FPS);
  smooth();
  noStroke();
  fill(FG);

  x = width  >> 1;   // screen center
  y = height >> 1;

  display();
}

void draw() {
  if (!mousePressed)  return;

  if (mouseButton == LEFT)  goUpLeft();
  else                   goDownRight();

  display();
}

void goUpLeft() {
  if ( (x -= SPD) < -HALF_DIM )  x = width  - HALF_DIM;
  if ( (y -= SPD) < -HALF_DIM )  y = height - HALF_DIM;
}

void goDownRight() {
  x = (x + SPD) % (width  - HALF_DIM);
  y = (y + SPD) % (height - HALF_DIM);
}

void display() {
  background(BG);
  rect(x, y, DIM, DIM);
}

Thanks! :)