You mention you work with 4 fullscreen offscreen images that are scaled to 50%. This was my assumption in the code below.

In this code the mx, my is based on where the cursor is, i.e. in which of the four parts the cursor is. Depending on where it is a 'regular fullscreen mouseX and mouseY' is calculated. So in essence the relative position within the part is re-calculated to a fullscreen position. After that, the fullscreen position is used in each of the 4 offscreen parts, since these are all also fullscreen (see the comment/assumption at the start). So basically you only need to 'convert' the mouseX, mouseY once and then feed the 'regular' values to all different PGraphics. The big advantage of this is that all of the code in the PGraphics will work as usual (as if it were displayed fullscreen) for example mouseOver code. See line 50 of the example.

Code Example

1. PGraphics[] pgs = new PGraphics[4];
2. color[] colors = new color[4];
3.  
4. void setup() {
5.   size(600,600);
6.   for (int i=0; i<pgs.length; i++) {
7.     pgs[i] = createGraphics(width, height, JAVA2D);
8.     colors[i] = color(random(255), random(255), random(255));
9.     pgs[i].beginDraw();
10.     pgs[i].noStroke();
11.     pgs[i].smooth();
12.     pgs[i].background(colors[i]);
13.     pgs[i].endDraw();
14.   }
15. }
16.  
17. void draw() {
18.   image(pgs[0], 0, 0, width/2, height/2);
19.   image(pgs[1], width/2, 0, width/2, height/2);
20.   image(pgs[2], 0, height/2, width/2, height/2);
21.   image(pgs[3], width/2, height/2, width/2, height/2);
22. }
23.  
24. void mouseMoved() {
25.   mouseToPgs();
26. }
27.  
28. void mouseToPgs() {
29.   int mx = 0, my = 0;
30.   if (mouseY < height/2) {
31.     if (mouseX < width/2) {
32.       mx = mouseX * 2;
33.       my = mouseY * 2;
34.     } else {
35.       mx = (mouseX-width/2) * 2;
36.       my = mouseY * 2;
37.     }
38.   } else {
39.     if (mouseX < width/2) {
40.       mx = mouseX * 2;
41.       my = (mouseY-height/2) * 2;
42.     } else {
43.       mx = (mouseX-width/2) * 2;
44.       my = (mouseY-height/2) * 2;
45.     }
46.   }
47.   for (int i=0; i<pgs.length; i++) {
48.     pgs[i].beginDraw();
49.     pgs[i].background(colors[i]);
50.     if (mx < pgs[i].width/2) { // notice how regular dimensions are used
51.       pgs[i].fill(0,125);
52.     } else {
53.       pgs[i].fill(255,125);
54.     }
55.     pgs[i].rect(0,0,width/2,height);
56.     pgs[i].fill(255);
57.     pgs[i].ellipse(mx, my, 50, 50);
58.     pgs[i].endDraw();
59.   }
60. }