Saying 'undefined' when it is defined

Programming Questions

truestory..

Saying 'undefined' when it is defined

in Programming Questions • 5 months ago

Hey, I'm new to constructors...hence why I may have one or two questions :)

From the below image, the error states that I haven't defined Car(int, int, int, int, float, int).

However, under the 'Class' portion of my code, I have defined it as int, int, int, float, float, int. So I'm not sure why its interpreting one of those data types wrongly:

Car(int colorR,int colorG,int colorB, float xpos, float ypos,int x) { // A constructor.

colorR = 255;

colorG = 0;

colorB = 0;

xpos = width/3;

ypos = height/3;

xspeed = 1;

Could it possibly be because I have the same line after it? (Though I've changed the values of some variables in it, am I right in saying modules/constructors should never have identical arguments? (Highlighted in bold below)

// Learning Processing

// Daniel Shiffman

// http://www.learningprocessing.com

//2. Check the Object Oriented Program for the Car.

//Improve the code such that you can change the color.

Car myCar, myCar1, myCar2; // Declare car object as a globle variable.

void setup() {

size(200,200);

// Initialize Car object

myCar = new Car(); // Initialize car object in setup()

//by calling constructor.

myCar1 = new Car(0,255,0,width/4,height*0.8,2);

myCar2 = new Car(0,0,255,width/8*5,height*0.5,3);

}

void draw() {

background(255);

// Operate Car object.

myCar.move(); // Operate the car object in draw( )

//by calling object methods using the

//dots syntax.

myCar.display();

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

myCar1.move();

myCar1.display();

//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

myCar2.move();

myCar2.display();

}

class Car { // Define a class below the rest

//of the program.

float colorR, colorG, colorB, xpos, ypos, xspeed;

Car() { // A constructor.

colorR = 0;

colorG = 255;

colorB = 0;

xpos = width/2;

ypos = height/2;

xspeed = 1;

}

Car(int colorR,int colorG,int colorB, float xpos, float ypos,int x) { // A constructor.

colorR = 255;

colorG = 0;

colorB = 0;

xpos = width/3;

ypos = height/3;

xspeed = 1;

}

Car(int colorR,int colorG,int colorB, float xpos, float ypos,int x) { // A constructor.

colorR = 0;

colorG = 0;

colorB = 255;

xpos = width/3*2;

ypos = height/3*2;

xspeed = 1;

}

void display() { // Function.

// The car is just a square

rectMode(CENTER);

stroke(0);

fill(colorR,colorG,colorB);

//Body

rect(xpos,ypos,50,30);

//Wheel

ellipse(xpos-15,ypos+15,10,10);

ellipse(xpos+15,ypos+15,10,10);

}

void move() { // Function.

xpos = xpos + xspeed;

if (xpos > width) {

xpos = 0;

}

Replies(8)

asimes

Re: Saying 'undefined' when it is defined

5 months ago

If you remove the second bold Constructor it works. Also, you can use Processing color type instead of r, g, and b:

void setup() {
size(100, 100);
Car example = new Car(color(0, 255, 0), width/2, height/2, 3);
exit();
}
class Car {
color c;
int speed, colorR, colorG, colorB;
float xPos, yPos;
Car(color inC, float inX, float inY, int inS) {
c = inC;
xPos = inX;
yPos = inY;
speed = inS;
}
}

truestory..

Re: Saying 'undefined' when it is defined

5 months ago

Thank you so much for your reply asimes. I've removed the second bolded constructor, however my third car is not appearing.

My understanding is that the following line of code will initialise the "Car" Object with the respective arguments (bolded):

~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

void setup() {
size(200,200);
// Initialize Car object
myCar = new Car(); // Initialize car object in setup()
//by calling constructor.
myCar1 = new Car(0,255,0,width/4,height*0.8,2);
myCar2 = new Car(0,0,255,width/4*3,height/4*3,3);
}

However, I do not get a third car :( is it because of the absence of a third constructor?

And thanks for the tip on colours :)

asimes

Re: Saying 'undefined' when it is defined

5 months ago

Actually, you only need one constructor regardless of how many cars there are. The only reason that the Car constructor without arguments is there is to make a "generic" Car where you don't specifically give it color, position, speed, etc.

If the other cars are not appearing then it is probably because they exist but nothing is displaying them. Here is an example.

Edit: I found that this was not the problem, but maybe this is useful to you anyway:

SimpleClass a, b, c, d;
void setup() {
size(400, 400);
/* Use the "default" constructor to make a
red ellipse() in the center of the screen */
a = new SimpleClass();
// Specifically set the other ones
b = new SimpleClass(color(0, 255, 0), 100, 100);
c = new SimpleClass(color(0, 0, 255), 100, 200);
d = new SimpleClass(color(255, 255, 0), 300, 100);
}
void draw() {
background(255);
a.display();
b.display();
c.display();
// I am not displaying d
}
class SimpleClass {
color c;
int x, y;
SimpleClass() {
c = color(255, 0, 0);
x = width/2;
y = height/2;
}
SimpleClass(color inC, int inX, int inY) {
c = inC;
x = inX;
y = inY;
}
void display() {
fill(c);
ellipse(x, y, 50, 50);
}
}

PhiLho

Re: Saying 'undefined' when it is defined

5 months ago

You don't need a constructor for each instance of the class you need to create! Imagine if you want to create 100 cars!
Moreover, you pass parameters to the constructor, but you just don't use them... So your third car is probably just hidden behind the second one, since they are at the same position.

asimes

Re: Saying 'undefined' when it is defined

5 months ago

I was looking at the code and realized that the arguments in the constructor have the same name as the class' variables, although as PhiLho said, the problem may have been that one car was hiding behind another. This works:

Car myCar, myCar1, myCar2;
void setup() {
size(200, 200);
myCar = new Car();
myCar1 = new Car(color(0, 255, 0), width/4, height*0.8, 2);
myCar2 = new Car(color(0, 0, 255), width/8, height*0.5, 3);
}
void draw() {
background(255);
myCar.move();
myCar.display();
myCar1.move();
myCar1.display();
myCar2.move();
myCar2.display();
}
class Car {
color c;
float speed, xpos, ypos;
Car() {
c = color(0, 255, 0);
xpos = width/2;
ypos = height/2;
speed = 1;
}
Car(color inC, float inX, float inY, float inS) {
c = inC;
xpos = inX;
ypos = inY;
speed = inS;
}
void display() {
rectMode(CENTER);
stroke(0);
fill(c);
rect(xpos, ypos, 50, 30);
ellipse(xpos-15, ypos+15, 10, 10);
ellipse(xpos+15, ypos+15, 10, 10);
}
void move() {
xpos += speed;
if (xpos > width) xpos = 0;
}
}

truestory..

Re: Saying 'undefined' when it is defined

5 months ago

Thanks! You explaining that the variable names can't be the same has lifted the fog.

I'm now going to inform my study group of this pitfall they may run into (I did, why not them?) by providing the following image

http://imgur.com/bY5TPJ1

Am I on the right track?

Thanks to everyone that has taken the time to help me out

Much appreciated :)

PhiLho

Re: Saying 'undefined' when it is defined

5 months ago

You must use the same variable names (field names, ie. the names of the variables declared at the class level) in the two constructors, but the parameter names must be different than the field names.

kooogy

Re: Saying 'undefined' when it is defined

5 months ago

> Am I on the right track?

no

the problem is the parameter names in the constructor matching the variable names.

this is right (from your example)

class Car {

color c;
float speed, xpos, ypos; // <- member names
Car(color inC, float inX, float inY, float inS) { // <- parameter names
c = inC;
xpos = inX;
ypos = inY;
speed = inS;
}
...

if the parameter names were c, xpos etc then you'd have c = c on line 5, which is confusing. you can get around the problem by using the 'this' keyword:

this.c = c; // set the c belonging to THIS instance to the value of the c parameter

but i prefer your way because it's easy to forget the 'this' and hard to spot when you do.

your previous problem was caused by the fact that you can only have one constructor with any given combination of parameters, otherwise how would it know which one to use?

public Car (int c){...};
public Car (int r){...}; // confusion, same as above
public Car (float r){...}; // this is fine, int != float