Saving MouseEvent Data In An Array

General Discussion Other

ebbnormal

Saving MouseEvent Data In An Array

in General Discussion • Other • 5 months ago

Hello. I am trying to write a program that stores the x, y coordinates of an a curve (not to be confused with the curve function) into an array. The curve is created by drawing a circle when the mouse is pressed and dragged across the screen. I would like to build up an array of the x,y coordinates so I can use the data as input into a generative art program. Any ideas? The following is what the curve would look like.

Replies(6)

Chrisir

Re: Saving MouseEvent Data In An Array

5 months ago

you can use an arraylist of PVector and if the mouse is dragged add an entry

pointMy = new PVector(mouseX, mouseY);

points.add(pointMy);

you could save the arraylist with savestring to your harddrive

GoToLoop

Re: Saving MouseEvent Data In An Array

5 months ago

Here's my take on it:

// http://forum.processing.org/topic/saving-mouseevent-data-in-an-array

import java.util.List;

final static List<PVector> coords = new ArrayList();

final static color BG = -1, FG = 0300, BORDER = 0;
final static short DIM = 20, BOLD = 2, FPS = 100, FREQ = 1;

void setup() {
  size(640, 480);
  smooth();
  noLoop();
  frameRate(FPS);

  fill(FG);
  stroke(BORDER);
  strokeWeight(BOLD);
}

void draw() {
  background(BG);

  if (frameCount == 1)  return;

  if (frameCount % FREQ == 0)  storeCoords();

  int i = coords.size();
  print(i + " - ");

  //displayCircles(i);

  for (PVector c: coords)  ellipse(c.x, c.y, DIM, DIM);
}

void mouseDragged() {
  redraw();
  //storeCoords();
}

void storeCoords() {
  coords.add( new PVector(mouseX, mouseY) );
}

void displayCircles(int i) {
  while (i-- != 0) {
    PVector c = coords.get(i);
    ellipse(c.x, c.y, DIM, DIM);
  }
}

GoToLoop

Re: Saving MouseEvent Data In An Array

5 months ago

Here's a more performance tweaked one.

It doesn't clear the canvas, and just displays latest added PVector instance from coords:

P.S.: You can also uncomment the storeCoords() call from mouseDragged(),

while commenting out the one from draw(). To get a more detailed mouse movement sample!

// http://forum.processing.org/topic/saving-mouseevent-data-in-an-array

import java.util.List;

final static List<PVector> coords = new ArrayList();

final static color BG = -1, FG = 0300, BORDER = 0;
final static short DIM = 20, BOLD = 2, FPS = 100, FREQ = 1;

void setup() {
  size(640, 480);
  smooth();
  noLoop();
  frameRate(FPS);

  fill(FG);
  stroke(BORDER);
  strokeWeight(BOLD);

  background(BG);
}

void draw() {
  if (frameCount == 1)  return;

  if (frameCount % FREQ == 0)  storeCoords();

  int i = coords.size();
  print(i + " - ");

  //displayCircles(i);

  //for (PVector c: coords)  ellipse(c.x, c.y, DIM, DIM);

  final PVector c = coords.get(i - 1);
  ellipse(c.x, c.y, DIM, DIM);
}

void mouseDragged() {
  redraw();
  //storeCoords();
}

void storeCoords() {
  coords.add( new PVector(mouseX, mouseY) );
}

void displayCircles(int i) {
  while (i-- != 0) {
    PVector c = coords.get(i);
    ellipse(c.x, c.y, DIM, DIM);
  }
}

GoToLoop

Re: Saving MouseEvent Data In An Array

5 months ago

Anyways, here's a more compact version w/ everything activated:

// http://forum.processing.org/topic/saving-mouseevent-data-in-an-array

import java.util.List;

final static List<PVector> coords = new ArrayList();

final static color BG = -1, FG = 0300, BORDER = 0;
final static short DIM = 20, BOLD = 2, FPS = 100;

void setup() {
  size(640, 480);
  smooth();
  noLoop();
  frameRate(FPS);

  fill(FG);
  stroke(BORDER);
  strokeWeight(BOLD);
  background(BG);
}

void draw() {
  print(coords.size() + " - ");
}

void mouseDragged() {
  redraw();
  coords.add( new PVector(mouseX, mouseY) );
  ellipse(mouseX, mouseY, DIM, DIM);
}

ebbnormal

Re: Saving MouseEvent Data In An Array

5 months ago

Thanks GoToLoop! That looks beautiful. Now my last question is, if I want to write the arrayList, coords, to a .txt file via the method saveStrings(), how can I convert it to type String[]. There is the method .toArray() on an arrayList but that gets you with something of type Object[]. Any ideas?

Thanks!

GoToLoop

Re: Saving MouseEvent Data In An Array

5 months ago

All mouse coords are stored within PVector instances, grouped in an ArrayList.

A Pvector class has 3 float field variables -> x, y, z. And only x & y are being used at all.

You just need to read each pair x & y of each PVector instance in the ArrayList ( coords variable),

concatenate them, and store in a String[] Array. Then, save that Array using saveStrings()!

Another option is rather than directly reading x & y, use PVector's method -> array().

Then, concatenate indices 0 & 1 from the resultant float[] Array!

I've left that alternative option commenting out. Either 1 works the same!

Just append this new callback function to the program above to get this new feature:

void keyTyped() {
  if (key != ' ' & key != RETURN & key != ENTER)  return;

  final String archive = dataPath("MouseCoords.txt");

  final int num = coords.size();
  final String[] coordsTxt = new String[num];

  for (int i = 0; i != num; ++i) {
    final PVector coord = coords.get(i);
    coordsTxt[i] = coord.x + "," + coord.y;

    //final int[] coord = int( coords.get(i).array() );
    //coordsTxt[i] = coord[0] + "," + coord[1];
  }

  saveStrings(archive, coordsTxt);
  println("\n\nMOUSE COORDS SAVED!\n");
}

Top Reply