/**
 * QueuedCapturer (v1.47)
 * by  GoToLoop (2013-Jun)
 * for Olga075
 *
 * http://forum.processing.org/topic/save-frames-per-second
 * https://github.com/onformative/ScreenCapturer
 */

import com.onformative.screencapturer.*;
ScreenCapturer capturer;
PImage captured;

import java.util.Queue;
import java.util.concurrent.ConcurrentLinkedQueue;
final  Queue<PImage> images = new ConcurrentLinkedQueue();

final static int FPS = 30, FREQ = 1000/FPS;

final static String NAME = "Capture-", EXT = ".jpg";
final static int DIGITS = 4, MAX_SAVES = 300;

boolean isCapturing, isBusy, isClosingDown;
int numbering;

void setup() {
  size(800, 600);
  frameRate(FPS);

  capturer = new ScreenCapturer(width, height, FPS);
  mousePressed();  // starts threads

  while (captured == null)  delay(100); // awaits for 1st snap
}

void draw() {
  image(captured, 0, 0);  // displays latest snapshot
  displayInfo();
  if (numbering + images.size() >= MAX_SAVES)   exit();
}

void mousePressed() {
  if (isClosingDown)
    println("Program is closing down. Calm down!");

  else if (isBusy) {
    print("Sorry, still emptying buffer! ");
    println("Wait some more and re-click to resume...");
  }

  else if (isCapturing = !isCapturing) {
    thread("enqueueImages");
    thread("saveImages");
    println("Screen capturing has started!!!");
  }

  else {
    isBusy = true; // halts snapshot resume till queue's empty
    println("Capturing paused! Click again to resume...");
  }
}

void displayInfo() {
  frame.setTitle( "FPS: " + round(frameRate)
    + "\t\t\tSaved : " + numbering
    + "\t\tBuffer: " + images.size() );
}

void enqueueImages() {
  final Queue imgs = images; // local caching

  while (isCapturing) {
    imgs.add( captured = capturer.getImage() );
    delay(FREQ); // awaits for next snapshot
  }
}

void saveImages() {
  final Queue<PImage> imgs = images; // local caching
  PImage img;
  final String dir = dataPath(NAME);

  while (isCapturing || !imgs.isEmpty ()) {
    delay(100); // slows down choking thread-shared variables

    while ( (img = imgs.poll ()) != null )
      img.save(dir + nf(++numbering, DIGITS) + EXT);
  }

  delay(100); // avoids a racing modification of next line's var.
  isBusy = false; // queue's empty & threads are now free to resume
}

@Override void exit() {
  if (isClosingDown)  return; // exit() invoked already.

  isClosingDown = isBusy = true;
  isCapturing = false;

  println("Emptying queued image buffer! Please wait...");
  while (isBusy)  delay(200);

  println("Finished!!!");
  super.exit();
}