/**
 * Sphere of Points (v1.2)
 * by Patakk (2013/Feb)
 *
 * http://forum.processing.org/topic/
 * opengl-error-1280-tried-to-fix-it-with-newest-
 * graphics-card-drivers-the-problem-is-still-here
 */

final static short POINTS = 8000;
final static PVector[] points = new PVector[POINTS];
final static float SPD = 2e-3;
float rotX, rotY;
//--------------------------------------------------------
void setup() {
  size(512, 512, P3D);
  frameRate(25);
  smooth();
  fill(-1);
  strokeWeight(2);

  createSpherePoints();
}
//--------------------------------------------------------
void draw() {
  background(222);
  translate(width>>1, height>>1);
  rotateX(rotX);
  rotateY(rotY += SPD);

  for (PVector p: points)   point(p.x, p.y, p.z);

  if (mousePressed) {
    rotY += (pmouseX - mouseX) * -SPD;
    rotX += (pmouseY - mouseY) * SPD;
  }

  frame.setTitle( "Sphere of Points\t\tFPS: " + round(frameRate) );
}
//--------------------------------------------------------
void keyPressed() {
  if (keyCode == 'S')   saveFrame(dataPath("Sphere.####.png"));
  else if (key == ' ')  createSpherePoints();
}
//--------------------------------------------------------
void createSpherePoints() {
  for ( int ni=0; ni!=POINTS; 
    points[ni++] = randomSpherePoint(width/2.5) );
}
//--------------------------------------------------------
// return random sphere point using method of Cook/Neumann
//--------------------------------------------------------
PVector randomSpherePoint(float radius) {
  float a=0, b=0, c=0, d=0, k=99;

  while (k >= 1) {
    a = random(-1, 1);
    b = random(-1, 1);
    c = random(-1, 1);
    d = random(-1, 1);

    k = a*a + b*b + c*c + d*d;
  }

  k /= radius;

  return new PVector
    (2*(b*d + a*c) / k
    , 2*(c*d - a*b) / k
    , (a*a + d*d - b*b - c*c) / k);
}

// http://forum.processing.org/topic/processing-question
// http://forum.processing.org/topic/generate-a-square-grid
// http://studio.processingtogether.com/sp/pad/export/ro.9PDcp7xMBknWz/latest

final static byte SQUARES = 4;
final static color[] colors = new color[SQUARES];

// Choose JAVA2D, P2D, P3D or OPENGL:
final static String ENGINE = JAVA2D;

void setup() {
  size(01510, 01510, ENGINE);
  frameRate(50);
  noLoop();
  noStroke();
  noCursor();
  rectMode(CORNERS);  // CORNER works too!

  mousePressed();
}

void draw() {
  fill(colors[0]);
  rect(0, 0, mouseX, mouseY);

  fill(colors[1]);
  rect(mouseX, 0, width, mouseY);

  fill(colors[2]);
  rect(0, mouseY, mouseX, height);

  fill(colors[3]);
  rect(mouseX, mouseY, width, height);
}

void mousePressed() {
  redraw();

  for ( byte c = SQUARES; c-- != 0; 
  colors[c] = (color) random(#000000) );

  print(hex(colors[0]) + "\t");
  
  saveFrame(dataPath("4ColorRects.####.png"));
}

void mouseMoved() {
  redraw();
}

void mouseDragged() {
  redraw();
}