Saved PDF is blank :(

Core Library Questions

likandoo

in Core Library Questions • 4 months ago

Hello guys :)

I have a short question.

Why does the following Sketch give me a blank pdf?

import processing.pdf.*;
boolean record;
void setup () {
size(600, 600);
smooth();
background(255);
}
void draw () {
if (record) {
beginRecord(PDF, "frame-####.pdf");
}
stroke (0,0,0);
line(frameCount*100, 600 , frameCount*100, 0);
if (record) {
endRecord();
record = false;
}
}
void keyPressed() {
record = true;
}

Replies(3)

GoToLoop

Re: Saved PDF is blank :(

4 months ago

Haven't looked at your code yet. However, here's a PDF recording example that works:

http://forum.processing.org/topic/pdf-export-shapes-misaligned

kooogy

that's pretty much identical to the example in the reference here

http://processing.org/reference/libraries/pdf/index.html

which i assume works.

so i think your problem is that you're drawing offscreen

line(frameCount*100, 600 , frameCount*100, 0);

with a screen size of 600x600 gives you 6 frames, about a 1/10th of a second, to press a key and save an image.

GoToLoop

Re: Saved PDF is blank :(

4 months ago

That's right! Found out that too! Those lines are being drawn far off screen!

And keeps getting even farther as it goes!

Since the screen isn't cleared after all, it displays the initial drawings which were still inbound!

However, PDF mode doesn't care what was previously displayed. Recording is only for newer content!

Here's your program tweaked and fixed:

// http://forum.processing.org/topic/saved-pdf-is-blank

import processing.pdf.*;

final static short SHAKE = 10, FPS = 20, BOLD = 4;
final static color BG = -1, FG = #FF0000;

final String NAME = "frame-####.pdf";
String path;

void setup () {
  size(300, 200);
  frameRate(FPS);

  path = dataPath(NAME);

  initialize();
}

void draw () {
  final boolean isRecording = keyPressed | mousePressed;

  if (isRecording) {
    beginRecord(PDF, path);
    initialize(); // initialize PDF's own graphics setup
  }

  background(BG);

  final int posX = frameCount % width + (int) random(SHAKE);
  line(posX, 0, posX, height);

  if (isRecording)    endRecord();
}

void initialize() {
  smooth();
  stroke(FG);
  strokeWeight(BOLD);
}

Top Reply