[Solved] SaveBytes() and LoadBytes() acting up

Programming Questions

mentecode

[Solved] SaveBytes() and LoadBytes() acting up

in Programming Questions • 7 months ago

Hello all.

I just had the array problem more or less dealt with ( Saving Game Level), but now it has given me a new problem.
I have the program rearranging the 2D array into a 1D array, and I'm using the Processing reference example for loadBytes() to test the efficiency and effectiveness of saveBytes() in my program ( loadBytes()).

What saveBytes() is actually doing, by the looks of it, is that it is mirroring the entire array on some sort of diagonal line.
Or the main program overall is made improperly.
Here are some images of what is happening:

This is the way the main
program shows the level:

Then the reference program
interprets the array like this:

Which is the same as this:

It's as though the program flipped the image vertically, then turned it quarter turn clockwise.
Why is the main program saving the array like this?
Code in the next post.

- MenteCode.

Replies(11)

mentecode

Re: SaveBytes() and LoadBytes() acting up

7 months ago

Here's the code:

int rows = 5;
int cols = 7;
int x; //Random entrance position x
int y; //Random entrance position y
int timer = 1;
byte[][] level = new byte[rows][cols];
byte[] sve = new byte[rows * cols]; //Saving array
void setup() {
size(1000, 600);
}
void draw() {
gen(); //Level generation function
sav(); //Saving function
display(); //Display function
}
void gen() {
level[0][0] = 3;
level[rows - 1][0] = 3;
level[0][cols - 1] = 3;
level[rows - 1][cols - 1] = 3;
for(int fx = 1; fx < rows - 1; fx++) {
for(int fy = 1; fy < cols - 1; fy++) {
level[fx][fy] = 2;
}
}
if(timer > 0) {
x = int(random(rows));
y = int(random(cols));
if(level[x][y] == 0) {
level[x][y] = 1;
noLoop();
}
}
else {
timer = 1;
}
}
void sav() {
for(int i = 0; i < rows; i++) {
int srcp = i * cols;
arrayCopy(level[i], 0, sve, srcp, cols);
}
saveBytes("Level.dat", sve);
}
void display() {
for(int i = 0; i < rows; i++) {
for(int j = 0; j < cols; j++) {
fill(level[i][j] * 255);
rect(i * 20, j * 20, 20, 20);
}
}
}

The reading code is above (loadBytes).

- MenteCode.

P. S. Don't mind the difference between the pictures and your run. The entrance is generated randomly.

GoToLoop

Re: SaveBytes() and LoadBytes() acting up

7 months ago

I believe you want an image which is 5x7. That is, 5 columns & 7 rows, right?
But what I see in your code is -> rows = 5 & cols = 7!!!

mentecode

Re: Re: SaveBytes() and LoadBytes() acting up

7 months ago

I don't get that either. I'm trying to get 7 columns and 5 rows.

I keep trying to make it iterate through the number of columns, and the number of rows.

Instead, for some reason, it iterates through the length of the columns, and the length of the rows,
and what I'm assuming the program does, is that saveBytes() is doing what it is supposed to do, but
the display function and the rest of the program overall is doing very stupid things, like I mentioned above.

- MenteCode.

PhiLho

Re: SaveBytes() and LoadBytes() acting up

7 months ago

I don't understand where you load the level.

mentecode

Re: Re: SaveBytes() and LoadBytes() acting up

7 months ago

Oh, sorry.

I didn't put that in yet, but instead I'm using the loadBytes() example that is shown at the top.
I does the same thing, so use that for now.

- MenteCode

GoToLoop

Re: SaveBytes() and LoadBytes() acting up

7 months ago

Is that pixelated zero what you're trying to achieve?
For my eyes, it is 5 cols x 7 rows!

So, it should be something like ---> final static byte levels = 10, cols = 5, rows = 7;

You only have to pay attention when rendering from the Array level[row][col].
Since in graphics you specify the scalar x (col) 1st, then y (row).

GoToLoop

Re: SaveBytes() and LoadBytes() acting up

7 months ago

final static byte levels = 10, cols = 5, rows = 7;

final static byte[][][] game  = new byte[levels][rows][cols];
final static byte[][]   level = new byte[rows][cols];
final static byte[]     sve   = new byte[rows * cols]; //Saving array

final static byte tileExit   = 1;
final static byte tileWall   = 2;
final static byte tileEmpty  = 3;

void setup() {
  size(0400, 0300);
  noLoop();
}

void draw() {
  gen(); //Level generation function
  sav(); //Saving function
  display(); //Display function
}

void gen() {
  level[0][0] = tileEmpty;
  level[rows - 1][0] = tileEmpty;
  level[0][cols - 1] = tileEmpty;
  level[rows - 1][cols - 1] = tileEmpty;

  for (int fx = 1; fx < rows - 1; fx++)
    for (int fy = 1; fy < cols - 1; fy++)
      level[fx][fy] = tileWall;

  int x = (int) random(rows);
  int y = (int) random(cols);

  if (level[x][y] == 0)   level[x][y] = tileExit;
}

void sav() {
  for (int row = 0; row < rows; row++) {
    int srcp = row * cols;
    arrayCopy(level[row], 0, sve, srcp, cols);
    println(level[row]);
  }
  saveBytes("Level.dat", sve);
  println(sve);
}

void display() {
  for (int i = 0; i < rows; i++)
    for (int j = 0; j < cols; j++) {
      fill(level[i][j] * 255);
      rect(j*20, i*20, 20, 20);

      fill(sve[i*cols + j] * 255);
      rect(j*20 + 0200, i*20, 20, 20);
    }
}

mentecode

Re: Re: SaveBytes() and LoadBytes() acting up

7 months ago

That is WEIRD!

What's the difference between your version of the code, and my version of the code listed above, besides you using final static byte, and you using variables to define the tiles?

- MenteCode

mentecode

Re: SaveBytes() and LoadBytes() acting up

7 months ago

Ohhhhhhhhh!!!

In void display(), I used int j and int i improperly! Why does it work that way!? Can someone tell me how to remember to use the displaying integers this way?

Thanks for everything!

- MenteCode.

GoToLoop

Re: SaveBytes() and LoadBytes() acting up

7 months ago

In void display(), I used int j and int i improperly! Why does it work that way!?

Already told you:
Canvas coordinates are x (or column) and y (or row). But your Array is row 1st, then col.
So you gotta swap them (besides scaling them up) when rendering!

mentecode

Re: Re: SaveBytes() and LoadBytes() acting up

7 months ago

Already told you:
Canvas coordinates are x (or column) and y (or row). But your Array is row 1st, then col.

Oh. I didn't quite catch that the first time. But now it all makes sense and fits together the way it is supposed to.
Thanks again.

- MenteCode.

Top Reply