1. enqueueImages() -> stores a captured PImage into a ConcurrentLinkedQueue object after each FREQ time delay.
2. saveImages() -> extracts a PImage from the Queue and stamps it into a PGraphics. Then save() it as a file.

Those 2 Threads run independently and at the same time as draw()! So there's no time wasted!!!  

• transferred to draw() the task to stamp captured PImage.
• save threshold -> MAX_SAVES.

• removed PGraphics instance. Using method save() directly from class PImage!

v1.30:

• locally caching Queue variable within Thread methods.
• Check whether buffer is empty thru' isBusy rather than images.isEmpty() within exit().

v1.35:

• added more comments.
• some minor adjustments.

v1.40:

• many fixes for pause/resume/exit locks. Especially when FPS has a low value.
  
• regression: images.isEmpty() is indeed the best indicator that threads have finished.

v1.45:

• new flag field -> isClosingDown. Guarantees a smooth shutdown till Queue's empty. 
• an extra delay() within saveImages() to avoid turning off isDelay before mousePressed() has a chance to turn it on! Otherwise, mousePressed() wouldn't be capable to resume Queue's threads anymore!
• isBusy can re-again be used as a reliable indicator Queue is empty within overridden exit(). 

v1.46:

• Forgotten to flag isBusy as well within exit(). Program quits before emptying Queue.

v1.47:

• Included -> if (isClosingDown)  return; within exit() to avoid multiple callings on it due to many ESC presses from user.
  

/**
 * QueuedCapturer (v1.47)
 * by  GoToLoop (2013-Jun)
 * for Olga075
 *
 * http://forum.processing.org/topic/save-frames-per-second
 * https://github.com/onformative/ScreenCapturer
 */

import com.onformative.screencapturer.*;
ScreenCapturer capturer;
PImage captured;

import java.util.Queue;
import java.util.concurrent.ConcurrentLinkedQueue;
final  Queue<PImage> images = new ConcurrentLinkedQueue();

final static int FPS = 30, FREQ = 1000/FPS;

final static String NAME = "Capture-", EXT = ".jpg";
final static int DIGITS = 4, MAX_SAVES = 300;

boolean isCapturing, isBusy, isClosingDown;
int numbering;

void setup() {
  size(800, 600);
  frameRate(FPS);

  capturer = new ScreenCapturer(width, height, FPS);
  mousePressed();  // starts threads

  while (captured == null)  delay(100); // awaits for 1st snap
}

void draw() {
  image(captured, 0, 0);  // displays latest snapshot
  displayInfo();
  if (numbering + images.size() >= MAX_SAVES)   exit();
}

void mousePressed() {
  if (isClosingDown)
    println("Program is closing down. Calm down!");

  else if (isBusy) {
    print("Sorry, still emptying buffer! ");
    println("Wait some more and re-click to resume...");
  }

  else if (isCapturing = !isCapturing) {
    thread("enqueueImages");
    thread("saveImages");
    println("Screen capturing has started!!!");
  }

  else {
    isBusy = true; // halts snapshot resume till queue's empty
    println("Capturing paused! Click again to resume...");
  }
}

void displayInfo() {
  frame.setTitle( "FPS: " + round(frameRate)
    + "\t\t\tSaved : " + numbering
    + "\t\tBuffer: " + images.size() );
}

void enqueueImages() {
  final Queue imgs = images; // local caching

  while (isCapturing) {
    imgs.add( captured = capturer.getImage() );
    delay(FREQ); // awaits for next snapshot
  }
}

void saveImages() {
  final Queue<PImage> imgs = images; // local caching
  PImage img;
  final String dir = dataPath(NAME);

  while (isCapturing || !imgs.isEmpty ()) {
    delay(100); // slows down choking thread-shared variables

    while ( (img = imgs.poll ()) != null )
      img.save(dir + nf(++numbering, DIGITS) + EXT);
  }

  delay(100); // avoids a racing modification of next line's var.
  isBusy = false; // queue's empty & threads are now free to resume
}

@Override void exit() {
  if (isClosingDown)  return; // exit() invoked already.

  isClosingDown = isBusy = true;
  isCapturing = false;

  println("Emptying queued image buffer! Please wait...");
  while (isBusy)  delay(200);

  println("Finished!!!");
  super.exit();
}

1.  saveFrame("something####.jpg");  

1. saveFrame("something####.tga");    // extension for TARGA images. This was popular format in 90ties.

1. saveFrame("something###.tif");