Rotation looking through a vector - Help!

Programming Questions

jeff_g

Rotation looking through a vector - Help!

in Programming Questions • 3 years ago

I've been beating my head on this all day and would greatly appreciate any help. I'm working on an addition to the PeasyCam library that would allow us to look through a xyz point.

So you have two points, the one your looking at (always 0,0,0), and the one you're looking through. I have everything completed except I'm getting stuck on the x,y,z to pitch,yaw,roll conversion. I've read through the forum but my math is just not that strong to understand some of the explanations. This thread is good but I don't understand it. This article is informative, but it doesn't work.

Example problem looks like this.. see the mouseclick area for the offending code.

import peasy.PeasyCam; //peasy camera control
PeasyCam cam;
float x,y,z;
void setup() {
size(600, 500, P3D );
cam = new PeasyCam(this, 1000);
cam.setMinimumDistance(150);
cam.setMaximumDistance(800);
noStroke();
}
void draw() {
background(0);
fill(255,0,0);
sphere(25);
//converted long/lat for new york city
x = -73;
y = -21;
z = -64;
pushMatrix();
translate(x,y,z);
fill(0,255,0);
sphere(10);
popMatrix();
}
void mouseClicked() {
//Need Help Here!!!
float r = sqrt(x * x + y * y + z * z);
float roll = -HALF_PI;
float yaw = -acos(z / r);
float pitch = atan2(z, x);
cam.setRotations(pitch,yaw,roll);
}

From my simple tests. It appears that the pitch, yaw, and roll should be something like this (these values look through the sphere).
roll = -1.5707963
yaw = -2.3125612
pitch = -0.31500

My pitch is way off, and my yaw is partly off. So I figure this should be pretty exact - so I'm doing something seriously wrong.

Replies(17)

kooogy

Re: Rotation looking through a vector - Help!

3 years ago

which way's up?

because if it's Y then i'd expect to see y in the pitch calculation. i'd also expect your y to be positive, NY being in the northern hemisphere and all.

also, are you sure about your expected values? i'd've thought they'd be the same as the lat-long values you started with, only in radians, something like

[NYC] 40.77 73.98 New York,NY (degrees, from here: http://www.realestate3d.com/gps/latlong.htm)
.711 and 1.29 radians

might be easier starting with london 8)

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

Once I apply the texture to the sphere, -Z becomes North. Here is my code for calculating the lat/long.
    x = r * sin(angEW) * cos(angNS);
    y = - r * cos(angNS) * cos(angEW);
    z = - r * sin(angNS);

NYC is at 74W or -74, so the radians would be .711 and -1.29.

I guess I may need to create some method in PeasyCam to allow the user to define which direction is up if that effects the calculation.

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

Looks like everything I need is already in the Rotation.java and Vector3D.java. I just don't know how to use it.

Jack Kern

Re: Rotation looking through a vector - Help!

3 years ago

Hey Jeff, I really appreciate using your peasycam library, so hopefully I can be of a little assistance! Here's how I would approach the problem -- though I haven't tested this all out. I'm fairly certain it will work, I'm just not 100% on my matrix calculation, and you might need to offset the angle calculations to put them in the right position for your coordinate system.

You have been warned

Figure 1 (I've always wanted to say that!)

First make sure CamVector is the vector from origin to the camera position

Project CamVector to X/Y plane by saying Z = 0

yaw = atan2( -CamVector.y, CamVector.x ) // Should give you the angle around Z

CVX = Vector3( CamVector.x, CamVector.y, 0 )

CVZ = Vector3( 0, 0, -1 );

CVY = CVX cross CVZ

Normalize all three vectors, now you have a the basis vectors for a matrix to rotate the cam vector into:

(Check my math here, this is from memory and I believe the basis vectors should be the column vectors of the matrix, please correct me if I'm wrong)

PV.x = CVX.x * CamVector.x + CVY.x * CamVector.y + CVZ.x * CamVector.z

PV.y = CVX.y * CamVector.x + CVY.y * CamVector.y + CVZ.y * CamVector.z

PV.z = CVX.z * CamVector.x + CVY.z * CamVector.y + CVZ.z * CamVector.z

Assume PV.y = 0 (Projection onto new X/Z, inside post-yaw rotation space)

Final values should be:

pitch = atan2( -PV.z, PV.x )

roll = 0 // Or whatever no roll is in your coordinate system

Hope that helps you work it out!

Best,

Jack

http://www.jackkern.com
http://www.twitter.com/ElectricJack

kooogy

Re: Re: Rotation looking through a vector - Help!

3 years ago

isn't that the wrong way around though - he wants the camera at CamVector looking at the origin. (yes, just reverse it)

going back to the .711 / -1.29

println(atan2(64, 73)); // pitch
println(acos(21.0f / 100.0f)); // yaw

gives .719 / 1.35, which are close enough given you've rounded up the position

this is actually conversion from cartesian to spherical coords and is described here under Conversions

http://en.wikipedia.org/wiki/Spherical_coordinate_system#Cartesian_coordinates

but i think you have to be careful in the order you apply them in cam.setRotations(). think they need to be x then y then z

Jack Kern

Re: Re: Rotation looking through a vector - Help!

3 years ago

Sure reverse the vector if you need to.

The problem is that the yaw effects getting the pitch value (well, actually that depends on the order of the rotations inside peasycam), so that's where the need comes in to translate that view vector into the first rotation's space.

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

Thanks Jack, I'm giving it a try but no luck yet. The PeasyCam is not my library, it's Jonathan Fienberg's. I'm just trying to extend the functionality of it. I added this to my code, with many variations with no success yet.

PVector CamVector = new PVector(x,y,z);
PVector CVX = new PVector(CamVector.x, CamVector.y, CamVector.z);
PVector CVZ = new PVector(0,0,-1);
PVector CVY = CVX.cross(CVZ);
PVector PV = new PVector();
PV.x = CVX.x * CamVector.x + CVY.x * CamVector.y + CVZ.x * CamVector.z;
PV.y = CVX.y * CamVector.x + CVY.y * CamVector.y + CVZ.y * CamVector.z;
PV.z = CVX.z * CamVector.x + CVY.z * CamVector.y + CVZ.z * CamVector.z;
float pitch = atan2( -PV.z, PV.x );
float yaw = atan2( -CamVector.y, CamVector.x );
float roll = HALF_PI;

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

kooogy, this didn't line up the green sphere. The rotation order being applied is XYZ.

float pitch = atan2(-64, -73);
float yaw = acos(-21.0f/100.0f);

To Jack's comment, the Rotation.java and Vector3D.java files have the info for doing Euler, Quaternion, or Angle. Problem is, I just don't understand enough to know how to use the methods. I've read several websites, but they don't explain enough for it to make sense to me.

It might looks something like..

Vector3D v = new Vector3D(x,y,z);
Rotation r = new Rotation(Vector3D.plusI, v);

I don't know.. once I get the rotation, I can apply it. It's just that conversion from xyz into the proper rotation that is killing me.

kooogy

Re: Re: Rotation looking through a vector - Help!

3 years ago

can you use peasycam to work these out?

set the lookat to be new york, distance to be your 100. then manipulate the camera with the mouse until the camera position is 0, 0, 0 and print out the angles?

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

From what I understand, the lookAt point is always 0,0,0 in peasycam. I think the angles for the green sphere in the example, should be something like:

pitch = 2.8255
yaw = -0.8255
roll = 1.552

Jack Kern

Re: Re: Rotation looking through a vector - Help!

3 years ago

This version works for me, I was wrong about the order of rotations so my calcuations were wrong. That and a bit of trial and error resulted in this:

import peasy.PeasyCam;  //peasy camera control
PeasyCam cam;
float x,y,z;

void setup() {
  size(600, 500, P3D );
  cam = new PeasyCam(this, 1000);
  cam.setMinimumDistance(150);
  cam.setMaximumDistance(800);
  noStroke();
  
  x = -73;   
  y = -21;
  z = -64;
}

void draw() {
  background(0);
 
  fill(255,0,0);
  
  sphere(25);
  stroke(200,0,0);
  line(0,0,0,100,0,0);
  stroke(0,200,0);
  line(0,0,0,0,100,0);
  stroke(0,0,200);
  line(0,0,0,0,0,100);
  
 //converted long/lat for new york city

  noStroke();
  pushMatrix();
    translate(x,y,z);
    fill(0,255,0);
    sphere(10);
  popMatrix();
}

void mouseReleased() {
  if( mouseButton == LEFT ) computeRotations();
  else
  {
    float s = 300;
    x = random(-s,s);   
    y = random(-s,s);
    z = random(-s,s);
  }
}

void computeRotations() {

  PVector CamVector = new PVector(x,y,z);
  
  PVector CVY = new PVector(0, CamVector.y, CamVector.z);
  PVector CVX = new PVector(1,0,0);
  PVector CVZ = CVX.cross(CVY);
  
  CVX.normalize();
  CVY.normalize();
  CVZ.normalize();

  PVector PV = new PVector( CVX.dot( CamVector )
                          , CVY.dot( CamVector )
                          , CVZ.dot( CamVector ));
 
  float pitch = atan2( CamVector.z, CamVector.y ) - HALF_PI;
  float yaw   = atan2( PV.x, PV.y );
  float roll  = 0;
 
  cam.setRotations(pitch,yaw,roll);
}

Right click to set the sphere at another random location, then left click to look through that object!

http://www.jackkern.com
http://www.twitter.com/ElectricJack

kooogy

Re: Rotation looking through a vector - Help!

3 years ago

you can specify a new lookat point, and the distance, in the constructor.

PeasyCam(PApplet parent, double lookAtX, double lookAtY, double lookAtZ, double distance);

Jack Kern

Re: Re: Rotation looking through a vector - Help!

3 years ago

Also, be sure to subtract the look at position from the camera position to get the CamVector if you want to support changing the look at position.

http://www.jackkern.com
http://www.twitter.com/ElectricJack

jeff_g

Re: Re: Rotation looking through a vector - Help!

3 years ago

I know you can set the lookAt there, but I think it realigns it to 0,0,0. So I'll have to test if changing the lookAt requires changing the CamVector.

jeff_g

Re: Rotation looking through a vector - Help!

3 years ago

Thanks Jack! This looks like the way to do it. That really brought this closer to being done. Do you guys have any suggestions on keeping an orientation, so that a particular direction is always north? I'm going to work on it tomorrow and see what is left.

pixelnerve

Re: Rotation looking through a vector - Help!

3 years ago

Seems to me you want to compute a view matrix from a view vector (origin - lookat). Using a up vector that is samething as using gluLookAt, but you probably want to use Rotation (quaternion) no ?

have a look at this http://www.gamedev.net/reference/programming/features/quatcam/default.asp

hope it helps

edit:
now that i think about it, you want the origin at sphere surface always looking at center (0,0,0). Have you looked into arcball?

jeff_g

Re: Re: Rotation looking through a vector - Help!

3 years ago

V pixelnerve, yes that does seem like the best way to go about doing it. As of now, I can't control it from rotating up-side-down.

Top Reply