Sounds like a familiar problem... Oh, yes, it is: mirroring image using blend()
I have since then improved a bit the code, including rotations, but the user interface is a bit clumsy/non intuitive... Here it is, anyway, it shows the base idea:

1. PFont fontMenu, fontHelp;
2.  
3. int IMAGE_W = 500;
4. int IMAGE_H = 500;
5. int CHOICE_T = 40;
6. int CHOICE_L = 50;
7. int CHOICE_W = 200;
8. int CHOICE_SPACING = 25;
9. PGraphics baseImage;
10. PGraphics resultImage;
11. int lineNb = 50;
12. int lengthIncrement = 7;
13. boolean bDoBlend;
14.  
15. BlendMode currentBlendMode;
16. class BlendMode
17. {
18.   int blendMode;
19.   String blendName;
20.   BlendMode(int bm, String bn) { blendMode = bm; blendName = bn; }
21.   String toString() { return blendName; }
22. }
23. ArrayList<BlendMode> blendModes = new ArrayList<BlendMode>();
24.  
25. void setup()
26. {
27.   size(700, 500);
28.   smooth();
29. //  noLoop();
30.   fontHelp = createFont("Tahoma", 12);
31.   fontMenu = createFont("Tahoma Bold", 14);
32.  
33.   blendModes.add(new BlendMode(REPLACE, "REPLACE"));
34.   blendModes.add(new BlendMode(BLEND, "BLEND"));
35.   blendModes.add(new BlendMode(ADD, "ADD"));
36.   blendModes.add(new BlendMode(SUBTRACT, "SUBTRACT"));
37.   blendModes.add(new BlendMode(LIGHTEST, "LIGHTEST"));
38.   blendModes.add(new BlendMode(DARKEST, "DARKEST"));
39.   blendModes.add(new BlendMode(DIFFERENCE, "DIFFERENCE"));
40.   blendModes.add(new BlendMode(EXCLUSION, "EXCLUSION"));
41.   blendModes.add(new BlendMode(MULTIPLY, "MULTIPLY"));
42.   blendModes.add(new BlendMode(SCREEN, "SCREEN"));
43.   blendModes.add(new BlendMode(OVERLAY, "OVERLAY"));
44.   blendModes.add(new BlendMode(HARD_LIGHT, "HARD_LIGHT"));
45.   blendModes.add(new BlendMode(SOFT_LIGHT, "SOFT_LIGHT"));
46.   blendModes.add(new BlendMode(DODGE, "DODGE"));
47.   blendModes.add(new BlendMode(BURN, "BURN"));
48.  
49.   currentBlendMode = blendModes.get(0);
50.  
51.   baseImage = createGraphics(IMAGE_W, IMAGE_H, JAVA2D);
52.   DrawImage();
53.   resultImage = createGraphics(IMAGE_W, IMAGE_H, JAVA2D);
54.   resultImage.beginDraw();
55.   resultImage.image(baseImage, 0, 0);
56.   resultImage.endDraw();
57. }
58.  
59. void draw()
60. {
61.   background(#99EEFF);
62.   ShowBlendChoices();
63.   image(resultImage, CHOICE_W, 0);
64. }
65.  
66. // Choosing the operation to do
67. // Will add choice of blend mode...
68. void keyPressed()
69. {
70.   // Update base image with current screen
71.   baseImage.beginDraw();
72.   baseImage.copy(g, CHOICE_W, 0, IMAGE_W, IMAGE_H, 0, 0, IMAGE_W, IMAGE_H);
73.   baseImage.endDraw();
74.  
75.   switch (key)
76.   {
77.   case 'b':
78.     bDoBlend = !bDoBlend;
79.     println("Blend? " + bDoBlend);
80.     break;
81.   case 'i':
82.     if (bDoBlend)
83.     {
84.       BlendInverted();
85.     }
86.     else
87.     {
88.       DrawInverted();
89.     }
90.     break;
91.   case 'r':
92.     if (bDoBlend)
93.     {
94.       BlendReflected();
95.     }
96.     else
97.     {
98.       DrawReflected();
99.     }
100.     break;
101.   case 's':
102.     if (bDoBlend)
103.     {
104.       BlendShifted();
105.     }
106.     else
107.     {
108.       DrawShifted();
109.     }
110.     break;
111.   case 't':
112.     if (bDoBlend)
113.     {
114.       BlendRotated();
115.     }
116.     else
117.     {
118.       DrawRotated();
119.     }
120.     break;
121.   case 'c': // clear
122.     DrawImage();
123.     resultImage.beginDraw();
124.     resultImage.image(baseImage, 0, 0);
125.     resultImage.endDraw();
126.     break;
127.   }
128.   redraw();
129. }
130.  
131. // Try to make an interesting base image
132. // Square spiral, slightly improved from yet another old sketch
133. void DrawImage()
134. {
135.   baseImage.beginDraw();
136.   baseImage.colorMode(HSB, 1000);
137.   baseImage.fill(#DDEEFF);
138.   baseImage.rect(0, 0, IMAGE_W, IMAGE_H);
139.   baseImage.strokeWeight(7);
140. //  stroke(#005080);
141.   int cH = 200, cS = 1000, cB = 500;
142.   int lineLength = 5;
143.   int x, y;
144.   int px, py;
145.   px = x = baseImage.width / 2;
146.   py = y = baseImage.height / 2;
147.  
148.   for (int i = 0; i < lineNb; i++)
149.   {
150.     switch (i % 4)
151.     {
152.     case 0:
153.       x -= lineLength;
154.       break;
155.     case 1:
156.       y -= lineLength;
157.       break;
158.     case 2:
159.       x += lineLength;
160.       break;
161.     case 3:
162.       y += lineLength;
163.       break;
164.     }
165.     baseImage.stroke(cH, cS, cB);
166.     cH += 1000 / lineNb;
167.     cS -= 1000 / lineNb;
168.     cB += 10;
169.     baseImage.line(px, py, x, y);
170.     px = x; py = y;
171.     lineLength += lengthIncrement;
172.   }
173.   baseImage.endDraw();
174. }
175.  
176. void DrawInverted()
177. {
178.   println("DrawInverted");
179.   resultImage.beginDraw();
180.   resultImage.translate(baseImage.width, baseImage.height);
181.   resultImage.rotate(PI);
182.   resultImage.image(baseImage, 0, 0);
183.   resultImage.endDraw();
184. }
185.  
186. void DrawReflected()
187. {
188.   println("DrawReflected");
189.   resultImage.beginDraw();
190.   resultImage.translate(0, baseImage.height);
191.   resultImage.scale(1.00, -1.00);
192.   resultImage.image(baseImage, 0, 0);
193.   resultImage.endDraw();
194. }
195.  
196. void DrawShifted()
197. {
198.   println("DrawShifted");
199.   float SCALE = 1.2;
200.   float ns = baseImage.width * (SCALE - 1) / 2;
201.   resultImage.beginDraw();
202.   resultImage.translate(-ns, -ns);
203.   resultImage.scale(SCALE, SCALE);
204.   resultImage.image(baseImage, 0, 0);
205.   resultImage.endDraw();
206. }
207.  
208. void DrawRotated()
209. {
210.   println("DrawRotated");
211.   float ns = resultImage.width;
212.   resultImage.beginDraw();
213.   resultImage.translate(ns, ns);
214.   resultImage.rotate(PI / 36);
215.   resultImage.translate(-ns, -ns);
216.   resultImage.image(baseImage, 0, 0);
217.   resultImage.endDraw();
218. }
219.  
220. void Blend()
221. {
222.   println(currentBlendMode);
223.   blend(resultImage, 0, 0, resultImage.width, resultImage.height,
224.       CHOICE_W, 0, resultImage.width, resultImage.height,
225.       currentBlendMode.blendMode);
226.   resultImage.beginDraw();
227.   resultImage.copy(g, CHOICE_W, 0, IMAGE_W, IMAGE_H, 0, 0, IMAGE_W, IMAGE_H);
228.   resultImage.endDraw();
229. }
230.  
231. void BlendInverted()
232. {
233.   println("BlendInverted");
234.   DrawInverted();
235.   Blend();
236. }
237.  
238. void BlendReflected()
239. {
240.   println("BlendReflected");
241.   DrawReflected();
242.   Blend();
243. }
244.  
245. void BlendShifted()
246. {
247.   println("BlendShifted");
248.   DrawShifted();
249.   Blend();
250. }
251.  
252. void BlendRotated()
253. {
254.   println("BlendRotated");
255.   DrawRotated();
256.   Blend();
257. }
258.  
259. void ShowBlendChoices()
260. {
261.   int posY = CHOICE_T;
262.   textFont(fontMenu);
263.   for (BlendMode blendMode : blendModes)
264.   {
265.     if (IsMouseOverChoice(posY))
266.     {
267.       fill(#C05080);
268.       currentBlendMode = blendMode;
269.     }
270.     else
271.     {
272.       fill(#005080);
273.     }
274.     text(blendMode.blendName, CHOICE_L, posY);
275.     posY += CHOICE_SPACING;
276.   }
277.   textFont(fontHelp);
278.   String help = "b=activate blend; c=clear;\nDraw:\n  i=inverted;\n  r=reflected;\n  s=shifted;\n  t=rotated";
279.   text(help, CHOICE_L / 2, posY);
280. }
281.  
282. boolean IsMouseOverChoice(int posY)
283. {
284.   if (mouseX < CHOICE_L - 20 ||
285.       mouseX > CHOICE_W - 20)
286.     return false;
287.   if (mouseY < CHOICE_T - CHOICE_SPACING ||
288.       mouseY > CHOICE_T + CHOICE_SPACING * blendModes.size())
289.     return false;
290.   if (mouseY < posY - CHOICE_SPACING ||
291.       mouseY > posY)
292.     return false;
293.   return true;
294. }

As one said: "Sorry to make it long, I have no time to make it shorter"...

thanks for the exemple, I think I have a lot to learn before understanding the whole of what you did there but messing around with your code gave me a good hint on where to look next. Though "Mirorring" and the thread you linked are a bit confusing

Got It! :) thank's a lot for shining a light on PGraphics! 

So, would this work with a live feed from a webcam capture?