As you can see on the forum there are usually two ways to do mouseOvers. Either mathematically or through color buffers. I am assuming you want to find a mathematical solution. Which leads me to the question...

Is the line horizontal, vertical or diagonal?

The first two are easy:

• horizontal: is mouseY equal to lineY, is mouseX between lineStartX and lineEndX
• vertical: is mouseX equal to lineX, is mouseY between lineStartY and lineEndY
  

The latter (a line for any two given points) is a bit harder. Perhaps too advanced for a beginner.

Here is a code example that does this. You can press the mouse to randomly place the line.

Code Example

1. PVector p1 = new PVector(200, 200);
2. PVector p2 = new PVector(600, 600);
3. PVector p3 = new PVector();
4.  
5. void setup() {
6.   size(800, 800);
7.   smooth();
8. }
9.  
10. void draw() {
11.   background(255);
12.   p3.set(mouseX, mouseY, 0);
13.   PVector cp = closestPoint(p1, p2, p3);
14.   noStroke();
15.   fill(0);
16.   ellipse(p1.x, p1.y, 10, 10);
17.   ellipse(p2.x, p2.y, 10, 10);
18.   ellipse(p3.x, p3.y, 10, 10);
19.   if (p3.dist(cp)<10) {
20.     strokeWeight(4);
21.     stroke(0, 0, 255);
22.   } else {
23.     strokeWeight(1);
24.     stroke(0);
25.   }
26.   line(p1.x, p1.y, p2.x, p2.y);
27.   noStroke();
28.   fill(255, 0, 0);
29.   ellipse(cp.x, cp.y, 15, 15);
30. }
31.  
32. void mousePressed() {
33.   p1.set(random(width), random(height), 0);
34.   p2.set(random(width), random(height), 0);
35. }
36.  
37. PVector closestPoint(PVector a, PVector b, PVector p) {
38.   PVector v1 = a.get();
39.   PVector v2 = b.get();
40.   PVector v3 = p.get();
41.   v2.sub(v1);
42.   v3.sub(v1);
43.   float t = v3.dot(v2) / pow(v2.mag(), 2);
44.   if (t < 0.0) {
45.     return a.get();
46.   } else if (t > 1.0f) {
47.     return b.get();
48.   }
49.   v2.mult(t);
50.   return PVector.add(v1, v2);
51. }