making colors to random values

Programming Questions

joshmyc

making colors to random values

in Programming Questions • 1 years ago

How would i organise the code so that fill colors change every time circles intersect?

(I've tried putting this in draw() but of course i get flashing random colors as draw() loops through, i've also tries putting it in boolean intersect, but get 'unreachable code')

Ball ball1;
Ball ball2;
void setup() {
size (300, 300);
ball1 = new Ball(52);
ball2 = new Ball (36);
}
void draw() {
background(0);
ball1.display();
ball1.move();
ball2.display();
ball2.move();
if (ball1.intersect(ball2)) {
ball1.changeColor();
ball2.changeColorz();
}
}
class Ball {
float rad;
float x, y;
float xspeed, yspeed;
color c;
Ball(float _rad) {
rad= _rad;
x = random(width);
y = random(height);
xspeed = random ( 4);
yspeed = random (4);
c= color (0,255,0);
}
void display() {
fill (c);
ellipse (x, y, rad, rad);
c= color(0,255,0);
}
void changeColor() {
c= color (255, 0, 0);
}
void changeColorz() {
c=color(0, 0, 255);
}
void move() {
x += xspeed;
y += yspeed;
if (x>width||x<0) {
xspeed *= -1;
}
if (y>height||y<0) {
yspeed *= -1;
}
}
boolean intersect (Ball other) {
float distance = dist (x, y, other.x, other.y);
if (distance < rad + other.rad) {
return true;
}
else {
return false;
}
}
}

Replies(7)

PhiLho

Re: returning colors to random values

1 years ago

You need two color fields: the original one, and the current one. At start, make them identical. On restore, make the current one equals to the original one. Never change the original one.

joshmyc

Re: making colors to random values

1 years ago

hi, have updated my question to deal with a related issue. thanks for response, but could you give me an example in code (i am struggling to implement it).

quarks

Re: returning colors to random values

1 years ago

Have another attribure to store the original colour and add a class method to restore the original colours e.g.

Ball ball1;
Ball ball2;
void setup() {
size (500, 500);
ball1 = new Ball(52, color(random(255), random(255), random(255)));
ball2 = new Ball (36, color(random(255), random(255), random(255)));
}
void draw() {
background(0);
ball1.display();
ball1.move();
ball2.display();
ball2.move();
if (ball1.intersect(ball2)) {
ball1.changeColor(color(0, 0, 255));
ball2.changeColor(color(255, 0, 0));
}
else {
ball1.restoreColor();
ball2.restoreColor();
}
}
class Ball {
float rad;
float x, y;
float xspeed, yspeed;
color c, cOrg;
Ball(float rad, color c) {
this.rad = rad;
x = random(width);
y = random(height);
xspeed = random (4);
yspeed = random (4);
this.c = c;
this.cOrg = c;
}
void display() {
fill (c);
ellipse (x, y, rad, rad);
}
void restoreColor() {
c = cOrg;
}
void changeColor(int col) {
c = col;
}
void move() {
x += xspeed;
y += yspeed;
if (x>width||x<0) {
xspeed *= -1;
}
if (y>height||y<0) {
yspeed *= -1;
}
}
boolean intersect (Ball other) {
float distance = dist (x + rad, y + rad, other.x + other.rad, other.y + other.rad);
if (distance < rad + other.rad) {
return true;
}
else {
return false;
}
}
}

I have made some other changes the most important is the intersection since you need to calculate the distance between the circle centres - your code calculated the distance between the top-left positions which will not give the same answer if the circles are of different radii

HTH

joshmyc

Re: making colors to random values

1 years ago

cool, thanks for code. I'm also trying randomise the fill colors every time circles intersect. I know i cant put this in the changeColors parameters within draw(), as it will loop through and flash..any help?

p.s. is 'this.rad=rad' the same as 'rad=_rad'?

quarks

Re: making colors to random values

1 years ago

Add the following method to the ball class

void randomColor(int col) {
c = color(random(255), random(255), random(255));
}

then change lines 16 & 17 to

ball1.randomColor();
ball2.randomColor();

joshmyc

Re: making colors to random values

1 years ago

Do I need to put a parameter in ball1.randomColor(), to match the arguments within;

void randomColor(int col)

if i take the argument out from void randomColor, i get flashing again..

can you clarify?

quarks

Re: making colors to random values

1 years ago

Forget my last post as I made a mistake.

The problem is more complex than I originally thought. When you look at the intersect method it returns true (T) or false (F) but the method is being called every draw cycle i.e. ~60 times per second so if you follow the output from intersect you get something like

FFFFFFFFFFFFFFFFFFFFFFTTTTTTTTTTTTTTTTTTTTTTFFFFFFFFFFFFFFFFFFFFFFF...

and what you need are the transition from F>T and T>F

This is what you want

Ball ball1;
Ball ball2;
boolean lastIntersect = false;
void setup() {
size (500, 500);
ball1 = new Ball(52, color(random(255), random(255), random(255)));
ball2 = new Ball (36, color(random(255), random(255), random(255)));
lastIntersect = ball1.intersect(ball2);
}
void draw() {
background(0);
ball1.display();
ball1.move();
ball2.display();
ball2.move();
boolean currIntersect = ball1.intersect(ball2);
if (currIntersect != lastIntersect) {
if (currIntersect == true) {
ball1.changeColor(color(random(255), random(255), random(255)));
ball2.changeColor(color(random(255), random(255), random(255)));
}
else {
ball1.restoreColor();
ball2.restoreColor();
}
}
lastIntersect = currIntersect;
}
class Ball {
float rad;
float x, y;
float xspeed, yspeed;
color c, cOrg;
Ball(float rad, color c) {
this.rad = rad;
x = random(width);
y = random(height);
xspeed = random (4);
yspeed = random (4);
this.c = c;
this.cOrg = c;
}
void display() {
fill (c);
ellipse (x, y, rad, rad);
}
void restoreColor() {
c = cOrg;
}
void changeColor(int col) {
c = col;
}
void move() {
x += xspeed;
y += yspeed;
if (x>width||x<0) {
xspeed *= -1;
}
if (y>height||y<0) {
yspeed *= -1;
}
}
boolean intersect (Ball other) {
float distance = dist (x + rad, y + rad, other.x + other.rad, other.y + other.rad);
if (distance < rad + other.rad) {
return true;
}
else {
return false;
}
}
}

Top Reply