return to original size

Programming Questions

jenny.benz

in Programming Questions • 1 years ago

double clicking on a circle doubles its radius.

the 'originalSize' function is meant to return circle to original size when its double clicked again:

it isn't working though..any ideas why?

Button[] buttons = new Button[60];
boolean somethingSelected = false;
void setup() {
size(800, 300);
smooth();
for (int i = 0; i < buttons.length; i++) {
buttons[i]= new Button(random(width), random(height), random(20, 80), color(random(255), random(255), random(255), 100), 0.5);
}
}
void draw() {
background(85);
for (int i = 0; i < buttons.length; i++) {
buttons[i].display();
}
}
void mousePressed() {
somethingSelected = false;
for (int i = 0; i < buttons.length; i++) {
buttons[i].rollOver();
buttons[i].doubleclick();
buttons[i].originalSize();
}
}
void mouseDragged() {
for (int i = 0; i < buttons.length; i++) buttons[i].bDragged();
}
void mouseReleased() {
for (int i = 0; i < buttons.length; i++) buttons[i].bReleased();
}
class Button {
float x;
float y;
float rad;
color c;
float s;
boolean click = false;
boolean drag = true;
boolean dclick=false;
boolean originalSize=false;
Button(float _x, float _y, float _radius, color _c, float _s) {
x=_x;
y=_y;
rad=_radius;
c=_c;
s=_s;
}
void display() {
if (click) {
fill (255, 0, 0);
strokeWeight(3);
}
else {
fill(c);
strokeWeight(s);
}
ellipse (x, y, rad, rad);
rad= constrain(rad, rad, rad*2);
}
void rollOver() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false) {
click = true;
drag = true;
}
}
void doubleclick() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false&&mouseEvent.getClickCount()==2) {
rad=rad*2;
//rad= constrain(rad,rad,rad*2);
}
}
void originalSize() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false&& key=='r'&& dclick==true )
{
println ("half");
rad=rad/2;
}
}
void bDragged() {
if (drag) {
x = mouseX;
y = mouseY;
}
}
void bReleased() {
click = false;
drag = false;
}
}

Replies(9)

jbum

In that function you are checking to see if 'r' is pressed. Maybe it's not pressed. Also you are checking if dclick is true, but in this current code, it will never be true. You perhaps intended to set it to true in your doubleclick function.

jenny.benz

Re: return to original size

1 years ago

yes, i intended dclick to be true in the doubleclick function.. why will it never be true, how can i make it true?

PhiLho

Re: return to original size

1 years ago

dclick will never be true because you never assign it, so it will keep its default value...
Set it to true in the doubleclick(), as you wrote.

jbum

Re: return to original size

1 years ago

In other words:

dclick = true;

jenny.benz

Re: return to original size

1 years ago

o.k., getting myself really confused- i'm caught in a loop here between rad=rad*2 and rad=rad/2, so the circles now never change size. Struggling ..any mods to code please?....

Button[] buttons = new Button[60];
boolean somethingSelected = false;
void setup() {
size(800, 300);
smooth();
for (int i = 0; i < buttons.length; i++) {
buttons[i]= new Button(random(width), random(height), random(20, 80), color(random(255), random(255), random(255), 100), 0.5);
}
}
void draw() {
background(85);
for (int i = 0; i < buttons.length; i++) {
buttons[i].display();
}
}
void mousePressed() {
somethingSelected = false;
for (int i = 0; i < buttons.length; i++) {
buttons[i].rollOver();
buttons[i].doubleclick();
buttons[i].originalSize();
}
}
void mouseDragged() {
for (int i = 0; i < buttons.length; i++) buttons[i].bDragged();
}
void mouseReleased() {
for (int i = 0; i < buttons.length; i++) buttons[i].bReleased();
}
class Button {
float x;
float y;
float rad;
color c;
float s;
boolean click = false;
boolean drag = true;
boolean dclick=false;
boolean originalSize=false;
Button(float _x, float _y, float _radius, color _c, float _s) {
x=_x;
y=_y;
rad=_radius;
c=_c;
s=_s;
}
void display() {
if (click) {
fill (255, 0, 0);
strokeWeight(3);
}
else {
fill(c);
strokeWeight(s);
}
ellipse (x, y, rad, rad);
rad= constrain(rad, rad, rad*2);
}
void rollOver() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false) {
click = true;
drag = true;
}
}
void doubleclick() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false&&mouseEvent.getClickCount()==2) {
rad=rad*2;
dclick=true;
}
}
void originalSize() {
if (sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2 && somethingSelected == false&&mouseEvent.getClickCount()==2&& dclick==true )
{
println ("half");
rad=rad/2;
}
}
void bDragged() {
if (drag) {
x = mouseX;
y = mouseY;
}
}
void bReleased() {
click = false;
drag = false;
}
}

jbum

Re: return to original size

1 years ago

Do you want it to go back to original size when the mouse is released, or do you want double-click to toggle the circle from large to small and back to large again?

jbum

Re: return to original size

1 years ago

Not sure if this is what you're looking for, but if not, perhaps you can fix it yourself. A few changes were made.

1) All those places where you were checking distance of mouse to button, I took out, and stuck this in a single routine called mouseIsOn().

2) I heavily modified your mousePressed() routine so that only the topmost button is activated.

3) I added a variable to keep track of button size, called buttonScale. This is cleaner than changing your radius.

Button[] buttons = new Button[60];
boolean somethingSelected = false;
void setup() {
size(800, 300);
smooth();
for (int i = 0; i < buttons.length; i++) {
buttons[i]= new Button(random(width), random(height), random(20, 80), color(random(255), random(255), random(255), 100), 0.5);
}
}
void draw() {
background(85);
for (int i = 0; i < buttons.length; i++) {
buttons[i].display();
}
}
void mousePressed() {
somethingSelected = false;
int topButton = -1;
for (int i = 0; i < buttons.length; i++) {
if (buttons[i].mouseIsOn()) {
topButton = i;
}
}
if (topButton != -1) {
buttons[topButton].rollOver();
buttons[topButton].doubleclick();
}
}
void mouseDragged() {
for (int i = 0; i < buttons.length; i++)
if (buttons[i].drag)
buttons[i].bDragged();
}
void mouseReleased() {
for (int i = 0; i < buttons.length; i++)
if (buttons[i].click)
buttons[i].bReleased();
}
class Button {
float x;
float y;
float rad;
color c;
float s;
boolean click = false;
boolean drag = false;
boolean dclick=false;
int buttonScale = 1;
Button(float _x, float _y, float _radius, color _c, float _s) {
x=_x;
y=_y;
rad=_radius;
c=_c;
s=_s;
}
void display() {
if (click) {
fill (255, 0, 0);
strokeWeight(3);
}
else {
fill(c);
strokeWeight(s);
}
ellipse (x, y, rad*buttonScale, rad*buttonScale);
}
boolean mouseIsOn() {
return sqrt(sq(mouseX-x)+sq(mouseY-y)) <= rad/2;
}
void rollOver() {
click = true;
drag = true;
}
void doubleclick() {
if (mouseEvent.getClickCount()==2) {
buttonScale = buttonScale == 2? 1 : 2;
}
}
void bDragged() {
if (drag) {
x = mouseX;
y = mouseY;
}
}
void bReleased() {
click = false;
drag = false;
}
}

jenny.benz

Re: return to original size

1 years ago

thanks a lot- this is perfect!

Can i clarify something?.. I understand that if mouse clicks==2, the radius is increased by ratio 1:2, but how does this code put it back to original size when its double-clicked again?

void doubleclick() {
if (mouseEvent.getClickCount()==2) {
buttonScale = buttonScale == 2? 1 : 2;
}

jbum

Re: return to original size

1 years ago

Whoops, that was me getting fancy. The ? : construct is a shortcut.

Condition ? Resultiftrue : Resultiffalse

It checks the condition,Manx evaluates ta resultiftrue, if the condition is true, otherwise it evaluates to Resultiffalse.

So in the code , if button scale is 2, it changes it to 1, and if it's 1 (or anything that isn't 2) it changes it to 2.

Top Reply