render offscreen to second Applet (urgent)

clankill3r

render offscreen to second Applet (urgent)

in Contributed Library Questions • 2 years ago

i have to finish something tommorow so plz help

How can i render the offscreen to the second applet?

library http://keystonep5.sourceforge.net/
library2 http://glgraphics.sourceforge.net/

import processing.opengl.*;
import codeanticode.glgraphics.*;

import deadpixel.keystone.*;

// this object is key! you can use it to render fully accelerated
// OpenGL scenes directly to a texture
GLGraphicsOffScreen offscreen;

Keystone ks;
CornerPinSurface surface;

// second window
PFrame f;
SecondApplet s;

void setup() {
size(640, 480, GLConstants.GLGRAPHICS);

    //second window
PFrame f = new PFrame();

offscreen = new GLGraphicsOffScreen(this, 1024, 768);

ks = new Keystone(this);
surface = ks.createCornerPinSurface(1024, 768, 20);
}

void draw() {
// convert
PVector mouse = surface.getTransformedMouse();

// first draw the sketch offscreen
offscreen.beginDraw();
offscreen.background(50);
offscreen.lights();
offscreen.fill(255);
offscreen.translate(mouse.x, mouse.y);
offscreen.rotateX(millis()/200.0);
offscreen.rotateY(millis()/400.0);
offscreen.box(100);
offscreen.endDraw();

// then render the sketch using the
// keystoned surface
background(0);
surface.render(offscreen.getTexture());

   s.background(0, 0, 255);
   s.fill(100);
   s.rect(10,20,frameCount%120,10);
   s.redraw();
}

// Controls for the Keystone object
void keyPressed() {

switch(key) {
case 'c':
    // enter/leave calibration mode, where surfaces can be warped
    // & moved
    ks.toggleCalibration();
    break;

case 'l':
    // loads the saved layout
    ks.load();
    break;

case 's':
    // saves the layout
    ks.save();
    break;
}
}

public class PFrame extends Frame {
    public PFrame() {
        setBounds(100,100,1024,768);
        s = new SecondApplet();
        add(s);
        s.init();
        show();
    }
}

public class SecondApplet extends PApplet {
    public void setup() {
        size(1024, 768);
        noLoop();
    }

    public void draw() {
    }
}

Replies(2)

andres

Re: render offscreen to second Applet (urgent)

2 years ago

The problem of the second frame is that you cannot draw the offscreen texture on it due to context sharing issues in OpenGL. The reason is rather technical: the offscreen texture is created in the main window's thread. Because the second window has its own thread, you need do some special low level setup so the second thread can access texture data from the first.

Anyways, this is taken care of in the GLTextureWindow class that comes with GLGraphics. This class allows you to create an output window where to draw textures from main window. These secondary windows are meant only for output and cannot take any input, so you need to keep all your input handling in the main window.

Take a look at the example below:

import processing.opengl.*;
import codeanticode.glgraphics.*;
import deadpixel.keystone.*;
// this object is key! you can use it to render fully accelerated
// OpenGL scenes directly to a texture
GLGraphicsOffScreen canvas;
GLGraphicsOffScreen canvasKeystoned;
Keystone ks;
CornerPinSurface surface;
GLTextureWindow output;
void setup() {
size(640, 480, GLConstants.GLGRAPHICS);
canvas = new GLGraphicsOffScreen(this, 1024, 768);
canvasKeystoned = new GLGraphicsOffScreen(this, 1024, 768);
ks = new Keystone(this);
surface = ks.createCornerPinSurface(1024, 768, 20);
// The arguments for the GLTextureWindow constructor are:
// * title string
// * initial x of left upper corner
// * initial y of left upper corner
// * initial width
// * initial height
// * visible/not visible
// * with/out borders
// * resizable/fixed size
output = new GLTextureWindow(this, "Output", 100, 100, 1024, 768, true, true, true);
// The texture of the keystoned canvas is attached to the output window.
// Anything is drawn on this canvas will be seen in the output window.
output.setTexture(canvasKeystoned.getTexture());
}
void draw() {
PVector mouse = surface.getTransformedMouse();
// first draw the sketch offscreen
canvas.beginDraw();
canvas.background(50);
canvas.lights();
canvas.fill(255);
canvas.translate(mouse.x, mouse.y);
canvas.rotateX(millis()/200.0);
canvas.rotateY(millis()/400.0);
canvas.box(100);
canvas.endDraw();
// Render the keystoned surface on the main window.
background(0);
surface.render(canvas.getTexture());
// Render the keystoned surface on the output window.
canvasKeystoned.beginDraw();
canvasKeystoned.background(0);
surface.render(canvasKeystoned, canvas.getTexture());
canvasKeystoned.endDraw();
}
// Controls for the Keystone object
void keyPressed() {
switch(key) {
case 'c':
// enter/leave calibration mode, where surfaces can be warped
// & moved
ks.toggleCalibration();
break;
case 'l':
// loads the saved layout
ks.load();
break;
case 's':
// saves the layout
ks.save();
break;
}
}

clankill3r

Re: render offscreen to second Applet (urgent)

2 years ago

yeah i know that example.

I solved the problem by making 2 skecthes, 1 sketch writes constant info to a txt file and the other sketch keeps reading it.

Top Reply