Some general remarks, while I read you code:

- You add elements to words, repeating what is in the good / bad arrays (with a typo on peace and not, BTW): you better iterate on these arrays to add its elements to the list. Even better, you can just do:
words.addAll(Arrays.asList(good));
words.addAll(Arrays.asList(bad));
(import java.util.*; at the start of your sketch).

- You tend to redefine several variables inside the code. If you prefix a variable by its declaration, you create a new local variable of same name than the global variable, hiding the latter. You redefine words after filling it in setup(), and you redefine it also in draw()! With a different declaration, which probably doesn't compile at all.
It is even worse with title, defined here and there, with various types; and you use a titlexml which isn't defined.

You should not try to build a complex sketch from scratch, then try to run it: try and build it progressively, running it often, to check your syntax and logic are still good. Don't hesitate to use println() to get a trace of intermediary results, to ensure they are what you expect.

- You use typed ArrayList (with <String>) and untyped ones. You should always type them.

- You use a QueryResult class, it isn't part of Processing and not defined anywhere in your code. Not sure what is it. The proper way to get a XML tag is indeed to use getChildren().

Hi PhilHo,
I've spent some time trying things out - and trying to better understand the principles of ArrayList (amongst others your arrayList example of Bricks - thank you) and trying to understand how splitting works. (managed to split texts from a txttfile)
I've added regular checks- So you can see in println ("-OK-2: "+ words);  I expected the words to show up in seperate lines in the console -Clearly something wrong here
I'm still pretty much stuck at the same point. I've rewritten the code- hopefully somewhat better, but still- In the cancelled out areas is the big question-how to connect the feed-in with the comparing keywords?

Also not sure how to rewrite the words.add part ( see your comment above)
How can I make a search query for specific keywords in an RSS feed?
Your help ( ot that of others )much appreciated

Here is the next version:

// bbc news text feeds
import java.util.*;
XML xml;

String[] good= {//to highten the chance for something to show up I put in "have"
  "good", "peace", "growth", "have"
};

String[] bad = { //to highten the chance for something to show up I put in "no"
  "bad", "war", "cuts", "not"
};


ArrayList <Item> items= new ArrayList <Item>();// The items array

PFont font;
//---------------------------------------------
void setup() {

  //?????????? Now inclear how to write these
  /* words.add("good");
   words.add("peace");
   words.add("growth");
   words.add("have");
   words.add( "bad");
   words.add("war");
   words.add("cuts");
   words.add("not");
   */

  size(500, 800);
  font = loadFont("Consolas-BoldItalic-42.vlw");
  textFont(font, 20);

  // Loads RSS feed and gets location of title and image of each item
  xml = loadXML( "http://feeds.bbci.co.uk/news/rss.xml");
  XML[] children = xml.getChildren("channel/item/title");
  println ("-OK-1: "+ children );

  for (int i = 0; i < 5; i++) {
    String title = children[i].getContent();// gets the content- title is further declared under item

    String[] words = split (title, " ");
    println ("-OK-2: "+ words); //expecting the words to show up independently in console ???

    items.add (new Item (title, 20, (i * 50)+10)); //String title, float x, float y
    println ("-OK-3: " +items);
    println ("-OK-4: " +title);
  }
}
/*  ???????
 //missing link between the compare functions and the ArrayList coming from the feed  to compare with
 
 void draw() {
 background(255);
 
 //Draw a word from the list of words that we've built
 String words = words.get(i);
 
 //show the results
 if (compareWordToArray(words, good)) {
 fill(0, 255, 0);
 text("good", random(width), random(height));
 }
 
 if (compareWordToArray(words, bad)) {
 fill(255, 0, 0);
 text("bad", random(width), random(height));
 }
 }
 //------------------------------------------------------
 boolean compareWordToArray(String word, String[] wordArray) {
 for (int i=0; i<wordArray.length; i++) {
 if (word.equals(wordArray[i])) return true;
 }
 return false;
 }
 */

//---------------------------------------------
void draw() {
  background(0);
  // Displays each item
  for (Item item: items) {
    item.display();
  }
}
//---------------------------------------------
 // Simple class to store title and image
class Item {

  String words;
  float x;
  float y;

  Item(String words_, float x_, float y_) {
   x = x_;
   y = y_;
   words= words_;
  }

  void display() {
    fill(255);
    text(words, x, y);
  }
}

I played a bit with your code. The result is probably not what you want, but I hope it will push you in the right direction.

1. // bbc news text feeds
2. import java.util.*;
3. String[] good= {//to highten the chance for something to show up I put in "to"
4.   "good", "peace", "growth", "to"
5. };
6. String[] bad = { //to highten the chance for something to show up I put in "in"
7.   "bad", "war", "cuts", "in"
8. };
9. ArrayList<Item> items = new ArrayList<Item>();
10. PFont font;
11. //---------------------------------------------
12. void setup() {
13.   size(500, 800);
14.   font = createFont("Arial", 20);
15.   textFont(font, 20);
16.   // Loads RSS feed and gets location of title and image of each item
17.   XML xml = loadXML("http://feeds.bbci.co.uk/news/rss.xml");
18.   XML[] children = xml.getChildren("channel/item/title");
19.   println ("-OK-1: "+ children );
20.   for (int i = 0; i < children.length; i++) {
21.     String title = children[i].getContent();// gets the content- title is further declared under item
22.     items.add(new Item(title, 20, (i * 50)+10)); //String title, float x, float y
23.     println ("-OK-3: " +title);
24.   }
25.   println ("-OK-4: " +items);
26. }
27. //---------------------------------------------
28. void draw() {
29.   background(0);
30.   // Displays each item
31.   for (Item item: items) {
32.     item.display();
33.     item.compare();
34.   }
35. }
36. //------------------------------------------------------
37. boolean compareWordToArray(String word, String[] wordArray) {
38.   for (int i=0; i<wordArray.length; i++) {
39.     if (word.equals(wordArray[i])) return true;
40.   }
41.   return false;
42. }
43. //---------------------------------------------
44. // Simple class to store title and image
45. class Item {
46.   String title;
47.   String[] words;
48.   float x;
49.   float y;
50.   Item(String title_, float x_, float y_) {
51.     x = x_;
52.     y = y_;
53.     title = title_;
54.    
55.     words = split(title, " ");
56.     println ("-OK-2"); println(words);
57.   }
58.   void display() {
59.     fill(255);
60.     text(title, x, y);
61.   }
62.  
63.   void compare() {
64.     for (String word : words) {
65.       //show the results
66.       if (compareWordToArray(word, good)) {
67.         fill(0, 255, 0);
68.         text("good", random(width), y);
69.       }
70.    
71.       if (compareWordToArray(word, bad)) {
72.         fill(255, 0, 0);
73.         text("bad", random(width), y);
74.       }
75.     }
76.   }
77.  
78.   public String toString() {
79.     return "Item[" + title + "]";
80.   }
81. }

this is great.
I don't think I could have ever found this out myself.
So the compare function went to the Item class. Why is this the better way to do it?
Also you added the public String to String().
how does this work here.?

Many thanks!

I moved the comparison into the class because words is part of Item, so it seems to make sense to do the comparison there.
toString() allows a class to be converted (generally for display purpose) to a string, it allows println() to display the content of the class instead of sketch_130326a$Item@1dfd90f for example...
Also note I separated the print out of words in two, because the + produces garbage, while println() of an array is OK in Processing.

much learned today!
now its time to play, many thanks!