Question about how to create a loop with conditions (I'm new to programming)

Programming Questions

Zeesh

Question about how to create a loop with conditions (I'm new to programming)

in Programming Questions • 28 days ago

I'm reading the book Generative Art, by Matt Pearson

I have a circle that is drawn, then filled in, leaving traces behind.

What I would like to do is have it so that once the circle is filled in, it starts all over again, but this time have it so it stops at a shorter diameter each time it starts over, with a different color.

I know it has something to do with how I create the conditions, but I'm still trying to wrap my head around it.

here is my code:

int diam=4;
float centX, centY;
void setup(){
size(800,800);
background(240,50,50);
frameRate(25);
smooth();
stroke(250);
strokeWeight(6);
noFill();
ellipse(width/2,height/2,width,height);
centX=width/2;
centY=height/2;
stroke(0);
strokeWeight(2);
fill(240,150,150,5);
}
void draw(){
if(diam<=800){
ellipse(centX,centY,diam,diam);
diam+=10;
}
}

Does that make any sense?

Thank you so much for your help in advance!!!

Replies(4)

GoToLoop

Re: Question about how to create a loop with conditions (I'm new to programming)

28 days ago

Come up w/ a separate restartGraph() function just to reset drawing parameters.
Also another drawBG() for the initial big circle.

// http://forum.processing.org/topic/
// question-about-how-to-create-a-loop-with-conditions-
// i-m-new-to-programming

int diam, limit;
int cx, cy;

final static int ALPHANESS = 10, STEP = 50, GAP = 10;
final static int FPS = 25, BOLD = 2;

void setup() {
  size(800, 800);
  frameRate(FPS);
  smooth(4);

  cx = width  >> 1;
  cy = height >> 1;

  drawBG();

  stroke(0);
  strokeWeight(BOLD);
}

void draw() {
  if ((diam += GAP) >= width - limit)   restartGraph();
  ellipse(cx, cy, diam, diam);
}

void drawBG() {
  noFill();
  stroke(-1);
  strokeWeight(6);

  background(#F03030);
  ellipse(cx, cy, width, height);
}

void restartGraph() {
  diam = 0;
  limit = (limit+STEP) % width;
  fill((color) random(#000000), ALPHANESS);
}

PhiLho

Re: Question about how to create a loop with conditions (I'm new to programming)

27 days ago

Let's rewrite a bit your code:

int diam=4;
float centX, centY;
int maxDiam;
void setup() {
size(800, 800);
background(240, 50, 50);
frameRate(25);
smooth();
centX = width / 2;
centY = height / 2;
maxDiam = width;
stroke(250);
strokeWeight(6);
noFill();
ellipse(centX, centY, maxDiam, maxDiam);
stroke(0);
strokeWeight(2);
fill(240, 150, 150, 5);
}
void draw() {
if (diam <= maxDiam) {
ellipse(centX, centY, diam, diam);
diam += 10;
}
}

It doesn't use "magical numbers" like 800 (that become obsolete if you change the size of your sketch) but exploits the constants you create.
Now, once the circle is at its max size, you want to clear the screen and start again, so you need to move part of the setup to a function (to avoid copy & paste), to do it again:

int diam;
float centX, centY;
int maxDiam;
void setup() {
size(800, 800);
frameRate(25);
smooth();
centX = width / 2;
centY = height / 2;
maxDiam = width;
setUp();
}
void draw() {
if (diam <= maxDiam) {
ellipse(centX, centY, diam, diam);
diam += 10;
}
}
void setUp() {
background(240, 50, 50);
stroke(250);
strokeWeight(6);
noFill();
ellipse(centX, centY, maxDiam, maxDiam);
stroke(0);
strokeWeight(2);
fill(240, 150, 150, 5);
diam = 4;
}

Now, it is simple to start over, with a smaller circle:

void draw() {
if (diam <= maxDiam) {
ellipse(centX, centY, diam, diam);
diam += 10;
} else {
maxDiam -= 20;
setUp();
}
}

Replace the background call in setUp() with:

background(random(255), random(255), random(255));

and you are done.

Jeff Tsuk..

Re: Question about how to create a loop with conditions (I'm new to programming)

27 days ago

Right, so one way of looking at things also, and i'm doing this in english, which i found most code to not have built in, is the way things react sequentially and in parallel.

You might get to a point when you're thinking.... wait, why don't i mix up changing the color of the stroke, the background, etc. From a lingo/actionscript point of view, it's simply just embedding the code in the timeline, but in a procedural language, this timeline is something you have to code yourself.

But if you start off immediately with this idea in the back of your head, you'll modularise each of the functions in such a way, that you can try out different permutations of the code without spending needless amount of time looking at how things generate --- that is assuming you've decided to essentially randomise all the parameters.

It puts a different dimension to things so to speak.

Zeesh

Re: Question about how to create a loop with conditions (I'm new to programming)

17 days ago

Thank You so much for your help! I appreciate it!

Top Reply