you can use append
and for-loop through the existing array and append each element

Can you explain that a little bit more? Because my cell is always moving to a random direction and I want the duplicated cell to appear everytime at the cell's current location and the duplicated one can move to another random direction

can you post the class cell?

in the meantime...

rough example you put into mousePressed() and adapt

I'll adapt your now

1.   // double array
2.   int currentLength=cells.length;
3.   for (int i = 0; i < currentLength; i++) {
4.     cell currentNewCell = new cell();
5.     currentNewCell = cells[i];
6.     currentNewCell.addSpeedX = -.76;
7.     cells = (cell[]) append (cells, currentNewCell);
8.   }

that works
see http://www.processing.org/reference/append_.html

1. cell[] cells;
2. void setup() {
3.   size(600, 600);
4.   smooth();
5.   cells = new cell[1];
6.   cells[0] = new cell(300, 300, 50);
7. }
8. void draw() {
9.   background (255, 235, 205);
10.   for (int i = 0; i < cells.length; i++) {
11.     cells[i].grow();
12.     cells[i].move();
13.     cells[i].display();
14.   }
15. }
16. void mousePressed() {
17.   // double array
18.   int currentLength=cells.length;
19.   for (int i = 0; i < currentLength; i++) {
20.     cell currentNewCell = new cell( cells[i].x, cells[i].y, cells[i].r);
21.     cells = (cell[]) append (cells, currentNewCell);
22.   }
23. }
24. // =======================================================
25. class cell {
26.   float x;
27.   float y;
28.   float speedX;
29.   float speedY;
30.   float r;
31.   int sw;
32.   color s;
33.   color c;
34.   cell(float tempX, float tempY, float tempR) {
35.     x = tempX;
36.     y = tempY;
37.     speedX = random(-2, 2);
38.     speedY = random(-2, 2);
39.     r = tempR;
40.     sw = 5;
41.     s = color(34, 139, 34);
42.     c = color(255);
43.   }
44.   void display() {
45.     fill(c);
46.     strokeWeight(sw);
47.     stroke(s);
48.     ellipse(x, y, r, r);
49.   } 
50.   void grow() {
51.     if (r <= 100) {
52.       r = r + 1;
53.     }
54.   }
55.   void move() {
56.     y = y + speedY;
57.     x = x + speedX;
58.     if (y > height || y < 0) {
59.       speedY = speedY * -1;
60.     }
61.     if (x > width || x < 0) {
62.       speedX = speedX * -1;
63.     }
64.   }
65. }

how come it says constructor .cell() is undefined?? weird..

sorry,
my new code answers that

(it's because it gives no parameters, that was before I saw your class)

thank you !! that's awesome.

Got it. Thank you so much! 

you're welcome !!!   

THAT might be faster
  size(1200, 900, OPENGL );

when you got a lot of cells...

One more question, why do you need to say "i < currentLength" instead of just "i<cell.length"? 

sorry i am new to processing

That's a good question - I did that to avoid that the for-loop takes into account the new cells...

it should only loop over the old ones 

maybe the other version just "i<cell.length" would do the same, I don't know

i tried it but only "i<cell.length" doesn't work. everything stops when you press the mouse. maybe because my cell array size is 1? 

he is looping over the array indefinetly because he extends the array then it is longer and he loops also over the new members so he doubles the new cells as well and then also doubling their new cells and so on - indefinetly

you can see this if you insert  

1. println(cells.length);

into the for-loop.

So it is wise to avoid that by using currentLength. This is a fixed value stored before the loop and thus he is doing only the old cells... 


we need to store the current size before the loop (because we change the array's size in the loop)

here is the func with better comments    

1. void mousePressed() {
2.   // double array
3.   //
4.   // store the current size (because we change the array's size in the loop!!)
5.   int currentLength = cells.length;
6.   // for-loop over the current cells, using currentLength as the border
7.   for (int i = 0; i < currentLength; i++) {
8.     // make a new cell item called currentNewCell with data of the current old cell
9.     // but small (50)
10.     cell currentNewCell = new cell( cells[i].x, cells[i].y, 50 );
11.     // make the old cell small as well
    
12.     cells[i].r=50;
13.     // append the new cell called currentNewCell on the array
14.     cells = (cell[]) append (cells, currentNewCell);
15.     // show the length of the array (for testing only)
16.     println(cells.length);
17.   } // for
18. } // function

Great, you're welcome!