quad() shapes or lines in a grid?

Programming Questions

clausneer..

quad() shapes or lines in a grid?

in Programming Questions • 1 year ago

Hi everyone,

I've been trying to wrap my head around this annoying, yet probably simple solution: I have build this mouse attractor code, that affects a grid of points. Now, I want to draw either lines or quads between the points, so that I have a rectangular grid instead of just points.

Any suggestions to how I can do that? I've been trying to figure it out with PVector and 2D arrays, but I just can't get it to work.

Thanks in advance!

Here is the code:

int step = 10;
void setup() {
size(800, 500);
smooth();
fill(100, 100);
}
void draw() {
background(255);
for (int x = step; x < width-step; x += step) {
for (int y = step; y < height-step; y += step) {
float d = dist(x, y, mouseX, mouseY);
PVector mouse = new PVector(mouseX, mouseY);
PVector center = new PVector(x, y);
mouse.sub(center);
mouse.div(0.1*d);
pushMatrix();
translate(x, y);
point(mouse.x, mouse.y);
popMatrix();
}
}
}

Replies(2)

amnon.owed

Re: quad() shapes or lines in a grid?

1 year ago

In your code the points are really individual. The solution is to store them, then use them to draw a grid.

Adapted Code

int stepsW, stepsH, stepSize = 30;
PVector[][] points;
void setup() {
size(800, 500);
stepsW = width/stepSize;
stepsH = height/stepSize;
points = new PVector[stepsH][stepsW];
smooth();
}
void draw() {
background(255);
for (int y=0; y<stepsH; y++) {
for (int x=0; x<stepsW; x++) {
PVector mouse = new PVector(mouseX, mouseY);
PVector center = new PVector(stepSize + x*stepSize, stepSize + y*stepSize);
float d = center.dist(mouse);
mouse.sub(center);
mouse.div(0.1*d);
center.add(mouse);
points[y][x] = center;
}
}
stroke(255);
for (int y=0; y<stepsH-1; y++) {
beginShape(QUAD_STRIP);
for (int x=0; x<stepsW; x++) {
fill(x*10, y*10, 125);
vertex(points[y][x].x, points[y][x].y);
vertex(points[y+1][x].x, points[y+1][x].y);
}
endShape();
}
}

clausneer..

Re: Re: quad() shapes or lines in a grid?

1 year ago

That is great! Thank you so much.

Top Reply