putting color codes into an int Array from File

Programming Questions

evilsin

putting color codes into an int Array from File

in Programming Questions • 1 month ago

Hello,

I have the following problem with my program

I would like to put color codes into an int array so i can randomise colors inside my program, but i have some difficulty's with it.

I tryed to load the color codes inside an int array with this:

int[] colorArray = int(loadStrings("colors.txt"));

But then i get an int array with only 0 values, while if i do it with an String Array i get the correct values.

I tryed different ways (loops etc) to try to convert the String Array to an int but nothing seems to work.

for some reason a normal int can accept the value #ADD8E6 for instance, but an array can't it seems.

It really needs to be in an int value couse fill() only accepts those.

could someone assist me with the problem please?

thx in advance.

Replies(5)

tfguy44

Re: putting color codes into an int Array from File

1 month ago

This should help:

String[] textColors;
color[] colorColors;
int[] intColors;
void setup(){
size(220,220);
textColors = loadStrings("colors.txt");
intColors = new int[textColors.length];
colorColors = new int[textColors.length];
for( int i=0; i < textColors.length; i++){
colorColors[i] = color( unhex( textColors[i].substring(1,3) ), unhex( textColors[i].substring(3,5) ), unhex( textColors[i].substring(5,7) ) );
intColors[i] = color( colorColors[i] );
println( textColors[i] + " => (" + int(red(colorColors[i])) + ", " + int(green(colorColors[i])) + ", " + int(blue(colorColors[i])) + ") => " + intColors[i] );
}
}
void draw(){
background(255);
for( int i=0; i < colorColors.length; i++){
fill(colorColors[i]);
ellipse(20+20*i, 20+20*i, 15, 15);
}
}

GoToLoop

Re: putting color codes into an int Array from File

1 month ago

Here's my version. A little late though.

"WebColors.txt":

#FF0000
#00FF00
#0000FF
0xfFC04080
Ff8040C0
30
0xa0

/** 
 * WebCode LoadString (v1.2)
 * by GoToLoop (2013/Aug)
 * 
 * http://forum.processing.org/topic/
 * putting-color-codes-into-an-int-array-from-file
 */

static final String FILE = "WebColors.txt";
color[] colours;

void setup() {
  size(400, 300);
  frameRate(.75);

  colours = loadWebColors(FILE);
}

void draw() {
  final int num = colours.length;
  final int idx = frameCount % num;
  final color c = colours[idx];

  background(c);

  frame.setTitle("Index: " + idx + "/" + (num-1) 
    + "\tWebColor: #" + hex(c).substring(2));
}

color[] loadWebColors(String path) {
  final String[] colorText = loadStrings(path);
  final int len = colorText.length;
  final color[] colorList = new color[len];

  for (int i = len; i-- != 0; colorList[i] = uncolor(colorText[i]));

  return colorList;
}

static final color uncolor(String webColor) {
  webColor = webColor.replaceFirst("#", "ff").replaceFirst("0x", "");
  return unhex(webColor);
}

quarks

Re: putting color codes into an int Array from File

1 month ago

Slight variation of post from tfguy44

In line the first part is to set the color opaques (alpha = 255) and the second part converts the hexadecimal after stripping of the #

String[] textColors;
int[] intColors;
void setup(){
size(220,220);
textColors = loadStrings("colors.txt");
intColors = new int[textColors.length];
// Assumes text colour is in #RRGGBB format - as per first post
for(int i = 0; i < textColors.length; i++){
intColors[i] = (0xFF000000 & Integer.parseInt(textColors[i].substring(1), 16));
}
}

evilsin

Re: putting color codes into an int Array from File

1 month ago

that helped me out allot! thanks!

GoToLoop

Re: putting color codes into an int Array from File

1 month ago

A little explanation:

The webcolor syntax using # is just a sugar coat for the Processing's pre-processor;
before it turns our code into a valid Java one.

The pre-processor merely replaces the # character w/ 0xff, turning it into a valid Java hexadecimal value.
The # or 0xff means that the color is 100% opaque.

Problem is that it just works as a literal value. Like this -> color c = #A080C0;
However, Processing got no means to interpret the # character outside that use.
Particularly, there's no function to convert a "#A080C0" String into its corresponding color data-type!

Neither to turn a color data-type back to a webcolor String!
A pity, it should have!

The only convert function which comes close to it is -> unhex().
But it can only interpret a hexadecimal String w/o either # nor 0x!

My snippet uncolor() function replaces # w/ "ff" & 0x w/ "" before using unhex() to complete the job!