put x-y coordinates into 2d array

Programming Questions

phildar

put x-y coordinates into 2d array

in Programming Questions • 6 months ago

hello, it should be simple:
I draw a 10x10 grid, and each center of the rects that are created.
I would like to put x-y coordinates of each center point into an array in order to make some drawing stuffs with them. (like drawing lines between each center and the mouse cursor, or define the distance between centers and mousecursor).
here's my code:

void setup()
{
size(800, 800);
for (int i =0; i<10; i++)
{
    line(i*width/10, 0, i*width/10, height);
    line(0, i*height/10, width, i*height/10);
}
for (int k= 0; k<10;k++)
{
    for (int l=0; l<10; l++)
    {
      fill(random(255), random(255), random(255));
      ellipse(width/20+k*width/10, height/20+l*height/10, 10, 10);
    }
}
}

void draw()
{
}

thanks in advance

Replies(6)

tfguy44

Re: put x-y coordinates into 2d array

6 months ago

This should help.

PVector[] centers;
void setup()
{
size(800, 800);
centers = new PVector[100];
for (int i =0; i<10; i++)
{
line(i*width/10, 0, i*width/10, height);
line(0, i*height/10, width, i*height/10);
}
int counter = 0;
for (int k= 0; k<10;k++)
{
for (int l=0; l<10; l++)
{
fill(random(255), random(255), random(255));
ellipse(width/20+k*width/10, height/20+l*height/10, 10, 10);
centers[counter++]= new PVector( width/20+k*width/10, height/20+l*height/10, 0 );
}
}
}
void draw()
{
stroke(0);
for( int t=0; t<100; t++ ){
line( mouseX, mouseY, centers[t].x, centers[t].y );
}
}

It's worth noting now, however, that your initial grey background & grid & circles are only drawn once. You might want to redraw them each time the screen is drawn, which would mean that you'd want to move the drawing of them into draw().

If you want the colors of the center circles to remain fixed colors, you'll probably want an array of colors to remember what color they are...

phildar

Re: put x-y coordinates into 2d array

6 months ago

thanks !!
here's the code completed with random color 'once':

PVector[] centers;
color[] couleur = new color[100];
void setup()
{
size(800, 800);
centers = new PVector[100];
for (int u=0;u<100;u++)
{
    couleur[u]= color(random(255), random(255), random(255));
}
}

void draw()
{
background(200);
for (int i =0; i<10; i++)
{
    line(i*width/10, 0, i*width/10, height);
    line(0, i*height/10, width, i*height/10);
}
int counter = 0;
for (int k= 0; k<10;k++)
{
    for (int l=0; l<10; l++)
    {
      fill(couleur[counter]);
      ellipse(width/20+k*width/10, height/20+l*height/10, 10, 10);
      centers[counter++]= new PVector( width/20+k*width/10, height/20+l*height/10, 0 );
    }
}
stroke(0);
for ( int t=0; t<100; t++ ) {
    line( mouseX, mouseY, centers[t].x, centers[t].y );
}
}

GoToLoop

Re: put x-y coordinates into 2d array

6 months ago

Here's an alternative version for tfguy44's:

Color is stored as field z from PVector! Need to use operator ( color) to use that though.

final static color BG  = -1, FG = 0;
final static short DIM = 30, D_DIM = DIM << 1;
final static short NUM = 20, D_NUM = NUM << 1;

final static PVector[][] coords = new PVector[NUM][NUM];

void setup() {
  size(800, 800);
  frameRate(50);
  smooth();
  noLoop();
  stroke(FG);

  rectMode(CORNER);
  ellipseMode(CENTER);

  int wdNum = width/NUM, wdDNum  = width/D_NUM;
  int hgNum = height/NUM, hgDNum = height/D_NUM;

  for (int x = 0; x != NUM; x++)
    for (int y = 0; y != NUM; y++) {
      fill(BG);
      rect(x*wdNum, y*hgNum, D_DIM, D_DIM);

      coords[x][y] = new PVector(
      wdDNum + x*wdNum, hgDNum + y*hgNum, 
      (color) random(0x1000000) | #000000);

      fill( (color) coords[x][y].z );
      ellipse(coords[x][y].x, coords[x][y].y, DIM, DIM);
    }

  line(width - 1, 0, width - 1, height - 1);
  line(0, height - 1, width - 1, height - 1);
}

GoToLoop

Re: put x-y coordinates into 2d array

6 months ago

Another one! Now implementing those rays following mouse. Also published it online!

http://studio.processingtogether.com/sp/pad/export/ro.9WgKFjA6WFscW/latest

// http://forum.processing.org/topic/put-x-y-coordinates-into-2d-array
// by phildar & tfguy44 (2013/Apr)

// http://studio.processingtogether.com/sp/pad/export/ro.9WgKFjA6WFscW/latest

final static float FPS = 40;
final static color BG  = -1, FG = 0;
final static short DIM = 60, D_DIM = DIM << 1;
final static short NUM = 10, D_NUM = NUM << 1;

final static PVector[][] squares = new PVector[NUM][NUM];
final static PVector[][] coords  = new PVector[NUM][NUM];

void setup() {
  size(800, 800);
  frameRate(FPS);
  smooth();
  noLoop();
  noCursor();
  stroke(FG);

  rectMode(CORNER);
  ellipseMode(CENTER);

  int wdNum = width/NUM, wdDNum  = width/D_NUM;
  int hgNum = height/NUM, hgDNum = height/D_NUM;

  for (int x = 0; x != NUM; x++)
    for (int y = 0; y != NUM; y++) {
      squares[x][y] = new PVector(x*wdNum, y*hgNum, BG);

      coords[x][y]  = new PVector(
      wdDNum + x*wdNum, hgDNum + y*hgNum, 
      (color) random(0x1000000) | #000000);
    }
}

void mouseMoved() {
  redraw();
}

void mousePressed() {
  redraw();

  for (int y = 0, x = 0; x != NUM; x += (y = (y+1) % NUM) == 0 ? 1:0)
    coords[x][y].z = (color) random(0x1000000) | #000000;
}

void draw() {
  background(BG);
  drawCoords();
  drawLines();
}

void drawCoords() {
  for (int x = 0; x != NUM; x++)
    for (int y = 0; y != NUM; y++) {
      fill(BG);
      rect(squares[x][y].x, squares[x][y].y, D_DIM, D_DIM);

      fill( (color) coords[x][y].z );
      ellipse(coords[x][y].x, coords[x][y].y, DIM, DIM);
    }

  line(width - 1, 0, width  - 1, height - 1);
  line(0, height - 1, width - 1, height - 1);
}

void drawLines() {
  for (int y = 0, x = 0; x != NUM; x += (y = (y+1) % NUM) == 0 ? 1:0)
    line(mouseX, mouseY, coords[x][y].x, coords[x][y].y);
}

phildar

Re: put x-y coordinates into 2d array

6 months ago

wow ! really cool !! mr Go to Loop !!
storing the color into the z of pvector is really nice !!
I don't understand how you set it up:

   coords[x][y] = new PVector(
      wdDNum + x*wdNum, hgDNum + y*hgNum, 
      (color) random(0x1000000) | #000000); You say a 2d Pvector = 3d Pvector ? is this 
right ? 

thanks !! big up

GoToLoop

Re: put x-y coordinates into 2d array

6 months ago

A PVector instance grants 3 float field variables -> x, y, z.

Rather than letting 1 of them go to waste,

I just took the unused z and stored the circle's random color there!

Now, random(0x1000000) picks any possible combination of RGB w/o alpha.

After that, I just add #000000 to make it opaque again!

[Edit] -> New version. Changes all circle colors each mousePressed()!