push/pop background? or reset one ellipse background and other not

Programming Questions

Per_

push/pop background? or reset one ellipse background and other not

in Programming Questions • 5 months ago

Hi!

I got one green and one red ellipse. I want the red one to make a straight line while the green one to just reset everytime in draw. I tried to accomplish this through push and popStyle() but i doesnt seem to work on background()

Maybe if you think in layers, I want one layer to reset the background and one layer to not reset the background in draw.

any hints?

thanks!

float slow_circle_x = 0; // slow green
float fast_circle_x = 0; // fast red
void setup() {
size(400, 400);
noStroke();
}
void draw() {
background(#1BB1F5);
fill(#C1FF3E); // green ellipse
ellipse(slow_circle_x, 50, 50, 50);
slow_circle_x = slow_circle_x + 1;
fill(#FF4800); // red ellipse
ellipse(fast_circle_x, 50, 50, 50);
fast_circle_x = fast_circle_x + 5;
if (slow_circle_x > 400) { // start over green
slow_circle_x = 0;
}
if (fast_circle_x > 400) { // start over red
fast_circle_x = 0;
}
}

Replies(6)

Alex Pilk..

Re: push/pop background? or reset one ellipse background and other not

5 months ago

Very interesting question! How about something like this:

float fast_circle_x = 0; // fast red
int i;
slowEllipse[] el=new slowEllipse[400];
void setup() {
size(400, 400);
noStroke();
for(int j=0; j<400; j++){
el[j]=new slowEllipse(j);
}
}
void draw() {
background(#1BB1F5);
fill(#C1FF3E); // green ellipse
i=constrain(i,0,400);
for(int j=0; j<i; j++){
el[j].drawEllipse();
}
i++;
///
fill(#FF4800); // red ellipse
ellipse(fast_circle_x, 50, 50, 50);
fast_circle_x = fast_circle_x + 5;
if (fast_circle_x > 400) { // start over red
fast_circle_x = 0;
}
}
class slowEllipse{
float p;
slowEllipse(float tp){
p=tp;
}
void drawEllipse(){
ellipse(p, 50, 50, 50);
}
}

Per_

Re: push/pop background? or reset one ellipse background and other not

5 months ago

thanks. that works! would be easier if would be possible to set individuell backgroundupdate though for each ellipse :)

but guess thats not possible

Per_

Re: push/pop background? or reset one ellipse background and other not

5 months ago

one more thing. Im trying to accomplish this in an drawingsketch with kinect where im using an ArrayList with PVector to point out the coordinates for the drawing. since this is an array with no ending (depends how long time you are drawing)

this wont work in that case:

slowEllipse[] ellipse_slow=new slowEllipse[400];

since im using something like this:

ArrayList<PVector> tracking = new ArrayList();

any other solution?

or any way using background to reset

GoToLoop

Re: push/pop background? or reset one ellipse background and other not

5 months ago

A drawing sketch? Perhaps this example can also help you out:

/** * Trailing Deque (v3.35) * by quarks (2013/Feb) * for rialobran * mod GoToLoop * * http://forum.processing.org/topic/drawing-a-trail-for-a-moving-object */

import java.util.*;

final static byte MAX_TRAIL_POINTS = 5;
final static Queue<PointXY> trails = new ArrayDeque(MAX_TRAIL_POINTS);

PointXY tt;

byte currTrailSize;
boolean isFull, trailOrLinked;

final static color BG = 0350, FG = #0000FF;
final static short FPS = 100, BOLD = 3;

final static String GFX = P2D; // use JAVA2D or P2D

void setup() {
  size(800, 600, GFX);
  frameRate(FPS);
  smooth();

  keyPressed();

  stroke(FG);
  strokeWeight(BOLD);
}

void keyPressed() {
  if (trailOrLinked = !trailOrLinked)    noLoop();
  else                                   loop();
}

void mousePressed() {
  redraw();

  if (isFull) {
    tt = trails.remove();
    trails.add( new PointXY(mouseX, mouseY) );
    return;
  }

  trails.add( new PointXY(mouseX, mouseY) );
  tt = trails.element();

  if (++currTrailSize == MAX_TRAIL_POINTS)   isFull = true;
}

void draw() {
  background(BG);

  for (PointXY t: trails)    t.action();
}

final class PointXY {
  final int X, Y;

  PointXY(int px, int py) {
    X = px;
    Y = py;
  }

  void action() {
    line(tt.X, tt.Y, X, Y);
    tt = this;
  }
}

v.k.

Re: push/pop background? or reset one ellipse background and other not

5 months ago

here another approach, using PGraphics, more like a layer approach:

float slow_circle_x = 0; // slow green
float fast_circle_x = 0; // fast red
// create an extra render
PGraphics pg;
void setup() {
size(400, 400);
noStroke();
//initialize it
pg = createGraphics (400,400);
}
void draw() {
//draw on pg no background call...
pg.beginDraw();
pg.fill(#C1FF3E); // green ellipse
pg.noStroke();
pg.ellipse(slow_circle_x, 50, 50, 50);
pg.endDraw();
// clear screen
background(#1BB1F5);
//display pg
image(pg, 0, 0);
// draw over it
slow_circle_x = slow_circle_x + 1;
fill(#FF4800); // red ellipse
ellipse(fast_circle_x, 50, 50, 50);
fast_circle_x = fast_circle_x + 5;
if (slow_circle_x > 400) { // start over green
slow_circle_x = 0;
}
if (fast_circle_x > 400) { // start over red
fast_circle_x = 0;
}
}

Per_

Re: push/pop background? or reset one ellipse background and other not

5 months ago

thanks! PGraphics did the trick!

Top Reply