pulling data from a text file

Programming Questions

geeb451

pulling data from a text file

in Programming Questions • 1 year ago

I am trying to pull data from a text file on another computer everything works but the text file gets a new number every half second and processing does not update to the new number but if I go into the processing menus and add the file again replacing the file with the same one only with the new number it will show the new number.

Thanks in advance

PFont f;
PFont g;
String[] lines;
int index = 0;
void setup() {
size(700,720);
f = createFont("Arial", 400, true);
g = createFont("Arial", 100, true);
noLoop();
}
void draw() {
background(255);
noStroke();
//line(width/2,0,width/2,height);
textFont(f);
fill(0);
String[] lines = loadStrings("compact.txt");
String[] pieces = split(lines[index], '\t');
// textAlign() sets the alignment for displaying text. It takes one argument: CENTER, LEFT, or RIGHT.
textAlign(CENTER);
text(pieces[0] ,width/2,400);
textFont(g);
fill(0);
text("compactability" ,width/2,600);
loop();
}

Replies(1)

benja

Re: pulling data from a text file

1 year ago

So you want to import data from a file that contantly changes, right?
I think you would have to watch if the file gets changed and reload the data if that is true.
Here is an example, how it could work:

import java.util.*;
import java.io.*;

int lastValue;

void setup() {
size(100, 100);
fill(0);

// create new Timer task
TimerTask task = new FileWatcher( new File(dataPath("")+"compact.txt"));
// create timer
Timer timer = new Timer();
timer.schedule( task, new Date(), 1000 );

loadData();
}

void draw() {
background(255);
text(lastValue, 20, 20);
}

void loadData() {
String[] lines = loadStrings("compact.txt");
String[] pieces = split(lines[lines.length-1], '\t');
lastValue = int(pieces[0]);
}

class FileWatcher extends TimerTask {
long timeStamp;
File file;

FileWatcher( File file ) {
    this.file = file;
    this.timeStamp = file.lastModified();
}

// check if file has been modified
void run() {
    long timeStamp = file.lastModified();

    if ( this.timeStamp != timeStamp ) {
      this.timeStamp = timeStamp;
      onChange(file);
    }
}

// load data again
void onChange( File file ) {
    loadData();
}
}

Top Reply