PShape performance

Android Processing

hudsonm40..

in Android Processing • 24 days ago

In Java Mode, the following code (based on Dan Shiffman's PShape tutorial) runs at about 50-54fps on my PC, but on an Android tablet (a good one), only at 7fps. I have tried a few display modes and the best seems to be P2D. Any help/thoughts as to why there is this huge performance difference?

Many thanks

Mark

int number=500;
Polygon[] polygons = new Polygon[number];
PShape rectangle;
void setup() {
size(640, 360, P2D); // 6 to 7 fps
// size(640, 360, OPENGL); //2 to 3 fps and it looks wierd
// size(640, 360); // PShape doesn't work
rectangle = createShape(RECT, 10, 10, 60, 40);
//create array of rectangles
for (int i = 0; i < number; i++) {
polygons[i] = new Polygon(rectangle, random(0, width), random(10, height));
}
}
void draw() {
background(51);
for (int i = 0; i < number; i++) {
polygons[i].display();
}
text(frameRate, 10, 10);
}
class Polygon {
PShape s;
float x, y;
Polygon(PShape s_, float _x, float _y) {
s = s_;
x=_x;
y=_y;
}
void display() {
shape(s, x, y);
}
}

Replies(4)

andres

Re: PShape performance

24 days ago

When rendering a large number of PShape objects, it is more efficient put them inside a parent group shape:

int number = 500;
PShape rectangles;
void setup() {
size(640, 360, P2D);
rectangles = createShape(GROUP);
for (int i = 0; i < number; i++) {
PShape rectangle = createShape(RECT,random(0, width), random(10, height), 60, 40);
rectangles.addChild(rectangle);
}
}
void draw() {
background(51);
shape(rectangles);
text(frameRate, 10, 10);
}

The reason is that, even though the amount of geometry is the same, rendering the shapes separately incurs in an extra overhead for each shape, which becomes noticeable as the numbers become large, and specially on mobile devices.

By grouping the shapes together, they are rendered in a single call, which is much faster. The individual shapes doesn't need to be static, you can apply geometry transformations (translate, scale, rotate) on each one separately, but the performance should still be acceptable, as long as they are part of the same group:

int number = 500;
PShape rectangles;
void setup() {
size(640, 360, P2D);
rectangles = createShape(GROUP);
for (int i = 0; i < number; i++) {
PShape rectangle = createShape(RECT, 10, 10, 60, 40);
rectangles.addChild(rectangle);
}
}
void draw() {
background(51);
for (int i = 0; i < number; i++) {
PShape rectangle = rectangles.getChild(i);
rectangle.resetMatrix();
rectangle.translate(random(0, width), random(10, height));
}
shape(rectangles);
text(frameRate, 10, 10);
}

hudsonm40..

Re: PShape performance

24 days ago

Wow! That's a massive improvement....many, many thanks!

Still surprised by the FR change from ~50 on my PC to ~7 in my tablet, but this method using groups gives me ~48FPS on my tablet. Very useful.

Mark

GoToLoop

Re: PShape performance

24 days ago

In my Lubuntu 13.04, w/ GeForce 9800GT running 64-bit JDK 7,
I get at least 60 FPS; even w/ higher resolution!

Anyways, a more simplified & some bling code using GROUP:

/** 
 * Shape Group Example (v3.0)
 * by Hudsonm4000 (2013/Sep)
 * mods Andres & GoToLoop
 * 
 * http://forum.processing.org/topic/pshape-performance
 */

final static int W = 60, H = 40, NUM = 500;
boolean isPaused;
PShape rects;

void setup() {
  size(800, 600, P2D);

  fill(#FFFF00);
  stroke(0);
  strokeWeight(4);

  rects = createShape(GROUP);

  for (int i=0; i!=NUM; i++)
    rects.addChild( createShape(RECT, 0, 0, W, H) );
}

void draw() {
  background(0100);

  for (int i=0; i!=NUM; i++) {
    final PShape rectangle = rects.getChild(i);
    rectangle.resetMatrix();
    rectangle.translate(random(width-W), random(height-H));
  }

  shape(rects);

  frame.setTitle("Shape Group Example  \t  FPS: " + round(frameRate));
}

void mousePressed() {
  if (isPaused = !isPaused)   noLoop();
  else                          loop();
}

void keyPressed() {
  mousePressed();
}

hudsonm40..

Re: PShape performance

24 days ago

Love it