proscene camera relative drawing

gennarose..

proscene camera relative drawing

in Contributed Library Questions • 1 year ago

What do you think is the best way to have just one object (for instance a box with attached interactive frame) not to follow the main camera frame but still preserving the local interactive frame mouse handling ?

within the context of a GUI for a CAD tool, the reason for having this is to let the user to easily set the "drawing plane" a plane in 3D where they can draw points, curves and all sort of objects.....

i.e.

user moves the main camera but the box stay always in the same position
user mouse over the box so that it spins as the interactive frame gets rotated and in so doing drawing plane is set

in a way the box should be drawn almost as it was part of the 2D gui, but it can’t be a 2d objects as user need to rotate it. If you've ever used Revit (AutoDesk) is pretty much the same way they do

let me know if you’ve got some idea.

Gennaro

Replies(4)

nakednous

Re: proscene camera relative drawing

1 year ago

consider the following sketch which draws an iFrame relative to the camera position and also adds a constraint to forbid its translation:

import remixlab.proscene.*;
Scene scene;
InteractiveFrame iFrame;
LocalConstraint constraint;
void setup() {
size(640, 360, P3D);
scene = new Scene(this);
iFrame = new InteractiveFrame(scene);
// we nest the iFrame to the camera frame:
iFrame.setReferenceFrame(scene.camera().frame());
iFrame.translate(40, 40, -180);
// and now forbids its translation:
constraint = new LocalConstraint();
constraint.setTranslationConstraintType(AxisPlaneConstraint.Type.FORBIDDEN);
iFrame.setConstraint(constraint);
scene.setInteractiveFrame(iFrame);
// press 'i' to switch the interaction between the camera frame and the interactive frame
scene.setShortcut('i', Scene.KeyboardAction.FOCUS_INTERACTIVE_FRAME);
// press 'f' to display frame selection hints
scene.setShortcut('f', Scene.KeyboardAction.DRAW_FRAME_SELECTION_HINT);
}
void draw() {
background(0);
fill(204, 102, 0);
// Draw a box in the world coordinate system
box(20, 30, 40);
// first level: draw respect to the camera frame
pushMatrix();
scene.camera().frame().applyTransformation();
// second level: draw respect to the iFrame
pushMatrix();
iFrame.applyTransformation();
scene.drawAxis(20);
// Draw a second box relative to the iFrame (which is nested to the Camera frame)
if (scene.interactiveFrame().grabsMouse()) {
fill(255, 0, 0);
box(12, 17, 22);
}
else if (scene.interactiveFrameIsDrawn()) {
fill(0, 255, 255);
box(12, 17, 22);
}
else {
fill(0, 0, 255);
box(10, 15, 20);
}
popMatrix();
popMatrix();
}

gennarose..

Re: proscene camera relative drawing

1 year ago

hello Jean Pierre,

I've tried to implement further the sketch camera relative drawing and ended up into a problem that I struggle solving

the camera relative drawing is useful if one wants to draw stuff relative to the "navigator"

however I founded a bit different the way in which rotation and translation apply in this case

below attached a small code that shows the current problems with the sketch :

what is the best way to have the navigator always showing and not be hidden when zooming in or out ?
what is the best way to parametrize the position of the "navigator", if the sketch is resized its position changes radically as it is drawn relative to the camera, I could not find a good logic so far.......
the plane drawn gets rotated properly when the navigator is fist rotated but if a translation is applied (using the slider) the plane does not rotate around its current centre but still with respect to the world coordinate system (although translate is called before the rotation). in the applyMatrix I use iFrame.rotation because I think we should use the local roation matrix...... but maybe this is not correct, however if iFrame.orientation is used then the plane is drawn relative to the camera which is not what we want......

import remixlab.proscene.*;
import controlP5.*;
import codeanticode.glgraphics.*;
import processing.opengl.*;
GLGraphicsOffScreen canvas;
Scene scene;
InteractiveFrame iFrame;
ControlP5 controlP5;
int sliderValue = 0;
public void setup()
{
size(1300, 760, GLConstants.GLGRAPHICS);
canvas = new GLGraphicsOffScreen(this, width, height);
scene = new Scene(this, (PGraphics3D) canvas);
iFrame = new InteractiveFrame(scene);
iFrame.setReferenceFrame(scene.camera().frame());
iFrame.translate(130, -70, -240);
LocalConstraint constraint = new LocalConstraint();
constraint.setTranslationConstraintType(AxisPlaneConstraint.Type.FORBIDDEN);
iFrame.setConstraint(constraint);
scene.setInteractiveFrame(iFrame);
controlP5 = new ControlP5(this);
controlP5.addSlider("sliderValue", -100, 100, sliderValue, 10, 50, 100, 10);
}
public void draw()
{
canvas.beginDraw();
scene.beginDraw();
canvas.background(255);
canvas.fill(204, 102, 0);
// first level: draw respect to the camera frame
canvas.pushMatrix();
scene.camera().frame().applyTransformation();
// second level: draw respect to the iFrame
canvas.pushMatrix();
iFrame.applyTransformation();
scene.drawAxis(20);
// Draw a second box
// the projection of the hint would be broken
if (scene.interactiveFrame().grabsMouse()) {
canvas.fill(255, 0, 0);
canvas.box(20, 20, 20);
}
else if (scene.interactiveFrameIsDrawn()) {
canvas.fill(0, 255, 255);
canvas.box(20, 20, 20);
}
else {
canvas.fill(0, 0, 255);
canvas.box(20, 20, 20);
}
canvas.popMatrix();
canvas.popMatrix();
canvas.pushMatrix();
PVector slide=PVector.mult(iFrame.yAxis(), -sliderValue);
canvas.translate(slide.x, slide.y, slide.z);
canvas.applyMatrix(iFrame.rotation().matrix());
canvas.rectMode(CENTER);
canvas.rect(0, 0, 200, 200);
canvas.popMatrix();
scene.endDraw();
canvas.endDraw();
GLTexture tex = canvas.getTexture();
image(tex, 0, 0, 1300, 760);
controlP5.draw();
}
public void mousePressed()
{
if (mouseX < 100)
{
scene.disableMouseHandling();
}
else
{
scene.enableMouseHandling();
}
}

hope to hear soon from you

nakednous

Re: proscene camera relative drawing

1 year ago

Hi Gennaro,

I'm getting a GL_ARB_geometry_shader4 extension not available error message so not able to test your code. However:

Maybe the reason for your object to disappear is that by default Proscene dynamically sets up the zNear() and zFar() values, in order to provide optimal precision of the z-buffer. However, there're two camera kinds: PROSCENE (default) and STANDARD. You may just try to set the camera kind to the latter. See camera.kind, together with camera.setStandardZNear and camera.setStandardZFar.
Resize events are handled by Scene.pre(). I tested it and it works nicely when running a sketch directly from a PDE. If I remember well it doesn't work when running sketches from eclipse though. Don't know why, but if someone has a hint, please let us know it.
Could you please try to reduce your last issue at minimum so that others (like me) can test it.

gennarose..

Re: proscene camera relative drawing

1 year ago

hi Pierre,

thanks for replying,

I've done a P3D version of the sketch, you should be able to run this

in the sketch you will find only one plane that rotates when the navigator is rotated

however if translation is applied (using the slider) the plane does not rotate around its center

but always with respect to the "scene.center"

let me know

import remixlab.proscene.*;
import controlP5.*;
PGraphics canvas;
Scene scene;
InteractiveFrame iFrame;
ControlP5 controlP5;
int sliderValue = 0;
public void setup()
{
size(1300, 760, P3D);
canvas = createGraphics(width,height,P3D);
scene = new Scene(this, (PGraphics3D) canvas);
iFrame = new InteractiveFrame(scene);
iFrame.setReferenceFrame(scene.camera().frame());
iFrame.translate(130, -70, -240);
LocalConstraint constraint = new LocalConstraint();
constraint.setTranslationConstraintType(AxisPlaneConstraint.Type.FORBIDDEN);
iFrame.setConstraint(constraint);
scene.setInteractiveFrame(iFrame);
controlP5 = new ControlP5(this);
controlP5.addSlider("sliderValue", -100, 100, sliderValue, 10, 50, 100, 10);
}
public void draw()
{
canvas.beginDraw();
scene.beginDraw();
canvas.background(255);
canvas.fill(204, 102, 0);
// first level: draw respect to the camera frame
canvas.pushMatrix();
scene.camera().frame().applyTransformation();
// second level: draw respect to the iFrame
canvas.pushMatrix();
iFrame.applyTransformation();
scene.drawAxis(20);
// Draw a second box
// the projection of the hint would be broken
if (scene.interactiveFrame().grabsMouse()) {
canvas.fill(255, 0, 0);
canvas.box(20, 20, 20);
}
else if (scene.interactiveFrameIsDrawn()) {
canvas.fill(0, 255, 255);
canvas.box(20, 20, 20);
}
else {
canvas.fill(0, 0, 255);
canvas.box(20, 20, 20);
}
canvas.popMatrix();
canvas.popMatrix();
canvas.pushMatrix();
PVector slide=PVector.mult(iFrame.yAxis(), -sliderValue);
canvas.translate(slide.x, slide.y, slide.z);
canvas.applyMatrix(iFrame.rotation().matrix());
canvas.rectMode(CENTER);
canvas.rect(0, 0, 200, 200);
canvas.popMatrix();
scene.endDraw();
canvas.endDraw();
image(canvas, 0, 0, 1300, 760);
controlP5.draw();
}
public void mousePressed()
{
if (mouseX < 100)
{
scene.disableMouseHandling();
}
else
{
scene.enableMouseHandling();
}
}

Top Reply