programming question Fifo

Programming Questions

dazzid

in Programming Questions • 1 month ago

Hi all,

I have the following question:

I have an array of 12 numbers (0 or 1) related to a list of buttons called "paisajeButtons[]". I need to program something that allows me to click only 5 and erase the first one when I click the 6th.

I have an array of 5 positions in order called "clickOn[]"

From here everything is fine,

if I manually turn off one of the five button, it works at the first step, but it doesn't when I have the second unselect with 4 buttons on.

I'm trying this but not going well:

Copy code

for (int i = 0; i < 12; i++) {

if (counterButtons > 0 ) {

if (paisajeButtons[i] == 0 && (clickOn[0] == i || clickOn[1] == i || clickOn[2] == i || clickOn[3] == i || clickOn[4] == i )) {

println("mira si hay un cero en el botón = " + i);

if (i == clickOn[0]) {

println("quita el botón 0");

clickOn[0] = clickOn[1];

clickOn[1] = clickOn[2];

clickOn[2] = clickOn[3];

clickOn[3] = clickOn[4];

clickOn[4] = -1;

counterButtons --;

}

if (i == clickOn[1]) {

println("quita el botón 1");

clickOn[1] = clickOn[2];

clickOn[2] = clickOn[3];

clickOn[3] = clickOn[4];

clickOn[4] = -1;

counterButtons --;

}

if (i == clickOn[2]) {

println("quita el botón 2");

clickOn[2] = clickOn[3];

clickOn[3] = clickOn[4];

clickOn[4] = -1;

counterButtons --;

}

if (i == clickOn[3]) {

println("quita el botón 3");

clickOn[3] = clickOn[4];

clickOn[4] = -1;

counterButtons --;

}

if (i == clickOn[4]) {

println("quita el botón 4");

clickOn[4] = -1;

counterButtons --;

}

}

}

}

Replies(2)

tfguy44

Re: programming question Fifo

1 month ago

That was a good one. I had to do a mental jump to hit on a good solution: Don't just track the button's state, track its clicked on order!

Copy code

class Button {
int age;
float px, py;
int id;
Button(int iid, float ipx, float ipy) {
age=0;
id=iid;
px=ipx;
py=ipy;
}
void draw() {
fill((age>0)?255:64);
stroke(isOver()?color(255, 0, 0):0);
ellipse(px, py, 20, 20);
}
boolean isOver() {
return(dist(mouseX, mouseY, px, py)<10);
}
void click() {
if ( isOver() && age==0 ) {
for (int i=0;i<buttons.length;i++) {
buttons[i].growOld();
}
age=5;
}
}
void growOld() {
if (age>0) {
age--;
}
}
}
Button[] buttons;
void setup() {
size(220, 220);
ellipseMode(CENTER);
buttons = new Button[12];
for (int i=0;i<buttons.length;i++) {
buttons[i] = new Button( i, 20 + 30 * (i / 4), 20 + 30 * (i % 4) );
}
}
void draw() {
background(128);
for (int i=0;i<buttons.length;i++) {
buttons[i].draw();
}
}
void mousePressed() {
for (int i=0;i<buttons.length;i++) {
buttons[i].click();
}
}

dazzid

Re: Re: programming question Fifo

1 month ago

hey man!

That's a very good idea, thanks a lot!

I'm using ControlP5 but having a parallel class Button that controls the interface is perfect. I should thought this at first glance. great!

Thanks again

David

Top Reply