No, it's not a bug. You haven't refreshed the background at the beginning of draw(). As draw() gets executed repeatedly,  "Draw this message repeatedly" gets drawn over and over on top of itself, with every call. So it appears degraded. Simply add background(255) at the start of draw() and it will be resolved.

This is not a bug or error. The reason the text degrades without a background call is because of the transparency of the outer pixels of the font. There are some pixels in text that are not 100% opaque making it look smooth. When you repeatedly place the text, each pixel either is 100% transparent or ends up 100% opaque. Which is the ugly text you see.

The way Processing works is with a setup() that runs once and a draw() that loops infinitely. To prevent your text from degrading use a background call at the beginning of draw(). You will notice that there is a background call in 99% of all Processing sketches. I suggest to check out the examples that come with Processing, starting with Examples\Basics\Structure & Examples\Basics\Typography .

One other thought: what if the background is an image?  Would I be forced to reload the image every time?  That seems over the top.

background() sets the background color. If you don't want certain part to be redrawn, then draw a rectangle(or any other shape) with proper fill color on the area that needs to be refreshed.
add the following instead of background(255)

2. boolean sw = true;
3. 
   
4. void setup() {
5.   size(480,480);
6.   background(255);
7. }
8. 
   
9. void draw() {
10.   fill(255);
11.   noStroke();
12.   rect(10,5,450,30);
13.   fill(0);
14.   textSize(24);
15.   text("Draw this message repeatedly", 10, 30);
16.   if (sw) text("Draw this message once", 10, 60);
17.   sw = false;
18.   //noLoop();  // remove or comment out after first run
19. }

Well, before jumping to a lot of conclusions it is better to try and grasp the basic concept of how the draw() loop works and what role background has in that. Check out the example below.

When you press a key you can toggle background calls on or off. You will notice that without a background call the drawing is aggregate aka things are continuously drawn on top of what was previously there, much like the canvas of a painter. Adding a circle every draw() loop at about 60 loops per second. This is basically what your sketch was doing (except nothing moved). When the background call is on, you will see that the circle follows the mouse. The latter effect is what is useful to most applications and how you can create interaction and many other things.

1. boolean bg = true;
2.  
3. void setup() {
4.   size(480,480);
5. }
6.  
7. void draw() {
8.   if (bg) { background(200); }
9.   fill(0);
10.   ellipse(mouseX,mouseY,20,20);
11. }
12.  
13. void keyPressed() {
14.   bg = !bg;
15. }

To answer some of your questions. Yes, you can create a separate layer/canvas for text using for example PGraphics. Loading an image is best done in setup (which runs once, loads the image, it's in memory) and then the image can be drawn where and how you want within draw. There are a lot of tools at your disposal within Processing (and broader Java) to create anything from very simple to extremely complex programs. However, when you try to drive a car with your hands on the brake and gas and your feet on the wheel, you will not get very far. So again, I suggest to try and understand the basic structure of a sketch by checking out some examples.

On another note, perhaps you could describe what you would like to achieve. There are undoubtedly many ways to achieve it.

Finally, check out the example below which shows different ways of (not) showing text while still using a background call.

1. boolean textOn;
2. boolean blinker;
3.  
4. void setup() {
5.   size(700,400);
6.   textFont(createFont("Arial",30));
7. }
8.  
9. void draw() {
10.   background(255);
11.   fill(0);
12.   text("you are in frame: " + frameCount,50,50);
13.   text(millis()/1000 + " seconds have passed since the start", 50,100);
14.   text("this text will be here forever",50,150);
15.   if (frameCount < 500) { 
16.     text("this text will be here for 500 frames",50,200);
17.   }
18.   if (frameCount > 800) { 
19.     text("this text will be here from 800 frames onwards",50,200);
20.   }
21.   if (millis() < 8000) {
22.     text("this text will be here the first 8 seconds",50,250);
23.   }
24.   if (millis() > 12000) { 
25.     text("this text will be here from 12 seconds onwards",50,250);
26.   }
27.   if (textOn) { 
28.     text("this text will depend on a boolean",50,300);
29.   }
30.   if (frameCount % 12 == 0) { blinker = !blinker; }
31.   if (blinker) { 
32.     text("this text will blink",50,350);
33.   }
34. }
35.  
36. void keyPressed() {
37.   // toggle text with spacebar
38.   if (key == ' ') { textOn = !textOn; }
39. }

I only skimmed the topic, but it seems you got good answers already. Anyway, I made the Technical FAQ to answer these very classical questions/errors. I should also mention there the problem with lack of background, which is asked quite frequently too.