Processing + Arduino + Serial port + Cp5.listbox

8bit_biker

Processing + Arduino + Serial port + Cp5.listbox

in Integration and Hardware • 1 year ago

Hi everybody!

I would like to create a "listbox" (using the controlP5 GUI library) containing the serial port list: the goal is to create a stand alone app using Processing to communicate with Arduino Uno, independently from which OS I'm going to use (win, mac or linux), and select (with the "listbox") the correct Serial Port to communicate with Arduino.

is it possible??

Replies(3)

benja

Re: Processing + Arduino + Serial port + Cp5.listbox

1 year ago

Sure, should not be a problem. Example:

import processing.serial.*;
import controlP5.*;

ControlP5 cp5;
ListBox l;
Serial port;
boolean portSelected;

void setup() {
size(400, 400);
cp5 = new ControlP5(this);

// create listbox
l = cp5.addListBox("Serial-ports").setPosition(10, 10).setSize(200, 200);

// add available seria.ports to the listbox
for (int i=0;i<Serial.list().length;i++) {
    ListBoxItem lbi = l.addItem(Serial.list()[i], i);
}
}

void draw() {
// check if port has already been selected
if (portSelected) {
    // things you would usually do in your program
}
}

void serialEvent(Serial p) {
// do something when you recieve serial data
String msg = p.readStringUntil(13);
if (msg != null) {
    println(msg);
}
}

void controlEvent(ControlEvent theEvent) {
if (theEvent.isGroup() && theEvent.name().equals("Serial-ports")) {
    int value = (int)theEvent.group().value();

    // stop connection if one has been created before
    if (port != null)
      port.stop();

    // connect to selected serial port
    port = new Serial(this, Serial.list()[value], 9600);
    portSelected = true;
    println("Serial port selected: "+Serial.list()[value]);
}
}

8bit_biker

Re: Processing + Arduino + Serial port + Cp5.listbox

1 year ago

Thank You..this should be ok!I'm going to try it!

8bit_biker

Re: Processing + Arduino + Serial port + Cp5.listbox

1 year ago

Dear benja...Your solution fits perfectly to me...I really want to thank you a lot!!!

Top Reply