Processing 2, PGraphics, and P2D

Programming Questions

artsnova

Processing 2, PGraphics, and P2D

in Programming Questions • 1 month ago

In the past when using PGraphics I have always used JAVA2D. I am now using Processing 2 and decided to give P2D a try but encountered a problem. I created the following code as a simple test to explain the problem.
If you take the following program and run it:..

PGraphics png;
String outDir="C:/a_PDE_Output/";
String filenam;
float x,y;
int limitF=100;
void setup() {
//size(100,100,P2D);
png = createGraphics(1024, 768, JAVA2D);
png.beginDraw();
png.background(255,210,210);
}
void draw() {
x = random(png.width-1);
y = random(png.height-1);
png.fill(random(255),random(255),random(255));
png.ellipse(x,y,10,10);
if(frameCount >= limitF) drawEnd();
}
void drawEnd() {
bldFname();
png.endDraw();
png.save(filenam);
println("Saved "+filenam);
exit();
}
void bldFname() {
String pr = "testing";
String sx = ".png";
filenam=outDir+pr+sx;
}

It will work as expected. Ellipses are drawn to the PGraphics object and then the output is saved to the file.

Now change JAVA2D to P2D on the createGraphics() statement.
Note that the program will not run as OpenGL needs the size() statement in order to execute.

So uncomment the size() statement and run the program. The program will run BUT...
while the background statement does execute and create the requested background color, none of the ellipses are written to the PGraphics object. Can someone else give this a try and confirm my findings.

Best Regards, Jim

Replies(2)

amnon.owed

Re: Processing 2, PGraphics, and P2D

1 month ago

To use an OpenGL PGraphics you indeed need to initialize and run the sketch itself in the OpenGL renderer.

The problem in your example code is that you use begin-endDraw very loosely. To the point that it could be called a coding error. Apparantly the JAVA2D renderer is more lenient towards this. In many cases however the OpenGL renderers are a bit more strict, especially when it comes to the drawing surface, pixels etc. This is probably because a lot more is going on behind the scenes to keep things running efficiently and where possible on the GPU.

The solution is simply to use begin-endDraw correctly (that is in a slightly stricter way than you were used to).

Adapted Code

PGraphics png;
int limitF = 100;
void setup() {
size(100, 100, P2D);
png = createGraphics(1024, 768, P2D);
png.beginDraw();
png.background(255, 210, 210);
png.endDraw();
}
void draw() {
float x = random(png.width);
float y = random(png.height);
png.beginDraw();
png.fill(random(255), random(255), random(255));
png.ellipse(x, y, 10, 10);
png.endDraw();
if (frameCount >= limitF) drawEnd();
}
void drawEnd() {
png.save("test.png");
println("Saved in the sketch folder:");
println(sketchPath("test.png"));
exit();
}

artsnova

Re: Re: Processing 2, PGraphics, and P2D

1 month ago

Thank you for your help. Bracketing the individual drawing statements with beginDraw/endDraw does solve the problem. The method I used in my example code is the method I've always used with the JAVA2D renderer. I wonder what other surprises await me on the OpenGL trail.

Best Regards, Jim

Top Reply