Problem with object collision

Programming Questions

mattzc

Problem with object collision

in Programming Questions • 1 year ago

Hello,

I am new to Processing and am having some trouble with a project I am working on. What I am trying to do is make it so that when the circles (following the mouse) comes in contact with one of the moving circles, they all stop moving. Unfortunately I know next to oohing about collision and am having a tough time. Here is the code I have right now, if anyone could give me some pointers, or an example or something, I would really appreciate it.

float x = 100;

float y = 100;

float xspeed = 1;

float yspeed = 3.3;

float x1 = 200;

float y1 = 200;

float xspeed1 = 4;

float yspeed1 = 7.3;

float x2 = 300;

float y2 = 400;

float xspeed2 = 4;

float yspeed2 = 4.3;

float x3 = 30;

float y3 = 40;

float xspeed3 = 5;

float yspeed3 = 4.3;

void setup() {

size(800,800);

smooth();

background(255);

}

void draw() {

noStroke();

fill(255,10);

rect(0,0,width,height);

background(0,0,0);

fill(255,0,0);

ellipse(mouseX,mouseY,50,50);

fill(255);

// Add the current speed to the location.

x = x + xspeed;

y = y + yspeed;

// Check for bouncing

if ((x > width) || (x < 0)) {

xspeed = xspeed * -1;

}

if ((y > height) || (y < 0)) {

yspeed = yspeed * -1;

}

// Display at x,y location

stroke(0);

fill(175);

ellipse(x,y,16,16);

x1 = x1 + xspeed1;

y1 = y1 + yspeed1;

// Check for bouncing

if ((x1 > width) || (x1 < 0)) {

xspeed1 = xspeed1 * -1;

}

if ((y1 > height) || (y1 < 0)) {

yspeed1 = yspeed1 * -1;

}

// Display at x,y location

stroke(0);

fill(175);

ellipse(x1,y1,16,16);

x2 = x2 + xspeed2;

y2 = y2 + yspeed2;

// Check for bouncing

if ((x2 > width) || (x2 < 0)) {

xspeed2 = xspeed2 * -1;

}

if ((y2 > height) || (y2 < 0)) {

yspeed2 = yspeed2 * -1;

}

// Display at x,y location

stroke(0);

fill(175);

ellipse(x2,y2,16,16);

x3 = x3 + xspeed3;

y3 = y3 + yspeed3;

// Check for bouncing

if ((x3 > width) || (x3 < 0)) {

xspeed3 = xspeed3 * -1;

}

if ((y3 > height) || (y3 < 0)) {

yspeed3 = yspeed3 * -1;

}

// Display at x,y location

stroke(0);

fill(175);

ellipse(x3,y3,16,16);

}

Replies(5)

tfguy44

Re: Problem with object collision

1 year ago

Ball[] balls;
boolean overlap;
class Ball {
float px, py, vx, vy;
Ball(float _px, float _py, float _vx, float _vy ) {
px = _px;
py = _py;
vx = _vx;
vy = _vy;
}
void simulate() {
px+=vx;
py+=vy;
vx*=((px > width) || (px < 0))?-1:1;
vy*=((py > width) || (py < 0))?-1:1;
}
void render() {
fill(175);
ellipse(px, py, 16, 16);
}
boolean overlaps(){
return( dist( mouseX, mouseY, px, py ) <= 33 );
}
}
void setup() {
size(800, 800);
smooth();
stroke(0);
ellipseMode(CENTER);
balls = new Ball[4];
balls[0] = new Ball(100, 100, 1, 3.3);
balls[1] = new Ball(200, 200, 4, 7.3);
balls[2] = new Ball(300, 400, 4, 4.3);
balls[3] = new Ball(30, 40, 5, 4.3);
overlap = false;
}
void draw() {
simulate();
render();
}
void simulate() {
overlap = false;
for ( int i = 0; i < balls.length; i++) {
if( balls[i].overlaps() ){
overlap = true;
}
}
if ( !overlap ) {
for ( int i = 0; i < balls.length; i++) {
balls[i].simulate();
}
}
}
void render() {
background(0);
fill(255, 0, 0);
ellipse(mouseX, mouseY, 50, 50);
for ( int i = 0; i < balls.length; i++) {
balls[i].render();
}
}

mattzc

Re: Problem with object collision

1 year ago

Wow thank you so much, you have no idea how much this helps me out!

mattzc

Re: Problem with object collision

1 year ago

Hey, sort to do this again, but i modified the code for more balls with individual features, but now when one ball stops the rest don't. Any suggestions?

here is the code:

Ball[] balls;

boolean overlap;

PFont fontA;

class Ball {

float px, py, vx, vy;

Ball(float _px, float _py, float _vx, float _vy ) {

px = _px;

py = _py;

vx = _vx;

vy = _vy;

}

void simulate() {

px+=vx;

py+=vy;

vx*=((px > width) || (px < 0))?-1:1;

vy*=((py > width) || (py < 0))?-1:1;

}

void render() {

fill(175);

ellipse(px, py, 16, 16);

}

boolean overlaps(){

return( dist( mouseX, mouseY, px, py ) <= 33 );

}

void setup() {

size(800, 800);

smooth();

stroke(0);

ellipseMode(CENTER);

balls = new Ball[7];

balls[0] = new Ball(100, 100, 4, 7.3);

balls[1] = new Ball(200, 200, 4, 6.3);

balls[2] = new Ball(300, 400, 4, 5.3);

balls[3] = new Ball(30, 40, 5, 4.3);

balls[4] = new Ball(350, 500, 4, 4.3);

balls[5] = new Ball(400, 300, 4, 4.3);

balls[6] = new Ball(500, 500, 2,2);

overlap = false;

}

void draw() {

simulate();

render();

simulateA();

renderA();

simulateB();

renderB();

simulateC();

renderC();

simulateD();

renderD();

simulateE();

renderE();

simulateF();

renderF();

textAlign (CENTER);

ellipseMode(CENTER);

fontA = loadFont("Serif-48.vlw");

textFont(fontA,48);

}

void simulate() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[0].overlaps() ){

overlap = true;

fill(255);

text ("Heart Attack",400,50);

text("2.5/1",400,400);

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[0].simulate();

}

void render() {

background(0);

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[0].render();

}

void simulateA() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[1].overlaps() ){

overlap = true;

fill(255);

text ("Cancer",400,50);

text("5/1",400,400);

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[1].simulate();

}

void renderA() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[1].render();

}

void simulateB() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[2].overlaps() ){

text ("Road Accident",400,50);

text("8000/1",400,400);

overlap = true;

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[2].simulate();

}

void renderB() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[2].render();

}

void simulateC() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[3].overlaps() ){

text ("Work Accident",400,50);

text("43 500/1",400,400);

overlap = true;

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[3].simulate();

}

void renderC() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[3].render();

}

void simulateD() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[4].overlaps() ){

text ("Train Crash",400,50);

text("500 000/1",400,400);

overlap = true;

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[4].simulate();

}

void renderD() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[4].render();

}

void simulateE() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[5].overlaps() ){

text ("Drowning in Bath",400,50);

text("685 000/1",400,400);

overlap = true;

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[5].simulate();

}

void renderE() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[5].render();

}

void simulateF() {

overlap = false;

for ( int i = 0; i < balls.length; i++) {

if( balls[6].overlaps() ){

text ("Shark Attack",400,50);

text("300 000 000/1",400,400);

overlap = true;

}

if ( !overlap ) {

for ( int i = 0; i < balls.length; i++) {

balls[6].simulate();

}

void renderF() {

fill(255, 0, 0);

ellipse(mouseX, mouseY, 50, 50);

for ( int i = 0; i < balls.length; i++) {

balls[6].render();

}

tfguy44

Re: Re: Problem with object collision

1 year ago

You don't need to make entirely separate function for each object just to do slightly different things for each one.

Just add a new variable to the class that can be used to do a different thing for each ball:

Ball[] balls;
boolean overlap;
PFont fontA;
class Ball {
float px, py, vx, vy;
String t;
Ball(float _px, float _py, float _vx, float _vy, String _t ) {
px = _px;
py = _py;
vx = _vx;
vy = _vy;
t = _t;
}
void simulate() {
px+=vx;
py+=vy;
vx*=((px > width) || (px < 0))?-1:1;
vy*=((py > width) || (py < 0))?-1:1;
}
void render() {
fill(175);
ellipse(px, py, 16, 16);
}
boolean overlaps() {
return( dist( mouseX, mouseY, px, py ) <= 33 );
}
}
void setup() {
size(800, 800);
smooth();
stroke(0);
ellipseMode(CENTER);
balls = new Ball[7];
balls[0] = new Ball(100, 100, 1, 3.3, "You found Ball 0!" );
balls[1] = new Ball(200, 200, 4, 7.3, "This is Ball 1." );
balls[2] = new Ball(300, 400, 4, 4.3, "Why you no use classes right?" );
balls[3] = new Ball(30, 40, 5, 4.3, "Santa's gonna get you." );
balls[4] = new Ball(350, 500, 4, 4.3, "What?" );
balls[5] = new Ball(400, 300, 4, 4.3, "Who?" );
balls[6] = new Ball(500, 500, 2, 2, "Huh?" );
overlap = false;
textAlign (CENTER);
fontA = loadFont("Serif-48.vlw");
textFont(fontA,48);
}
void draw() {
simulate();
render();
}
void simulate() {
overlap = false;
for ( int i = 0; i < balls.length; i++) {
if ( balls[i].overlaps() ) {
overlap = true;
}
}
if ( !overlap ) {
for ( int i = 0; i < balls.length; i++) {
balls[i].simulate();
}
}
}
void render() {
background(0);
fill(255, 0, 0);
ellipse(mouseX, mouseY, 50, 50);
for ( int i = 0; i < balls.length; i++) {
balls[i].render();
if ( balls[i].overlaps() ) {
fill( 255 );
text( balls[i].t , 400, 50 );
}
}
}

mattzc

Re: Problem with object collision

1 year ago

Thanks again!

Top Reply