Problem with creating Object from Sketch

Programming Questions

ldiethyla..

Problem with creating Object from Sketch

in Programming Questions • 1 year ago

Hey all,

I was messing around with making music visualizers in Processing (using the Minim library) and came up with this neat sketch:

import ddf.minim.analysis.*;
import ddf.minim.*;
import processing.video.*;
Minim minim;
AudioInput input;
FFT fft;
void setup() {
size(1024,640);
smooth();
background(0);
minim = new Minim(this);
input = minim.getLineIn(Minim.STEREO, 512);
fft = new FFT(input.bufferSize(), input.sampleRate());
fft.linAverages(64);
}
void draw() {
//clear screen
fill(0,12);
rect(0, 0, width, height);
noFill();
//move the FFT forward
fft.forward(input.mix);
//compute some parameters
int w = int(fft.specSize()/64);
//draw everything using the FFT data
for (int i = 0; i < fft.avgSize(); i++){
//stroke(0, 0, fft.getAvg(i)*50, 225);
stroke(fft.getAvg(i)*25, fft.getAvg(i)*25, fft.getAvg(i)*25 + 50);
ellipse(width/2 + fft.getAvg(w)*50, height/2 + fft.getAvg(i)*50, i, i);
ellipse(width/2 + fft.getAvg(w)*50, height/2 - fft.getAvg(i)*50, i, i);
ellipse(width/2 - fft.getAvg(w)*50, height/2 + fft.getAvg(i)*50, i, i);
ellipse(width/2 - fft.getAvg(w)*50, height/2 - fft.getAvg(i)*50, i, i);
}
}
void stop(){
input.close();
minim.stop();
super.stop();
}

It looks pretty neat, but I wanted to be able to put multiple visualizations into a single file and be able to switch between them without closing the window. I figured the best way to do this would be with classes, so I tried to turn this sketch into a class:

import ddf.minim.analysis.*;
import ddf.minim.*;
import processing.video.*;
Minim minim;
AudioInput input;
FFT fft;
DualCircles circ;
void setup() {
size(1024, 640);
smooth();
background(0);
minim = new Minim(this);
input = minim.getLineIn(Minim.STEREO, 512);
fft = new FFT(input.bufferSize(), input.sampleRate());
fft.linAverages(64);
rectMode(CORNERS);
DualCircles circ = new DualCircles(color(25,25,25),75);
}
void draw() {
fill(0, 16);
rect(0, 0, width, height);
noFill();
//move the FFT forward
fft.forward(input.mix);
//pass the updated FFT to draw() to update the sketch
circ.draw(fft);
}
void stop() {
input.close();
minim.stop();
super.stop();
}
class DualCircles {
color strokeColor;
float sensitivity;
float bassFactor;
DualCircles(color strokeColorValue, float sensitivityValue){
strokeColor = strokeColorValue;
sensitivity = sensitivityValue;
}
void draw(FFT fft){
int bassFactor = int(fft.specSize()/64);
for (int i = 0; i < fft.avgSize(); i++) {
stroke(fft.getAvg(i)*red(strokeColor), fft.getAvg(i)*green(strokeColor), fft.getAvg(i)*blue(strokeColor) + 50);
ellipse(width/2 + fft.getAvg(bassFactor)*sensitivity, height/2 + fft.getAvg(i)*50, i, i);
ellipse(width/2 + fft.getAvg(bassFactor)*sensitivity, height/2 - fft.getAvg(i)*50, i, i);
ellipse(width/2 - fft.getAvg(bassFactor)*sensitivity, height/2 + fft.getAvg(i)*50, i, i);
ellipse(width/2 - fft.getAvg(bassFactor)*sensitivity, height/2 - fft.getAvg(i)*50, i, i);
}
}
}

However, this seems to throw an error at the call to draw(). I get a NullPointerException, and the following gets printed out:

Exception in thread "Animation Thread" java.lang.NullPointerException

at circlesandsquaresTEST.draw(circlesandsquaresTEST.java:50)

at processing.core.PApplet.handleDraw(Unknown Source)

at processing.core.PApplet.run(Unknown Source)

at java.lang.Thread.run(Thread.java:662)

I can decode that to understand that there's an error in draw(), but I can't narrow it down any further. Any thoughts?

Replies(7)

PhiLho

Re: Problem with creating Object from Sketch

1 year ago

Please read the Why do I get a NullPointerException? FAQ page, the answer is there...
It is in the http://wiki.processing.org/w/Technical_FAQ page...

Jonny Stu..

Re: Problem with creating Object from Sketch

1 year ago

phi.lho - unfortunately that wiki page is blank at the moment.

Idiethylamine - the problem is that you've created a second instance of DualCircles that is local to the setup() function so your global instance of DualCircles is never instantiated.

What you have at the moment is an allocation of space for DualCircles called circ on line 8 which will be global. When you come to instantiate (fill the allocated space with an actual working class) the global circ in setup you end up allocating another space for a DualCircles also called circ that is local to the setup() function and then immediately creating a DualCircles in this space leaving the global one as empty. The local circ vanishes at the end of setup() so when you come to access it in draw() you get a NullPointerException. To fix this change line 19 to:

circ = new DualCircles(color(25,25,25),75);

It's really important that you try to fully understand why this error happened or you'll end up with a load more problems down the line (which is why I've spent a paragraph explaining it). Consider reading the tutorial page on variable scope if you haven't already http://processing.org/learning/basics/variablescope.html.

You're going to have a similar problem with draw function in your DrawCircles class eventually - you need to rename the fft argument so that it doesn't clash with your global variable which is also called fft.

PhiLho

Re: Re: Problem with creating Object from Sketch

1 year ago

Zoho is behaving again with these links!

Looks like I must make titles without question marks in them...
I updated the message, thanks for pointing it out.

Chrisir

Re: Problem with creating Object from Sketch

1 year ago

Here is phi.lho's Link working:

Link

ldiethyla..

Re: Problem with creating Object from Sketch

1 year ago

Hey all -- thanks so much for the help! That really cleared up the issue; I was able to wrap my head around it and fix it :)

Though, now I'm having another problem that seems to be related to swapping over from a sketch to an object:

my original sketch is as follows:

void draw() {
fill(0,12);
rect(0, 0, width, height);
noFill();
fft.forward(input.mix);
int w = int(fft.specSize()/64);
for (int i = 0; i < fft.avgSize(); i++) {
stroke(fft.getAvg(w)*25, fft.getAvg(w)*25, fft.getAvg(w)*25 + 50);
ellipse(width/2,height/2,fft.getAvg(i)*fft.getAvg(i)/fft.getAvg(w)*100,fft.getAvg(w)*fft.getAvg(w)/fft.getAvg(i)*100);
}
}

When I switched it to an object, I made it:

void draw() {
fft.forward(input.mix);
hyperbola.draw(fft,2*input2,input3/4);
}
class Hyperbolic {
color strokeColor;
float sensitivity;
float bassFactor;
Hyperbolic(color strokeColorValue, float sensitivityValue){
strokeColor = strokeColorValue;
sensitivity = sensitivityValue;
}
void draw(FFT transform, float sensitivityValue, int fillVal){
fill(0, fillVal);
rect(width/2, height/2, width, height);
noFill();
sensitivity = sensitivityValue/4;
int bassFactor = int(transform.specSize()/64);
for (int i = 0; i < fft.avgSize(); i++) {
stroke(fft.getAvg(bassFactor)*25, fft.getAvg(bassFactor)*25, fft.getAvg(bassFactor)*25 + 50);
ellipse(width/2,height/2,fft.getAvg(i)*fft.getAvg(i)/fft.getAvg(bassFactor)*sensitivity,fft.getAvg(bassFactor)*fft.getAvg(bassFactor)/fft.getAvg(i)*sensitivity);
}
}
}

But when I run the object-oriented version, I get the error:

Exception in thread "Animation Thread" java.lang.ArrayIndexOutOfBoundsException: 720

at processing.core.PGraphics2D.ellipseImpl(Unknown Source)

at processing.core.PGraphics.ellipse(Unknown Source)

at processing.core.PApplet.ellipse(Unknown Source)

at midiVisualizertemplate$Hyperbolic.draw(midiVisualizertemplate.java:240)

at midiVisualizertemplate.draw(midiVisualizertemplate.java:75)

at processing.core.PApplet.handleDraw(Unknown Source)

at processing.core.PApplet.run(Unknown Source)

at java.lang.Thread.run(Thread.java:662)

It seems that my array indices are all out of wack somehow, but I can't tell how -- if I println(bassFactor), then it comes out as '4' -- which should be within the array size (I've used fft.linAverages(64) to make 64 bins of FFT data).

Any suggestions on how I should approach debugging this?

PhiLho

Re: Problem with creating Object from Sketch

1 year ago

The exception is in processing.core.PGraphics2D.ellipseImpl ie. in Processing code itself. Probably in the cosLUT or sinLUT tables, which look like being used for fast sin/cos implementation. 720 is 2 * 360, but I am not sure why you reach the limit. No time to investigate right now, I fear. Perhaps later.

ldiethyla..

Re: Problem with creating Object from Sketch

1 year ago

Hmm, by removing the 'P2D' option in setup, everything returned to normal, so it seem to be an issue only with the P2D renderer.

Top Reply