Problem with animation of graph.

Programming Questions

jorrebor

Problem with animation of graph.

in Programming Questions • 2 years ago

Hoi everybody!

i'm stuck with something simple...

my sketch should draw a graph, but cannot exceed a certain area. So when the max width is reached the graph should shift to the left.

PVector[] my_array = new PVector[100];
int val;
int j;
void setup() {
frameRate(1);
size(400,400);
//initialize some values
for (int i = 0; i < my_array.length; i++) {
my_array[i] = new PVector();
my_array[i].x = i;
my_array[i].y = i*2;
}
// printArray(my_array);
//
// shiftAndAdd(my_array, 10);
// printArray(my_array);
//
// shiftAndAdd(my_array, 999);
// printArray(my_array);
}
void draw(){
background(0);
stroke(255);
val = int(random (100,120));
my_array = shiftAndAdd(my_array, val);
for(int i = 0; i < my_array.length; i++){
point(my_array[i].x,my_array[i].y);
}
}
// shift all the values to the left, and set the new value at the end
PVector[] shiftAndAdd(PVector a[], int val){
int a_length = a.length;
System.arraycopy(a, 1, a, 0, a_length-1);
for(int i = 0; i < a.length; i++){
a[i].x = i;
}
printArray(a);
a[a_length-1].y = val;
return a;
}
// function to print array values in a row
void printArray(PVector a[]) {
for (int i = 0; i < a.length; i++) {
print("x: " + a[i].x + " y: " + a[i].y + ", ");
}
println("\n----");
}

the random value val should be added to the array form which the line is drawn. for some reason this does not happen... The graph shifts, but without the las added item...

i have no idea why this is; please help!

thanks

Replies(2)

quarks

Re: Problem with animation of graph.

2 years ago

Here is the solution change the shiftAndAdd to this

// shift all the values to the left, and set the new value at the end
PVector[] shiftAndAdd(PVector a[], int val) {
int a_length = a.length;
System.arraycopy(a, 1, a, 0, a_length-1);
a[a.length -1] = new PVector (a.length-1, val);
for (int i = 0; i < a.length; i++) {
a[i].x = i;
}
printArray(a);
return a;
}

When using classes you have to get used to the idea of object references, for instance

PVector vec;
vec = new PVector(1,2,3);

Consider the statements above after the first line is executed what is vec? The answer it is an object reference, in this case a PVector object reference - it is NOT a PVector. The value stored in vec is null which is a special value to indicate that the variable is not referencing an object.
In line 2 we actually create a PVector object and vec will reference it. Now consider

PVector veca, vecB;
vecA = new PVector(1,2,3);
vecB = vecA;

How many PVectors are there? Only one has been created in line 2 BUT both vecA and vecB reference the SAME object so

vecB.x = 999;
println(vecA.x);

will display 999 and not1.

The arraycopy copies the references so after its execution so for array size 100
a[98] and a[99} both reference the same vector.

jorrebor

Re: Re: Problem with animation of graph.

2 years ago

Thanks alot!

solution plus explaination, great!

Top Reply